WolfTXT

Indiana Jones 1 aneb Chrám Zkázy 1

Nov 12th, 2015
694
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. 1 POKE 16,64:POKE 53774,64:POKE 580,1
  2. 2 DIM M$(6),X$(1000),A$(100),B$(100),O$(600),Z$(500),E$(30),F$(30),K$(30),Q$(1000),S$(1000),C$(5)
  3. 3 SETCOLOR 1,1,1:GOTO 9145
  4. 10 REM
  5. 40 PR=0
  6. 50 P=0:X$(LEN(X$)+1)=" ":Q$=""
  7. 60 FOR I=1 TO LEN(X$)
  8. 80 Q$(LEN(Q$)+1)=X$(I,I)
  9. 90 IF X$(I,I)<>" " THEN 200
  10. 100 IF P+LEN(Q$)>37 THEN ? :P=0:PR=PR+1
  11. 110 ? Q$;:P=P+LEN(Q$):Q$=""
  12. 200 NEXT I:? :RETURN
  13. 210 DATA s,j,z,v,n,d,vezmi,seber,poloz,prohledni,prozkoumej,r,otevri,zavri,stiskni,zmackni,nastup,vlez
  14. 211 DATA vejdi,vystup,vylez,vyjdi,i,privaz,pripevni,odvaz,otoc,zapal,vloz,uloz,pomoc,load,save,konec,quit,stop
  15. 251 REM
  16. 252 REM
  17. 253 REM
  18. 254 REM
  19. 255 REM
  20. 256 GOTO 3600
  21. 257 REM
  22. 258 GOTO 3700
  23. 259 GOTO 3800
  24. 260 REM
  25. 261 GOTO 3900
  26. 262 GOTO 4000
  27. 263 GOTO 4100
  28. 264 GOTO 4150
  29. 265 REM
  30. 266 GOTO 4200
  31. 267 REM
  32. 268 REM
  33. 269 GOTO 4350
  34. 270 REM
  35. 271 REM
  36. 272 GOTO 4400
  37. 273 GOTO 4450
  38. 274 REM
  39. 275 GOTO 4500
  40. 276 GOTO 4600
  41. 277 GOTO 4050
  42. 278 GOTO 4650
  43. 279 REM
  44. 280 GOTO 4700
  45. 281 GOTO 4800
  46. 282 GOTO 4900
  47. 283 GOTO 5000
  48. 284 REM
  49. 285 GOTO 5100
  50. 301 DATA 000400,Stojis na mytine. Ve skale je maly pruchod. Dalsi vetsi otvor je 15m nad tebou.
  51. 302 DATA @03507,Jsi na zacatku siroke chodby. V podlaze je otvor vetraci sachty. Ve strope nad sachtou je tram.
  52. 303 DATA 004600,Jsi uprostred siroke chodby. Podlaha tvori trychtyr. Je v ni otvor. Zem je vlhka a kluzka.
  53. 304 DATA 005000,Jsi na vychodnim konci siroke chodby.
  54. 305 DATA 0=0048,Visis na lane ve vetraci sachte. Sachta pokracuje nahoru i dolu. V jizni stene jsou
  55. 306 DATA 0;0970,Stojis na hromade kameni. Nad tebou je usti vetraci sachty.
  56. 307 DATA 008:00,Jsi v uzke chodbe. Ve strope ja maly otvor.
  57. 308 DATA 009000,Jsi na konci uzke chodby.
  58. 309 DATA 80000<,Jsi v prostorne jeskyni. Ze zdi usti tlusta roura s kohoutem. V podlaze jsou
  59. 310 DATA 0000;0,Jsi v zatuchle jame.
  60. 311 DATA 7>00>0,Jsi ve vlhke mistnosti.V rohu podlahy je maly otvor.Na jihu je schodiste.Vede vzhuru.V sev.zdi jsou
  61. 312 DATA =?000=,Jsi na vrcholu schodiste. Je tu plno pavucin. Zrejme zde nikdo dlouho nebyl.
  62. 313 DATA >C0000,Jsi u vstupu do chramu. Na jihu je zlatem vykladana brana.
  63. 314 DATA A40000,Jsi v hlavni stole. Zacinaji tu koleje. Vedou na sever. Stoji zde dulni lokomotiva.
  64. 315 DATA B@0000,Jsi uprostred hlavni stoly. Po zemi lezou odporni pavouci.
  65. 316 DATA 0A0000,Jsi na severnim konci hlavni stoly. Na kolejich stoji dulni lokomotiva.
  66. 317 DATA ?CDCCC,Jsi v bludisti.
  67. 318 DATA ECCCCC,Jsi v bludisti.
  68. 319 DATA CGFCCC,Jsi v bludisti.
  69. 320 DATA CCCCCC,Jsi v bludisti.
  70. 321 DATA CCCHCC,Jsi v bludisti.
  71. 322 DATA CCCICC,Jsi v bludisti.
  72. 323 DATA CCCCJC,Jsi v bludisti.
  73. 324 DATA KCCCCC,Jsi v bludisti.
  74. 325 DATA CLCCCC,Jsi v bludisti.
  75. 326 DATA KM000M,Jsi na severnim kraji velke prohlubne. V prohlubni se prevaluji mracna plynu.
  76. 327 DATA LN0000,Jsi obklopen zelenym plynem.
  77. 328 DATA M00O0M,Jsi na jiznim okraji prohlubne. V prohlubni se prevaluji mracna plynu.
  78. 329 DATA 00NP00,Jsi na zapadnim okraji baziny.
  79. 330 DATA 00OQ00,Jsi uprostred baziny. Z bahna unikaji jedovate plyny.
  80. 331 DATA 00PR00,Jsi na vychodnim okraji baziny.
  81. 332 DATA 00QS00,Jsi v siroke chodbe. Zdi jsou vyzdobeny vybledlymi kresbami.
  82. 333 DATA T0R000,Jsi v okrouhle mistnosti. Je zde kamenny oltar. Na prohluben v oltari dopada svetlo.
  83. 334 DATA VS0000,Jsi v mistnosti vyzdobene sochami kralu a jinych velmozu. Ve vychodni zdi je mohutna brana.
  84. 335 DATA 00T0W0,Jsi v hlavni mistnosti chramu. Nahoru vedou schudky k oltari. V zapadni zdi je mohutna brana.
  85. 336 DATA 0TX000,Jsi v male kobce. Drive zrejme  slouzila jako hladomorna. V zapadni zdi je male rezave okno.
  86. 337 DATA 00000U,Stojis na kamennem oltari.
  87. 338 DATA 000V03,Drzis se skaly pod okenkem. 15m pod sebou vidis mytinu. Z teto mytiny jsi vysel.
  88. 339 DATA 000000,Jsi v dulni lokomotive.
  89. 400 FOR I=LEN(X$) TO 1 STEP -1
  90. 401 IF X$(I,I)="," THEN S$=X$(1,I-1):S$(LEN(S$)+1)=" a":S$(LEN(S$)+1)=X$(I+1,LEN(X$)):X$=S$:RETURN
  91. 402 NEXT I
  92. 403 RETURN
  93. 501 DATA kanystr s benzinem,,14,Je na nem napsano:Sheil oil.
  94. 502 DATA sirku,,16,Neni na ni nic zvlastniho.
  95. 503 DATA dopis,,1,nic
  96. 504 DATA vetev,uschlou,2,Neni na ni nic zvlastniho.
  97. 505 DATA vetev,horici,99,Vetev hori.
  98. 506 DATA bednu,,4,Neni na ni nic zvlastniho.
  99. 507 DATA lano,,98,Je dlouhe asi 20m a vypada zachovale.
  100. 508 DATA masku,plynovou,98,Neni na ni nic zvlastniho.
  101. 509 DATA bacpack,,8,Pripomina pusku pripojenou dratem k batohu.Z hlavne vyzaruje svetelny paprsek.
  102. 510 DATA past,,10,Uvnitr je drapak na pruzine.Na stene pasti je zelene tlacitko.
  103. 511 DATA ducha,poletujiciho,13,Vypada docela sympaticky.
  104. 512 DATA filtr,dychaci,20,Neni na nem nic zvlastniho.
  105. 513 DATA kohout na roure,,9,Neni na nem nic zvlastniho.
  106. 514 DATA ropuchu,obrovskou,32,Vypada odporne(jako ty).
  107. 515 DATA paku,drevenou,34,Pohybuje se snadno ve zdi.
  108. 516 DATA diamant,,99,Je prekrasny.Ma mnoho vybrousenych ploch.
  109. 517 DATA masku slunecniho boha,zlatou,37,Ma nevycislitelnou cenu.Ted se musis dostat ven.
  110. 518 DATA truhlicku,bronzovou,99,Uvnitr neco chrasti.
  111. 519 DATA pedal v podlaze,,39,Neni na nem nic zvlastniho.
  112. 520 DATA lano privazane k tramu,,99,Neni na nem zvlastniho.
  113. 521 DATA tlacitko,zelene,10,Neni na nem nic zvlastniho.
  114. 1000 GOSUB 1010:GOTO 1500
  115. 1010 RESTORE X+300:READ M$,X$:IF (X=5 OR X=11) AND P$(31,31)="1" THEN X$(LEN(X$)+1)=" otevrene dvere."
  116. 1020 IF (X=5 OR X=11) AND P$(31,31)="0" THEN X$(LEN(X$)+1)=" zavrene dvere."
  117. 1030 IF X=9 AND P$(32,32)="0" THEN X$(LEN(X$)+1)=" zavrene dvere."
  118. 1040 IF X=9 AND P$(32,32)="1" THEN X$(LEN(X$)+1)=" otevrene dvere."
  119. 1045 IF X=7 AND P$(34,34)="0" THEN X$(LEN(X$)+1)="Zem je pokryta spalenymi hady."
  120. 1050 S=0:FOR I=1 TO 20:IF ASC(P$(I,I))<>X THEN 1100
  121. 1060 S=S+1:IF S=1 THEN X$(LEN(X$)+1)=" Vidis"
  122. 1070 IF S>1 THEN X$(LEN(X$)+1)=","
  123. 1080 RESTORE I+500:READ A$,B$:X$(LEN(X$)+1)=" "
  124. 1085 IF B$>"" THEN X$(LEN(X$)+1)=B$:X$(LEN(X$)+1)=" "
  125. 1090 X$(LEN(X$)+1)=A$
  126. 1100 NEXT I:IF S>1 THEN GOSUB 400
  127. 1102 IF S>0 THEN X$(LEN(X$)+1)="."
  128. 1110 GOSUB 10:X$=""
  129. 1120 IF X=5 AND P$(31,31)="0" THEN M$(2,2)="0"
  130. 1130 IF X=11 AND P$(31,31)="0" THEN M$(1,1)="0"
  131. 1140 IF X=9 AND P$(32,32)="0" THEN M$(6,6)="0"
  132. 1150 IF X=13 AND ASC(P$(11,11))=13 THEN M$(2,2)="0"
  133. 1160 IF X=34 AND P$(33,33)>="(" THEN M$(4,4)="U"
  134. 1170 IF X=35 AND P$(18,18)<>"%" THEN M$(3,3)="0"
  135. 1180 RESTORE 1200
  136. 1190 IF M$="000000" THEN 1499
  137. 1200 DATA na sever,na jih,na zapad,na vychod,nahoru,dolu
  138. 1210 S=0:FOR I=1 TO 6
  139. 1220 A$="":READ A$:IF M$(I,I)="0" THEN 1300
  140. 1230 S=S+1:IF S=1 THEN X$(LEN(X$)+1)="Muzes jit"
  141. 1240 IF S>1 THEN X$(LEN(X$)+1)=","
  142. 1250 X$(LEN(X$)+1)=" ":X$(LEN(X$)+1)=A$
  143. 1300 NEXT I
  144. 1310 IF S>1 THEN GOSUB 400
  145. 1315 IF S>0 THEN X$(LEN(X$)+1)=".":GOSUB 10
  146. 1499 RETURN
  147. 1500 P$(33,33)=" "
  148. 1510 IF X=7 AND P$(34,34)="1" THEN X$="JE TU SPOUSTA JEDOVATYCH HADU.JEDEN Z NICH TE USTKL!!":GOSUB 10:GOTO 9500
  149. 1520 IF X=27 AND (P$(8,8)<>"Z" OR P$(12,12)<>"Z") THEN X$="UDUSIL SES!!":GOSUB 10:GOTO 9500
  150. 1530 IF X=30 AND (NS>1 OR P$(10,10)<>"Z") THEN X$="ZAPADL JSI DO BAZINY!!":GOSUB 10:GOTO 9500
  151. 1540 IF X=15 THEN X$="PAVOUCI TI ZA ZIVA VYRVALI SRDCE!!":GOSUB 10:GOTO 9500
  152. 1550 P$(50+X,50+X)="1"
  153. 2000 IF P$(33,33)<"Z" AND X=34 THEN P$(33,33)=CHR$(ASC(P$(33,33))+1)
  154. 2010 IF X=34 AND P$(33,33)>="(" THEN M$(4,4)="U":X$="BRANA JE OTEVRENA!!":GOSUB 10
  155. 2095 TRAP 2095
  156. 2100 SOUND 1,60,10,8:POKE 764,255:? :POKE 752,0:? "Prikaz";:SOUND 1,0,0,0:INPUT Z$:? :POKE 752,1
  157. 2200 IF LEN(Z$)<1 THEN X$="Nerozumim":GOSUB 10:GOTO 2000
  158. 2250 IF Z$="Pavel Homas" THEN GRAPHICS 0:SETCOLOR 1,1,1:POKE 580,0:STOP
  159. 2300 IF Z$<"a" THEN X$="Prikazy se zadavaji malymi pismeny!":GOSUB 10:GOTO 2100
  160. 2500 IF Z$="Pavel Homas" THEN GRAPHICS 0:STOP
  161. 2502 E$="":F$="":FOR I=1 TO LEN(Z$)
  162. 2510 IF Z$(I,I)=" " THEN E$=Z$(1,I-1):F$=Z$(I+1,LEN(Z$)):GOTO 2600
  163. 2520 NEXT I:E$=Z$
  164. 2550 E$=Z$
  165. 2600 RESTORE 200:E=0:TRAP 40000
  166. 2605 IF E$="" THEN X$="Nerozumim.":GOSUB 10:GOTO 2000
  167. 2610 LET E=E+1:READ Z$:IF Z$="stop" THEN X$="Nerozumim.":GOSUB 10:GOTO 2000
  168. 2615 IF LEN(Z$)<LEN(E$) THEN 2610
  169. 2620 IF Z$(1,LEN(E$))<>E$ THEN 2610
  170. 2640 F=0
  171. 2650 IF F$="" OR F$=" " THEN 3500
  172. 2660 FOR F=1 TO 21:RESTORE 500+F:READ A$,B$:B$(LEN(B$)+1)=" ":IF B$>"" THEN B$(LEN(B$)+1)=A$
  173. 2670 A=LEN(F$):IF A>LEN(B$) THEN 3000
  174. 2680 IF B$(1,A)=F$ THEN Z=1:GOTO 3100
  175. 2800 IF LEN(A$)<A THEN 3000
  176. 2810 IF A$(1,A)=F$ THEN Z=2:GOTO 3100
  177. 3000 NEXT F:F=0:GOTO 3500
  178. 3100 IF F=4 AND Z=2 AND P$(4,4)<>"Z" AND P$(4,4)<>CHR$(X) THEN F=5
  179. 3110 IF F=8 AND Z=2 AND P$(8,8)<>"Z" AND P$(8,8)<>CHR$(X) AND  NOT (P$(8,8)="b" AND (P$(6,6)="Z" OR P$(6,6)=CHR$(X))) THEN F=17
  180. 3115 IF F=7 AND Z=2 AND P$(7,7)<>"Z" AND P$(7,7)<>CHR$(X) AND  NOT (P$(7,7)="b" AND (P$(6,6)="Z" OR P$(6,6)=CHR$(X))) THEN F=20
  181. 3120 IF F>0 THEN RESTORE 500+F:READ A$,B$:F$=B$:F$(LEN(F$)+1)=" ":F$(LEN(F$)+1)=A$
  182. 3500 ?
  183. 3510 GOTO 250+E
  184. 3600 RESTORE 1200:FOR I=1 TO E:READ K$:NEXT I
  185. 3610 IF M$(E,E)="0" THEN X$="Nemuzes jit ":X$(LEN(X$)+1)=K$:X$(LEN(X$)+1)="!":GOSUB 10:GOTO 2000
  186. 3620 ? "O.K.":X$="Jdes ":X$(LEN(X$)+1)=K$:X$(LEN(X$)+1)=".":GOSUB 10:?
  187. 3630 IF X=2 AND E=6 AND P$(20,20)<>CHR$(2) THEN X$="ZABIL SES PADEM Z VYSKY!!":GOSUB 10:GOTO 9500
  188. 3640 X=ASC(M$(E,E))-50:IF X=1 AND E=6 AND P$(6,6)=CHR$(1) THEN GOSUB 12000:GOSUB 10:IF P$(17,17)="Z" THEN 9800
  189. 3650 IF X=1 AND E=6 AND P$(6,6)=CHR$(1) THEN X$="Uklouzl jsi na  skale.Zabil ses padem z vysky.":GOSUB 10:GOTO 9500
  190. 3660 GOTO 1000
  191. 3700 IF F=0 THEN X$="Neni mi jasne,co chces vlastne vzit.":GOSUB 10:GOTO 2000
  192. 3701 IF P$(F,F)="Z" THEN X$="Vzdyt mas ":X$(LEN(X$)+1)=F$:X$(LEN(X$)+1)=" u sebe.":GOSUB 10:GOTO 2000
  193. 3710 IF P$(F,F)=CHR$(X) OR (P$(F,F)="b" AND (P$(6,6)="Z" OR P$(6,6)=CHR$(X))) THEN 3730
  194. 3720 X$="Neni tady!!":GOSUB 10:GOTO 2000
  195. 3730 IF F=11 THEN X$="JAKMILE SES HO DOTKL...AARGH!":GOSUB 10:GOTO 9500
  196. 3740 IF F=13 THEN X$="To nemuzes,je pripevnen k roure.":GOSUB 10:GOTO 2000
  197. 3750 IF F=14 OR F=15 OR F=19 OR F=21 THEN X$="To je nad tve sily.":GOSUB 10:GOTO 2000
  198. 3760 ? "O.K.":X$="Vzal jsi ":X$(LEN(X$)+1)=F$:X$(LEN(X$)+1)=".":GOSUB 10
  199. 3770 IF F=20 THEN P$(20,20)=CHR$(99):F=7
  200. 3780 P$(F,F)="Z":NS=NS+1:GOTO 2000
  201. 3800 IF F=0 THEN X$="Neni mi jasne,co chces vlastne polozit.":GOSUB 10:GOTO 2000
  202. 3810 IF P$(F,F)<>"Z" THEN X$="Nemuzes polozit neco,co u sebe nemas.":GOSUB 10:GOTO 2000
  203. 3815 ? "O.K.":X$="Polozil jsi ":X$(LEN(X$)+1)=F$:X$(LEN(X$)+1)=".":GOSUB 10
  204. 3820 Z=0:IF X=3 THEN X$="Predmet sklouzl do diry v podlaze.":GOSUB 10:P$(F,F)="c":LET Z=1:GOSUB 12010
  205. 3840 NS=NS-1:IF Z=0 THEN P$(F,F)=CHR$(X)
  206. 3850 GOTO 2000
  207. 3900 IF F=0 THEN X$="Neni mi jasne,co chces vlastne prozkoumat.":GOSUB 10:GOTO 2000
  208. 3910 IF P$(F,F)<>CHR$(X) AND P$(F,F)<>"Z" AND  NOT (P$(F,F)="b" AND (P$(6,6)="Z" OR P$(6,6)=CHR$(X))) THEN GOTO 12030
  209. 3915 IF F=3 THEN X$=O$:GOSUB 10:GOTO 2000
  210. 3920 RESTORE 500+F:READ A$,A$,A,A$:? "O.K."
  211. 3930 IF F=3 THEN ? "Cituji:"
  212. 3940 IF F<>6 THEN X$=A$:GOSUB 10:GOTO 2000
  213. 3950 X$="Bedna je vylozena polystyrenem. ":IF P$(7,7)<>"b" AND P$(8,8)<>"b" THEN 3990
  214. 3960 IF P$(7,7)="b" THEN X$(LEN(X$)+1)="Uvnitr je lano.":IF P$(8,8)="b" THEN X$(LEN(X$))=" a plynova maska.":GOTO 3990
  215. 3980 X$(LEN(X$)+1)="Uvnitr je plynova maska."
  216. 3990 GOSUB 10:GOTO 2000
  217. 4000 ? "O.K.":? :GOSUB 1010:GOTO 2000
  218. 4050 IF F=0 THEN X$="Neni mi jasne,co chces vlastne otocit.":GOSUB 10:GOTO 2000
  219. 4060 IF F<>13 OR X<>9 THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  220. 4070 ? "O.K.":? "Otocil jsi kohout.":IF P$(35,35)="0" THEN X$="Nic se nestalo.":GOSUB 10:GOTO 2000
  221. 4080 IF P$(32,32)="0" THEN X$="Z roury zacala tryskat voda.Naplnila celou mistnost.UTOPIL SES!!":GOSUB 10:GOTO 9500
  222. 4090 X$="Z roury zacala tryskat voda,ktera odtekala do diry v zemi.Po nekolika minutach prestala teci."
  223. 4095 P$(35,35)="0":P$(39,39)="1":GOSUB 10:GOTO 2000
  224. 4100 IF F=0 THEN F=97
  225. 4102 IF (P$(10,10)<>"Z" AND P$(10,10)<>CHR$(X)) OR F<>10 THEN 4120
  226. 4105 IF P$(11,11)<>"a" THEN ? "O.K.":? "Otevrel jsi past.":GOTO 2000
  227. 4110 ? "O.K.":? "Otevrel jsi past.":X$="Duch vyletel ven a s hroznym revem zmizel ve strope.":GOSUB 10:GOSUB 12040
  228. 4115 X$="Ropucha se vydesila a utekla na zapad.Zustal zde prekrasny diamant.":GOSUB 10:GOSUB 12060:GOTO 2000
  229. 4120 IF F=18 AND (P$(F,F)="Z" OR P$(F,F)=CHR$(X)) THEN X$="Nemuzes.Truhlicka je zamcena a nemas klic.":GOSUB 10:GOTO 2000
  230. 4125 Z=0:IF X=5 OR X=11 THEN Z=31
  231. 4130 IF X=9 THEN Z=32
  232. 4140 IF Z=0 THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  233. 4142 IF P$(Z,Z)="1" THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  234. 4145 P$(Z,Z)="1":? "O.K.":? "Otevrel jsi dvere.":IF P$(35,35)="0" OR X<>5 THEN GOSUB 1010:GOTO 2000
  235. 4147 X$="ZA DVERMI BYLA OBROVSKA MASA VODY.SRAZILA TE Z LANA!!":GOSUB 10:GOTO 9500
  236. 4150 IF F=10 AND (P$(10,10)="Z" OR P$(10,10)=CHR$(X)) THEN ? "O.K.":? "Zavrel jsi past.":GOTO 2000
  237. 4160 Z=0:IF X=5 OR X=11 THEN Z=31
  238. 4170 IF X=9 THEN Z=32
  239. 4180 IF Z=0 THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  240. 4185 IF P$(Z,Z)="0" THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  241. 4190 ? "O.K.":? "Zavrel jsi dvere.":P$(Z,Z)="0":GOSUB 1010:GOTO 2000
  242. 4200 IF F=0 THEN X$="Neni mi jasne,co chces vlastne stisknout.":GOSUB 10:GOTO 2000
  243. 4210 IF X=39 AND F=19 THEN 4300
  244. 4220 IF P$(10,10)<>"Z" AND P$(10,10)<>CHR$(X) THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  245. 4230 ? "O.K.":? "Stiskl jsi zelene tlacitko.":IF P$(11,11)="a" THEN ? "Nic se nestalo.":GOTO 2000
  246. 4240 X$="Past se otevrela a vyjel z ni drapak.":IF X<>13 OR (X=13 AND P$(11,11)<>CHR$(13)) THEN GOSUB 12070:GOTO 2000
  247. 4250 IF P$(9,9)<>"Z" AND P$(9,9)<>CHR$(13) THEN X$(LEN(X$)+1)="Duch ale v posledni chvili uhnul.":GOSUB 10:GOTO 2000
  248. 4260 X$(LEN(X$)+1)="Duch se pokusil uhnout.Byl zadrzen paprskem z bacpacku.":GOSUB 12080:GOSUB 1010:GOTO 2000
  249. 4300 ? "O.K.":? "Stiskl jsi pedal.":X$="Lokomotiva se rozjela a po chvilce zastavila.":GOSUB 10
  250. 4310 IF P$(36,36)="0" THEN P$(36,36)="1":GOTO 2000
  251. 4320 P$(36,36)="0":GOTO 2000
  252. 4350 IF X<>14 AND X<>16 THEN X$="Neni mi jasne do ceho chces nastoupit.":GOSUB 10:GOTO 2000
  253. 4360 ? "O.K.":? "Nastoupil jsi do lokomotivy.":X=39:GOTO 1000
  254. 4400 IF X<>39 THEN X$="Kdyz nejsi uvnitr,nemuzes vystoupit.":GOSUB 10:GOTO 2000
  255. 4410 ? "O.K.":? "Vystoupil jsi z lokomotivy":X=14+2*VAL(P$(36,36)):GOTO 1000
  256. 4450 ? "O.K":IF NS<=0 THEN ? "Nemas s sebou nic.":GOTO 2000
  257. 4460 I=1:Z=0:FOR I=1 TO 20:IF P$(I,I)<>"Z" THEN 4490
  258. 4465 Z=Z+1:IF Z=1 THEN X$="Mas s sebou"
  259. 4470 IF Z>1 THEN X$(LEN(X$)+1)=","
  260. 4480 RESTORE 500+I:READ B$,A$:X$(LEN(X$)+1)=" "
  261. 4485 IF A$<>"" THEN X$(LEN(X$)+1)=A$:X$(LEN(X$)+1)=" "
  262. 4487 X$(LEN(X$)+1)=B$
  263. 4490 NEXT I:X$(LEN(X$)+1)=".":IF NS>1 THEN GOSUB 400
  264. 4495 GOSUB 10:GOTO 2000
  265. 4500 IF F=0 THEN X$="Neni mi jasne,co chces vlastne privazat.":GOSUB 10:GOTO 2000
  266. 4510 IF (P$(7,7)<>"Z" AND P$(7,7)<>CHR$(X)) OR X<>2 OR F<>7 THEN ? "To bohuzel nemuzes.":GOTO 2000
  267. 4520 ? "O.K":? "Privazal jsi lano k tramu.":NS=NS-1:P$(7,7)="c":P$(20,20)=CHR$(2):GOTO 2000
  268. 4600 IF X<>2 OR P$(20,20)<>CHR$(2) THEN ? "To bohuzel nemuzes.":GOTO 2000
  269. 4610 ? "O.K.":? "Odvazal jsi lano od tramu.":P$(20,20)="c":P$(7,7)=CHR$(2):GOTO 2000
  270. 4650 IF F=0 THEN X$="Neni mi jasne,co chces vlastne zapalit.":GOSUB 10:GOTO 2000
  271. 4660 IF F=2 AND (P$(F,F)="Z" OR P$(F,F)=CHR$(X)) THEN NS=NS-1:? "O.K.":GOSUB 12100:GOSUB 10:P$(2,2)="c":GOTO 2000
  272. 4665 IF P$(2,2)<>"Z" AND P$(2,2)<>CHR$(X) THEN X$="Nemuzes.Nemas sirky.":GOSUB 10:GOTO 2000
  273. 4670 IF F<>4 OR (P$(F,F)<>"Z" AND P$(F,F)<>CHR$(X)) THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  274. 4675 IF P$(4,4)<>"Z" THEN NS=NS+1
  275. 4680 P$(2,2)="c":NS=NS-1:? "O.K.":? "Zapalil jsi vetev sirkou.":P$(4,4)="c":P$(5,5)="Z":GOTO 2000
  276. 4700 IF F=0 THEN X$="Neni mi jasne,co chces vlastne vlozit.":GOSUB 10:GOTO 2000
  277. 4710 IF F<>16 OR X<>33 OR (P$(16,16)<>"Z" AND P$(16,16)<>CHR$(X)) THEN X$="To bohuzel nemuzes.":GOSUB 10:GOTO 2000
  278. 4720 ? "O.K.":X$="Vlozil si diamant do prohlubne v oltari.":GOSUB 10:P$(16,16)=CHR$(33)
  279. 4730 IF P$(18,18)<>"c" THEN ? "Nic se nestalo.":GOTO 2000
  280. 4740 X$="Slunecni paprsek dopadl na diamant.Ze stropu vypadla mala truhlicka!!":GOSUB 10:P$(18,18)=CHR$(33):GOTO 2000
  281. 4800 ZZ=1
  282. 4810 GOSUB 9205:GOTO 2000
  283. 4900 ? "Chces opravdu nahrat pozici(a/n)?"
  284. 4910 IF PEEK(764)=35 THEN GOTO 2000
  285. 4920 IF PEEK(764)<>63 THEN 4910
  286. 4930 ? "Stiskni PLAY"
  287. 4940 OPEN #4,4,0,"C:"
  288. 4950 INPUT #4;P$
  289. 4960 CLOSE #4:SOUND 1,0,0,0
  290. 4970 NS=ASC(P$(99,99)):X=ASC(P$(98,98))
  291. 4980 GOTO 2000
  292. 5000 ? "Stiskni PLAY+RECORD "
  293. 5005 P$(98,98)=CHR$(X):P$(99,99)=CHR$(NS)
  294. 5010 OPEN #4,8,0,"C:"
  295. 5020 INPUT #4,P$
  296. 5030 CLOSE #4:SOUND 1,0,0,0:GOTO 2000
  297. 5100 ? "Opravdu chces skoncit?"
  298. 5110 IF PEEK(764)=63 THEN 9505
  299. 5120 IF PEEK(764)=35 THEN 2100
  300. 5130 GOTO 5110
  301. 9100 REM DOPIS
  302. 9101 O$="Drahy Indiana Jonesi! Za tu dobu, co jsi byl v Egypte doslo k nekolika zajimavym udalostem:"
  303. 9102 O$(LEN(O$)+1)="V Amazonskem pralese objevili pri tezbe uhli rozsahly podzemni komplex. Beloq se to "
  304. 9103 O$(LEN(O$)+1)="rozjel prozkoumat, ale potom byl rad ze vyvazl se zdravou kuzi! Podarilo se mi z nej vytahnout"
  305. 9104 O$(LEN(O$)+1)=", ze v tom jsou zapojeny nadprirozene sily. Zustalo zde vybaveni po nejakych chlapicich, ktere"
  306. 9105 O$(LEN(O$)+1)=" by se ti mohlo hodit. Ze svitku v me sbirce jsem zjistil, ze se tomu komplexu kdysi rikalo "
  307. 9106 O$(LEN(O$)+1)="CHRAM ZKAZY a ze je v nem ukryta zlata maska slunecniho boha!!"
  308. 9107 O$(LEN(O$)+1)="Mnoho stesti ti preje                                   Abner."
  309. 9110 DIM P$(99)
  310. 9120 FOR I=1 TO 99:P$(I,I)=" ":NEXT I
  311. 9130 I=1:RESTORE 500:FOR I=1 TO 20:READ A$,A$,A,A$:P$(I,I)=CHR$(A):NEXT I
  312. 9140 P$(31,31)="0":P$(32,32)="0":P$(32,32)="0":P$(33,33)=" ":P$(34,34)="1":P$(35,35)="1":P$(36,36)="0"
  313. 9142 RETURN
  314. 9145 ? "}":? :POKE 752,1:? "           Ăčňáí úëáúů"
  315. 9150 ? "           FUXOFT 1985     "
  316. 9155 ? "          Frantisek Fuka    "
  317. 9160 ? :? :? "          ATARI version"
  318. 9162 ? :? "           Tomas Havel":IF NH=1 THEN GOSUB 9120
  319. 9163 IF NH=0 THEN GOSUB 9100
  320. 9164 POKE 764,255:? :? :? :? "Klavesu":X=1
  321. 9165 RESTORE 14000
  322. 9170 READ C$:IF C$="-1" THEN 9165
  323. 9172 FOR I=1 TO VAL(C$(LEN(C$)))
  324. 9175 SOUND 1,VAL(C$(1,LEN(C$)-1)),14,8:FOR J=1 TO 5:NEXT J
  325. 9185 IF PEEK(764)<255 THEN ? "}":POP :SOUND 1,0,0,0:GOSUB 9205:GOTO 1000
  326. 9189 NEXT I:SOUND 1,0,0,0:FOR PAU=1 TO 3:NEXT PAU
  327. 9190 GOTO 9170
  328. 9205 ? "Prikazy(forma):SLOVESO-POD.JM"
  329. 9206 ? "               jen SLOVESO"
  330. 9210 ? "Pohyb:S,J,Z,V,N,D(s-sever,d-dolu)"
  331. 9220 ? "Spec.prikazy:I-vypise predmety"
  332. 9230 ? "             R-popis mistnosti"
  333. 9240 ? "             SAVE-ulozi pozici"
  334. 9250 ? "             LOAD-nahraje pozici"
  335. 9251 ? "Nevite-li si rady pouzijte prikaz     POMOC nebo PROZKOUMEJ."
  336. 9252 ? "Prikazy pis malymi pismeny"
  337. 9260 SOUND 1,60,10,8:POKE 764,255:? :? "Klavesu":SOUND 1,0,0,0
  338. 9270 IF PEEK(764)<>255 THEN RETURN
  339. 9280 GOTO 9270
  340. 9500 SOUND 1,60,10,8:POKE 764,255:? "JSI MRTEV!!":? "Klavesu":SOUND 1,0,0,0
  341. 9501 SH=PEEK(764):IF SH=88 THEN 2100
  342. 9502 IF PEEK(764)<>255 THEN ? "}":GOTO 13000
  343. 9503 GOTO 9501
  344. 9504 ? :? :? "Zde lezi Indiana Jones."
  345. 9505 S=0:FOR I=51 TO 90:IF P$(I,I)="1" THEN S=S+1:NEXT I
  346. 9506 S=S/38*95:S=INT((S*10+0.5)/10)
  347. 9507 IF P$(17,17)<>CHR$(37) THEN S=S+2.5
  348. 9508 ? :? :? "Zvladl jsi ";S;"% hry "
  349. 9509 SOUND 1,60,10,8:POKE 764,255:? :? :? :? :? "Klavesu":SOUND 1,0,0,0
  350. 9510 IF PEEK(764)<255 THEN NH=1:GOTO 9145
  351. 9515 GOTO 9510
  352. 9800 GOSUB 12200:? "}":POSITION 10,10:? " ˇˇˇÚöéôĺúéě ęó顡ˇ "
  353. 9810 POSITION 10,11:? "  úéóëáě ęóé úěáôďő "
  354. 9820 POSITION 10,12:? "       íáóëő        "
  355. 9830 POSITION 10,13:? "         á          "
  356. 9840 POSITION 10,14:? "     őîéëě ęóé      "
  357. 9850 POSITION 10,15:? "         ú          "
  358. 9860 POSITION 10,16:? "    ĂČŇÁÍŐ ÚËÁÚŮ    "
  359. 9890 SOUND 1,60,10,8:? :? :? "Ëěáöĺóő":POKE 764,255:SOUND 1,0,0,0
  360. 9900 IF PEEK(764)<>255 THEN RUN
  361. 9910 GOTO 9900
  362. 10000 END
  363. 12000 X$="Uklouzl jsi na hladke skale.Mas stesti.Spadl jsi do bedny s polystyrenem.":RETURN
  364. 12010 IF F=5 AND P$(1,1)="c" AND P$(34,34)="1" THEN X$="Podlaha se otrasla vybuchem.":GOSUB 10:P$(34,34)="0"
  365. 12020 RETURN
  366. 12030 X$="Neni tady.":GOSUB 10:GOTO 2000
  367. 12040 P$(11,11)="c":IF X<>32 OR P$(14,14)<>" " THEN POP :GOTO 2000
  368. 12050 RETURN
  369. 12060 P$(14,14)="c":P$(16,16)=" ":RETURN
  370. 12070 X$(LEN(X$)+1)="Drapak zajel zpet a past se zavrela.":GOSUB 10:RETURN
  371. 12080 X$(LEN(X$)+1)="Drapak zajel s duchem do pasti.Past se zavrela.":GOSUB 10:P$(11,11)="a":RETURN
  372. 12100 X$="Sirka vzplala a za chvili zhasla.":RETURN
  373. 12200 SOUND 1,60,10,8:POKE 764,255:? "Klavesu":SOUND 1,0,0,0
  374. 12210 IF PEEK(764)<>255 THEN RETURN
  375. 12220 GOTO 12210
  376. 13000 ? "              |   "
  377. 13001 ? "               "
  378. 13002 ? "              |  "
  379. 13003 ? "             | "
  380. 13004 ? "               "
  381. 13005 ? "           
  382.  
  383.    "
  384. 13006 ? "            
  385.  
  386. "
  387. 13007 GOTO 9504
  388. 14000 DATA 644,644,534,534,533,604,603,533,604,603,724,724,604,604,603,644,643,603,644,643
  389. 14010 DATA 814,814,644,644,643,724,723,643,724,723,534,1084,964,914,813,914,913,723,814,813,-1
  390. 14020 DATA 2435,2435,2432,2433,2045,2173,2173,2433,2433,2173,2435,02,-1
RAW Paste Data

Adblocker detected! Please consider disabling it...

We've detected AdBlock Plus or some other adblocking software preventing Pastebin.com from fully loading.

We don't have any obnoxious sound, or popup ads, we actively block these annoying types of ads!

Please add Pastebin.com to your ad blocker whitelist or disable your adblocking software.

×