2.bat

@echo off
rem http://vijay.axham.com/blog/498/building-ogre3d-1-8-1-on-mingw
rem http://forums.qhimm.com/index.php?topic=15060.0

set home=%cd%
set "path=%home%\cmake-2.8.11.2-win32-x86\bin;%path%"

@echo Fetch the source code.
set "hg_url=ssh://hg@bitbucket.org/cabalistic/ogredeps"
set "OGRE_SOURCE_DIR=%home%\ogre\v1-8"
mkdir "%OGRE_SOURCE_DIR%"
cd /D %OGRE_SOURCE_DIR%
hg clone %hg_url%
cd /D %home%
set "OGREDEPS_SOURCE_DIR=%OGRE_SOURCE_DIR%\ogredeps"
rem @pause
@echo Set up some environment vars and build the deps:
set "BUILD_OUTPUT_DIR=%home%\build\output"
set "OGRE_OUTPUT_DIR=%BUILD_OUTPUT_DIR%\ogre\v1-8"
set "OGREDEPS_OUTPUT_DIR=%OGRE_OUTPUT_DIR%\ogredeps"
set "BUILD_INSTALL_DIR=%home%\build\install"
set "OGREDEPS_INSTALL_DIR=%BUILD_INSTALL_DIR%\ogredeps"
mkdir "%OGREDEPS_OUTPUT_DIR%"
cd /D %OGREDEPS_OUTPUT_DIR%

echo :Start of Log:> %home%\ogredeps.log
@echo if you’re using MinGW without MSYS:
set "CMAKE_BUILD_TYPE=Debug"
:afterbuildtype
cmake "%OGREDEPS_SOURCE_DIR%" -G "MinGW Makefiles" -DCMAKE_BUILD_TYPE:STRING="%CMAKE_BUILD_TYPE%" >> %home%\ogredeps.log
mingw32-make -j >> %home%\ogredeps.log
mkdir "%BUILD_INSTALL_DIR%"
mingw32-make -j install >> %home%\ogredeps.log
rem move /Y ogredeps "%OGREDEPS_INSTALL_DIR%"
robocopy ogredeps "%OGREDEPS_INSTALL_DIR%" /E /IS /MOVE
rem rmdir /S /Q ogredeps
if not %CMAKE_BUILD_TYPE% == Release (
    set "CMAKE_BUILD_TYPE=Release"
    goto afterbuildtype
)
cd /D %home%
echo set "OGRE_DEPENDENCIES_DIR=%OGREDEPS_INSTALL_DIR%" > %home%\ogredeps_home.bat
echo setx OGRE_DEPENDENCIES_DIR %OGREDEPS_INSTALL_DIR% >> %home%\ogredeps_home.bat
call %home%\ogredeps_home.bat