uefi32.ld

/* Heavily modified default linker script, for UEFI executables */
/* Copyright (C) 2014-2018 Free Software Foundation, Inc.
   Copying and distribution of this script, with or without modification,
   are permitted in any medium without royalty provided the copyright
   notice and this notice are preserved.  */
OUTPUT_FORMAT(pei-i386)
SECTIONS
{
  /* Make the virtual address and file offset synced if the alignment is
     lower than the target page size. */
  . = SIZEOF_HEADERS;
  . = ALIGN(__section_alignment__);
  .text  __image_base__ + ( __section_alignment__ < 0x1000 ? . : __section_alignment__ ) :
  {
    *(.text)
  }
  .data BLOCK(__section_alignment__) :
  {
    *(.data)
  }
  .rdata BLOCK(__section_alignment__) :
  {
    *(.rdata)
  }
  /* TODO: does UEFI handle .bss correctly? */
  .bss BLOCK(__section_alignment__) :
  {
    __bss_start__ = . ;
    *(.bss)
    *(COMMON)
    __bss_end__ = . ;
  }
  /DISCARD/ :
  {
    *(.pdata*)
	*(.edata)
  }
  .reloc BLOCK(__section_alignment__) :
  {
    *(.reloc)
  }
}