prontera,155,181,5	script	Sample#freebie	757,{
if( getgmlevel() >= .GMLevel )
	mes "Hello GM '"+strcharinfo(0)+"' Do you want to manage the Freebies Application?";
else
	mes "How can i help you ?";
next;
switch( select( "Freebies Informations",
				"Apply for Freebies",
				( getgmlevel() < .GMLevel )?"":"^0055FF[ GM ]^000000 Manage Freebies" )){
	Case 1:
		mes "We have a freebies unique system, you will receive a 1st Pack in limited time, and when you complete the process you will receive another freebies which make you more stronger!.";
		next;
		mes "You can ^FF0000only register once and apply one character per account^000000 the items are not tradable.";
		next;
		mes "^FF0000NOTE:^000000 If we found that your abusing this system all of your Account will get punished.";
		break;
	Case 2:
		query_sql( "SELECT `status` FROM `E-Freebies` WHERE `account_id` = '"+getcharid(3)+"'",.@Status );
		switch( .@Status ){
			Case 0:
				mes "Do you want to apply for freebies?, you need to register your name here!";
				input .@Name$;
				if( .@Name$ == strcharinfo(0) ){
					mes "Thanks you are now registered to our freebies system!";
					query_sql( "SELECT `last_ip` FROM `login` WHERE `account_id`='"+getcharid(3)+"'",.@IP$ );
					query_sql( "INSERT INTO `E-Freebies` VALUES ( '"+getcharid(3)+"','"+strcharinfo(0)+"','1','1','"+.@IP$+"' )" );
					next;
					mes "Here's your freebies, when you spent ^FF0000another 24 hours^000000 playing you will receive another freebies!";
					for( set .@i,0; .@i < getarraysize( .Freebies1 ) - 1; set .@i,.@i + 2 )
						getitem .Freebies1[.@i],.Freebies1[.@i+1];
					addtimer 60000,strnpcinfo(0)+"::OnMinuteCheck";
					next;
					mes "Remember 24 hours playing without ^FF0000Vending^000000 will receive another Pack!";
				}else{
					mes "You can't register any other person than yourself in this System.";
				}
				break;
			Case 1:
				query_sql( "SELECT `time` FROM `E-Freebies` WHERE `account_id` = '"+getcharid(3)+"'",.@OnlineTime );
				if( .@OnlineTime < 86400 ){
					mes "You've been online for ^0055FF"+( .@OnlineTime / 3600 )+"^000000 hours and you have about ^FF0000"+( ( 86400 - .@OnlineTime ) / 3600 )+"^000000 hours left! to get the special package.";
				}else{
					mes "It looks like you've that your Newbie Test verywell, i would like you to give a warm welcome!";
					if( select("Claim Freebies:Maybe Later....") == 1 ){
						announce "Lets welcome give a warm welcome to our new server '"+strcharinfo(0)+"' for being active in server",0;
						for( set .@i,0; .@i < getarraysize( .Freebies1 ) - 1; set .@i,.@i + 2 )
							getitem .Freebies2[.@i],.Freebies2[.@i+1];
						query_sql( "SELECT `last_ip` FROM `login` WHERE `account_id`='"+getcharid(3)+"'",.@IP$ );
						query_sql("UPDATE `E-Freebies` SET `status`='2',`last_ip`='"+.@IP$+"' WHERE `account_id`='"+getcharid(3)+"'");
					}
				}
				break;
			Case 2:
				mes "You have collected all the freebies.";
				break;
			Case 3:
				mes "Your Freebies Application has been denied.";
			default: break;
			}
		break;
	Case 3:
		query_sql( "SELECT `name`,`status` FROM `E-Freebies` WHERE `status`<> 2 ORDER BY `status` ASC LIMIT 100",.@Name$,.@Status );
		mes "These are the player who have apply for freebies package but not yet completed.";
		mes "Total of "+getarraysize( .@Name$ )+" Records found.";
		if( getarraysize( .@Name$ ) <= 0 ) close;
		for( set .@i,0; .@i < getarraysize( .@Name$ ); set .@i,.@i + 1 )
			set .@Menu$,.@Menu$ +( ( .@Status[.@i] == 1 )?"^00EE55[ Pending ]":( .@Status[.@i] == 3 )?"^FF0000[ Denied ]":"^0055FF[ Approved ]" )+"^000000 "+.@Name$[.@i]+"^000000"+":";
		next;
		set .@i,( select( .@Menu$ ) - 1 );
		mes "Player Name : ^0055FF"+.@Name$[.@i]+"^000000";
		mes "Status : "+( ( .@Status[.@i] == 1 )?"^00EE55[ PENDING ]":( .@Status[.@i] == 3 )?"^FF0000[ DENIED ]":"^0055FF[ APPROVED ]" )+"^000000";
		set .@Option,select( ( .@Status[.@i] != 2 )?"Approve Application":"",( .@Status[.@i] == 1 )?"Deny Application":"",( .@Status[.@i] == 2 )?"":"Delete Application");
		switch( .@Option ){
			Case 1: query_sql("UPDATE `E-Freebies` SET `status`='1',`time`='86400' WHERE `name`='"+.@Name$[.@i]+"'"); break;
			Case 2: query_sql("UPDATE `E-Freebies` SET `status`='3',`time`='0' WHERE `name`='"+.@Name$[.@i]+"'"); break;
			Case 3: query_sql("DELETE FROM `E-Freebies` WHERE `name`='"+.@Name$[.@i]+"'"); break;
		}
		mes "Application ^0055FF"+( ( .@Option == 1 )?"Approved":( ( .@Option == 2 )?"Denied":"Deleted" ))+"^000000";
		if( isloggedin( .@ID[.@i] ) ){
			message .@Name$[.@i],"Your Freebies Packages has been "+( ( .@Option == 1 )?"Approved":( ( .@Option == 2 )?"Denied":"Deleted" ) )+" by GM '"+strcharinfo(0)+"'";
		}
		break;
}
close;

OnInit:
set .GMLevel,90;
// Freebies Pack 1
setarray .Freebies1[0],512,10,607,1,608,2;
// Freebies Pack 2
setarray .Freebies2[0],512,20,607,10,608,20;
end;


OnMinuteCheck:
if( !checkchatting() && !checkvending() )
	set @Online,@Online + 60;
	if( @Online >= 86400 ){
		message strcharinfo(0),"You have online for 24 hours and you may get the freebies again.";
	}
	else
		addtimer 60000,strnpcinfo(0)+"::OnMinuteCheck";
end;

OnPCLoginEvent:
query_sql( "SELECT `status`,`time` FROM `E-Freebies` WHERE `account_id` = '"+getcharid(3)+"' AND `status`='1'",.@Status,@Online );
if( @Online && @Online < 86400 ){
	addtimer 60000,strnpcinfo(0)+"::OnMinuteCheck";
}
end;

OnPCLogoutEvent:
query_sql( "SELECT `time` FROM `E-Freebies` WHERE `account_id` = '"+getcharid(3)+"' AND `status`='1'",.@Online2 );
if( @Online >= .@Online2 )
	query_sql( "UPDATE `E-Freebies` SET `time`='"+@Online+"' WHERE `account_id` = '"+getcharid(3)+"'" );
end;
}