20_betterpistols.dec

actor " B-Pistols ": DoomWeapon
{
    Weapon.SelectionOrder 1500
    Weapon.AmmoUse1 1
    Weapon.AmmoUse2 6
    Weapon.AmmoGive 20
    Weapon.AmmoType1 "DakkaBullet_10mm"
    Weapon.AmmoType2 "DakkaBullet_10mm"

    +UNDROPPABLE

    Decal BulletChip

    Inventory.PickupMessage "$DAKKA_PK_PISTOLS"
    Obituary "$DAKKA_MP_PISTOLS"

    States
    {
      Select:
        BPKP D 0 A_JumpIfInventory(" B-Pistol ", 1, 2)
        BPKP D 0 A_GiveInventory(" B-Pistol ")

        BPKP DD 0 A_Raise
        BPKP D 1 A_Raise
        loop

      Deselect:
        BPKP CCC 0 A_Lower
        BPKP C 1 A_Lower
        loop

      Ready:
        BPKP A 1 A_WeaponReady
        loop

      Fire:
        BPKP F    0 A_PlaySound("betterdoomweapons/pistolfire", 5)
        BPKP F    0 A_FireBullets(4, 2.5, -1, 12, "DakkaPuff", FBF_NORANDOM | FBF_USEAMMO)
        BPKP F    0 A_GiveInventory("GiveScrapCounter", 500)
        BPKP F 0 ACS_ExecuteAlways(467, 0, -45, 2, 5)
        BPKP G 1 bright A_Light2
        BPKP H 1 bright A_Light0
        //BPKP I 1 bright A_Light0
        BPKP I 0 A_JumpIfNoAmmo("NoFire")
        BPKP I 0 A_JumpIfInventory("MainFired", 1, "Fire2")
        goto NoFire

      NoFire:
        BPKP V 0 A_ReFire
        BPKP V 2 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP W 0 A_ReFire
        BPKP W 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP X 0 A_ReFire
        BPKP X 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP Y 0 A_ReFire
        BPKP Y 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        goto Ready

      Fire2:
        BPKP J 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP I 0 A_JumpIfNoAmmo("NoFire")
        BPKP I 0 A_JumpIfInventory("MainFired", 1, 1)
        goto NoFire

        BPKP K    0 A_PlaySound("betterdoomweapons/pistolfire", 6)
        BPKP K    0 A_FireBullets(4, 2.5, -1, 12, "DakkaPuff", FBF_NORANDOM | FBF_USEAMMO)
        BPKP F    0 A_GiveInventory("GiveScrapCounter", 500)
        BPKP F 0 ACS_ExecuteAlways(467, 0, -45, 2, 5)
        BPKP K 1 bright A_Light2
        BPKP L 1 bright A_Light1
        BPKP M 0 bright A_Light0
        BPKP MN 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
        BPKP I 0 A_JumpIfNoAmmo("NoHold")
        BPKP O 0 A_ReFire
        BPKP O 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP P 0 A_ReFire
        BPKP P 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP Q 0 A_ReFire
        BPKP Q 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP R 0 A_ReFire
        BPKP R 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        goto Ready

      NoHold:
        BPKP Q 0 A_ReFire
        BPKP Q 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        BPKP R 0 A_ReFire
        BPKP R 1 A_WeaponReady(WRF_NOBOB | WRF_NOPRIMARY)
        goto Ready

      Hold:
        BPKP T    0 A_PlaySound("betterdoomweapons/pistolfire", 5)
        BPKP T    0 A_FireBullets(4, 2.5, -1, 12, "DakkaPuff", FBF_NORANDOM | FBF_USEAMMO)
        BPKP F    0 A_GiveInventory("GiveScrapCounter", 500)
        BPKP F 0 ACS_ExecuteAlways(467, 0, -45, 2, 5)
        BPKP T 1 bright A_Light2
        BPKP U 1 bright A_Light1
        BPKP U 0 A_Light0
        BPKP I 0 A_JumpIfNoAmmo("NoFire")
        BPKP I 0 A_JumpIfInventory("MainFired", 1, "Fire2")
        goto NoFire

      AltFire:
        BPKP F    0 A_PlaySound("betterdoomweapons/pistolaltfire", 5, 0.7)
        BPKP F    0 A_PlaySound("betterdoomweapons/pistolaltfire", 6, 0.7)
        BPKP F    0 A_FireBullets(15, 10, 8, 12, "DakkaPuff", FBF_NORANDOM | FBF_USEAMMO)
        BPKP F    0 A_GiveInventory("GiveScrapCounter", 4000)
        BPKP F    0 ACS_ExecuteAlways(467, 0, 5, 3, 11)
        BPKP FD 1 bright A_Light2
        BPKP E 2 A_Light1
        BPKP E 6 A_Light0
        BPKP D 3 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
        BPKP C 2 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
        BPKP B 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
        goto Ready


      Spawn:
        PIST A -1
        stop
    }
}