Macro - Reparar Arcos de 1 baú automaticamente (v1)

$${
////////////////////////////////////////////////////////////
////////////////////////////// by MUR4I#0409
////////////////////////////// Macro - Reparar Arcos de 1 baú automaticamente (v1)
////////////////////////////////////////////////////////////
    LOG(" ");
    TOGGLE(blues);
    IF(!blues);
        LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cOFF&4!");
        STOP;
    ENDIF;
    PLAYSOUND(tile.piston.in);
    LOG("&b&l[MACRO] &6Reparar Arcos (v1): &aON&2!");
////////////////////////////////////////////////////////////
////////////////////////////// DECLARAÇÃO DE VARIÁVEIS
////////////////////////////////////////////////////////////
    SET(#player_xpos,"%XPOS%");
    SET(#player_ypos,"%YPOS%");
    SET(#player_zpos,"%ZPOS%");
    SET(#bau_n_abre,0);
    SET(#tentativas,0);
    SET(#qtdarco,0);
    SET(#qtdlinha,0);
    UNSET(parar);
    UNSET(pegou_arco);
    UNSET(limpeza);
    UNSET(@sleeplack)
    UNSET(#yawblocoferro);
    UNSET(#pitchblocoferro);

////////////////////////////////////////////////////////////
////////////////////////////// TEMP INFO
////////////////////////////////////////////////////////////
    LOOK(%YAW%,%PITCH%);
    SET(#lookyaw,"%YAW%");
    SET(#lookpitch,"%PITCH%");
    IF(%DIRECTION% = "N"); SET(&frente,"NORTH"); SET(&atras,"SOUTH"); SET(&direita,"EAST"); SET(&esquerda,"WEST"); ENDIF;
    IF(%DIRECTION% = "S"); SET(&frente,"SOUTH"); SET(&atras,"NORTH"); SET(&direita,"WEST"); SET(&esquerda,"EAST"); ENDIF;
    IF(%DIRECTION% = "E"); SET(&frente,"EAST"); SET(&atras,"WEST"); SET(&direita,"SOUTH"); SET(&esquerda,"NORTH"); ENDIF;
    IF(%DIRECTION% = "W"); SET(&frente,"WEST"); SET(&atras,"EAST"); SET(&direita,"NORTH"); SET(&esquerda,"SOUTH"); ENDIF;
    GETIDREL(0,-1,0,#blocoferro1);IF(%#blocoferro1%=42);SET(#yawblocoferro,"0");SET(#pitchblocoferro,"90");ENDIF;
    GETIDREL(-1,0,0,#blocoferro2);IF(%#blocoferro2%=42);SET(#yawblocoferro,"270");SET(#pitchblocoferro,"64");ENDIF;
    GETIDREL(1,0,0,#blocoferro3);IF(%#blocoferro3%=42);SET(#yawblocoferro,"90");SET(#pitchblocoferro,"64");ENDIF;
    GETIDREL(0,0,-1,#blocoferro4);IF(%#blocoferro4%=42);SET(#yawblocoferro,"0");SET(#pitchblocoferro,"64");ENDIF;
    GETIDREL(0,0,1,#blocoferro5);IF(%#blocoferro5%=42);SET(#yawblocoferro,"180");SET(#pitchblocoferro,"64");ENDIF;
////////////////////////////////////////////////////////////
////////////////////////////// INÍCIO DA MACRO
////////////////////////////////////////////////////////////
    IF(#pitchblocoferro);
        DO();
        //--- ABRIR BAÚ
            GUI();
            LOOK(%#lookyaw%,%#lookpitch%);
            DO(3);
                IF((HITID == 54)||(HITID == 146));
                    KEY(use);
                    DO(200);
                    UNTIL(%GUI%="GUICHEST");
                ENDIF;
            UNTIL(%GUI%="GUICHEST");
            WAIT(10T);
        //--- PEGAR ARCOS
            IF(%GUI%="GUICHEST");
                SET(#tentativas,0);
                SET(#qtdarco,0);
                FOR(#slot,0,53);
                    GETSLOTITEM(%#slot%,#id,#stack,#data);
                    IF(%#id%=261);
                        SLOTCLICK(%#slot%,L,TRUE);
                        INC(#qtdarco,1);
                    ENDIF;
                    INC(#tentativas,1);
                    IF(%#qtdarco%>=9);
                        SET(pegou_arco);
                        GUI();
                        BREAK;
                    ELSEIF(%#tentativas%>=54);
                        LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cNão foram encontrados 9 arcos!");
                        GUI();
                        SET(parar);
                        BREAK;
                    ENDIF;
                NEXT;
        //--- BAÚ NÃO ABRE
            ELSEIF((HITID == 54)||(HITID == 146));
                INC(#bau_n_abre,1);
                IF(%#bau_n_abre%<=3);
                    LOG("");
                    LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cO baú não está abrindo! Tentando novamente... &7&o#MR&3&oBLUEEES");
                    LOG("");
                ELSE;
                    LOG("");
                    LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cAconteceu algum problema.");
                    LOG("&bFinalizando a macro...");
                    LOG("");
                    SET(parar);
                    BREAK;
                ENDIF;
        //-- NÃO ESTÁ OLHANDO PARA UM BAÚ
            ELSE;
                LOG("");
                LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cVocê não está olhando para um baú.");
                LOG("&bFinalizando a macro...");
                LOG("");
                SET(parar);
                BREAK;
            ENDIF;
        //-- SE PEGOU ARCOS
            IF(pegou_arco);
            //-- REPARAR TODA HOTBAR
                WAIT(1);
                GUI();

                FOR(#slot,1,9);
                    SLOT(%#slot%);
                    DO();
                        LOOK(%#yawblocoferro%,%#pitchblocoferro%);
                        KEY(use);
                        WAIT(500ms);
                        IF(@sleeplack);
                            BREAK;
                        ENDIF;
                    UNTIL((%DURABILITY%=384)||(@sleeplack));

                    IF(@sleeplack);
                        LOG("");
                        LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cAcabaram as linhas!");
                        LOG("&bFinalizando a macro...");
                        LOG("");
                        UNSET(pegou_arco);
                        SET(parar);
                        BREAK;
                    ENDIF;
                NEXT;

                IF(!parar);
                LOG("");
                LOG("&b&l[MACRO] &6Reparar Arcos (v1): &aReparei toda hotbar!");
                LOG("&bIniciando limpeza...");
                LOG("");
                UNSET(pegou_arco);
                SET(limpeza);
                ENDIF;
            ENDIF;

            //-- LIMPEZA DOS ARCOS
            IF(limpeza);
                WAIT(1);
                GUI();
                FOR(#slot,1,9);
                    LOOK(%&frente%);

                    SLOT(%#slot%);
                    DO();
                        KEY(DROP);
                        WAIT(100ms);
                    UNTIL(%DURABILITY%=0);
                NEXT;
                LOG("");
                LOG("&b&l[MACRO] &6Reparar Arcos (v1): &aLimpeza finalizada!");
                LOG("");

                UNSET(limpeza);
            ENDIF;

        UNTIL(parar);
    ELSE;
        LOG("");
        LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cNão foi encontrado nenhum bloco de ferro por perto!");
        LOG("");
    ENDIF;
////////////////////////////////////////////////////////////
////////////////////////////// FIM DA MACRO
////////////////////////////////////////////////////////////
    TOGGLE(blues);
    PLAYSOUND(tile.piston.out);
    LOG("");
    LOG("&b&l[MACRO] &6Reparar Arcos (v1): &aFinalizado! &7&o#MR&3&oBLUEEES");
    LOG("&b&l[MACRO] &6Reparar Arcos (v1): &cOFF&4!");
    LOG("");
    STOP;
}$$