Fulcrum for Tri-leg Stool

include <BOSL/constants.scad>
use <BOSL/masks.scad>

leg_angle = 45;
leg_diameter = 13;
leg_clearance = 0.6;
cordage_diameter = 2.5;
height = 6;
diam = 52;

translate([0,0,height/2])
difference() {
    difference() {
        cylinder(h=height, d=diam, center=true, $fn=200);
        translate([0,0,height/2]) #fillet_cylinder_mask(r=diam/2, fillet=1.5, $fn=200);
        rotate([180,0,0]) translate([0,0,height/2]) #fillet_cylinder_mask(r=diam/2, fillet=1.5, $fn=200);
        rotate_extrude(convexity=10, $fn=200) translate([diam/2 + 0.7, 0, 0]) circle(d=2, $fn=20);
    }

    union() {
        for (r = [0 : 120 : 240]) {
            rotate([0,0,r]) {
                for (i = [0 : 5 : leg_angle]){
                    translate([14,0,0]) rotate([-i,0,0]) cylinder(h=40, d=leg_diameter + leg_clearance, center=true, $fn=50);
                }
                // hole to reduce weight
                translate([-18,0,0]) rotate([leg_angle,0,0]) cylinder(h=40, d=8, center=true, $fn=50);
                // hole for cordage to secure to legs
                translate([0,0,0]) rotate([-90,0,90]) cylinder(h=200, d=cordage_diameter, center=true, $fn=50);
            }
        }

        // hole to reduce weight
        cylinder(h=40, d=8, center=true, $fn=50);
    }
}