Shader "Lightning/Erosion"
{
	Properties
	{
		[HDR] _Color("Color", Color) = (1,1,1,1)
		_ErosionTex("Erosion Texture", 2D) = "white" {}
		_Threshold("Threshold", Range(0,1)) = 0
		_Smoothing("Smoothing", Range(0,1)) = 0
	}
	SubShader
	{
		Tags
		{
			"Queue" = "Transparent"
		}

		ZWrite Off
		Blend One One

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float4 uv : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float2 uv : TEXCOORD0;
			};

			sampler2D _ErosionTex;
			float4 _ErosionTex_ST;

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _ErosionTex);
				return o;
			}

			float4 _Color;
			float _Threshold;
			float _Smoothing;

			fixed4 frag (v2f i) : SV_Target
			{
				float4 col = tex2D(_ErosionTex, i.uv);

				float alpha = smoothstep(_Threshold - _Smoothing, _Threshold + _Smoothing, col.r);

				return _Color * alpha;
			}
			ENDCG
		}
	}
}