Batch - Smooth Window Grow (ideal for games)

@ECHO OFF
SETLOCAL EnableDelayedExpansion
TITLE Smooth Window Grow - Testing
REM Implemented:
REM     Horizontal window grow or shrink
REM Not implemented
REM     Vertical window grow or shrink
REM     Parallel horiz. & vertic. window grow or shrink
SET "DefaultWidth=80"
SET "DefaultHeight=25"

MODE !DefaultWidth!,!DefaultHeight!

:SmoothWindowGrowth
CLS
IF NOT DEFINED OldWidth (
    ECHO.Current width:  !DefaultWidth!
    ECHO.Current height: !DefaultHeight!
) ELSE (
    ECHO.Current width:  !OldWidth!
    ECHO.Current height: !OldHeight!
)
SET /P "NewWidth=Please enter a new window width: "
IF NOT DEFINED OldWidth (
    IF "!NewWidth!"=="!DefaultWidth!" (
        ECHO.No action needed.
        GOTO :SmoothWindowGrowth
    )
) ELSE IF "!NewWidth!"=="!OldWidth!" (
    ECHO.No action needed.
    GOTO :SmoothWindowGrowth
)
IF NOT DEFINED OldWidth (
    IF !NewWidth! GTR !DefaultWidth! (
        SET "ArithmeticStep=1"
    ) ELSE (
        SET "ArithmeticStep=-1"
    )
) ELSE (
    IF !NewWidth! GTR !OldWidth! (
        SET "ArithmeticStep=1"
    ) ELSE (
        SET "ArithmeticStep=-1"
    )
)
IF NOT DEFINED OldWidth (
    FOR /L %%A IN (!DefaultWidth!,!ArithmeticStep!,!NewWidth!) DO (
        MODE %%A,!DefaultHeight!
        TITLE ^<-%%A-^> - Smooth Window Grow - Testing
    )
)
IF DEFINED OldWidth (
    FOR /L %%A IN (!OldWidth!,!ArithmeticStep!,!NewWidth!) DO (
        MODE %%A,!DefaultHeight!
        TITLE ^<-%%A-^> - Smooth Window Grow - Testing
    )
)
IF NOT DEFINED NewHeight (
    SET "OldHeight=!DefaultHeight!"
) ELSE (
    SET "OldHeight=!NewHeight!"
)
IF NOT DEFINED NewWidth (
    SET "OldWidth=!DefaultWidth!"
) ELSE (
    SET "OldWidth=!NewWidth!"
)
GOTO :SmoothWindowGrowth