MW5 absolute joystick

#NoEnv
#MaxHotkeysPerInterval 99000000
#HotkeyInterval 99000000
#KeyHistory 0
ListLines Off
Process, Priority, , A
SetBatchLines, -1
SetKeyDelay, -1, -1
SetMouseDelay, -1
SetDefaultMouseSpeed, 0
SetWinDelay, -1
SetControlDelay, -1
SendMode Input

JOYSTICK_ID := "1Joy"
MOUSE_PER_JOYSTICK := 15
MAX_MOUSE_MOVE := 40
INVERT_Y := true
DEADZONE_Xpos := 1
DEADZONE_Xneg := 1
DEADZONE_Ypos := 1
DEADZONE_Yneg := 1

y_multiplier := INVERT_Y ? -1 : 1
Xaxis := JOYSTICK_ID "V", Yaxis := JOYSTICK_ID "Y"
Xcurrent := 50 * MOUSE_PER_JOYSTICK, Ycurrent := 50 * MOUSE_PER_JOYSTICK
reset_ok := true
active := true

Loop {

    WinGetTitle, activeWindowTitle, A

    if (active and InStr(activeWindowTitle, "MW5Mercs")) {
        Xjoy := GetKeyState(Xaxis), Yjoy := GetKeyState(Yaxis)

        if (Xjoy > 50 and DEADZONE_Xpos > 0) {
            if (Xjoy <= 50+DEADZONE_Xpos) {
                Xjoy := 50
            } else {
                Xjoy := 50 + (100-50)* (Xjoy-(50+DEADZONE_Xpos))/(100 - (50+DEADZONE_Xpos))
            }
        }

        if (Xjoy < 50 and DEADZONE_Xneg > 0) {
            if (Xjoy >= 50-DEADZONE_Xneg) {
                Xjoy := 50
            } else {
                Xjoy := Xjoy / (50-DEADZONE_Xneg) * 50
            }
        }

        if (Yjoy > 50 and DEADZONE_Ypos > 0) {
            if (Yjoy <= 50+DEADZONE_Ypos) {
                Yjoy := 50
            } else {
                Yjoy := 50 + (100-50)* (Yjoy-(50+DEADZONE_Ypos))/(100 - (50+DEADZONE_Ypos))
            }
        }

        if (Yjoy < 50 and DEADZONE_Yneg > 0) {
            if (Yjoy >= 50-DEADZONE_Yneg) {
                Yjoy := 50
            } else {
                Yjoy := Yjoy / (50-DEADZONE_Yneg) * 50
            }
        }

        Xoffset := round(Xjoy * MOUSE_PER_JOYSTICK) - Xcurrent, Yoffset := round(Yjoy * MOUSE_PER_JOYSTICK) - Ycurrent
        Xoffset := abs(Xoffset) > MAX_MOUSE_MOVE ? (Xoffset > 0 ? MAX_MOUSE_MOVE : -1 * MAX_MOUSE_MOVE) : Xoffset, Yoffset := abs(Yoffset) > MAX_MOUSE_MOVE ? (Yoffset > 0 ? MAX_MOUSE_MOVE : -1 * MAX_MOUSE_MOVE) : Yoffset

        Xcurrent += Xoffset, Ycurrent += Yoffset
        DllCall("mouse_event", uint, 1, int, Xoffset, int, Yoffset * y_multiplier, uint, 0, int, 0)
        if (reset_ok and Xjoy > 46 and Xjoy < 54 and Yjoy > 46 and Yjoy < 54) {
            Send c
            reset_ok := false
            SetTimer, UnlockReset, -500
        }
        Sleep 1
    } else {
        Sleep 1000
    }
}

F12::active := !active

UnlockReset:
    reset_ok := true
    return