dialog Settings {
  title "interSys Script Settings"
  size -1 -1 108 142
  option dbu
  box "Q Auth", 1, 4 2 100 60
  text "Username:", 2, 8 10 29 8
  text "Password:", 3, 8 22 29 8
  edit "", 4, 42 10 58 10
  edit "", 5, 42 22 58 10, pass
  button "Connect", 6, 8 34 43 12
  button "Hide IP", 7, 56 34 43 12
  check "Auto Connect", 8, 8 48 42 10, left
  check "Auto Hide IP", 9, 56 48 42 10, left
  box "Auto join channels", 10, 4 62 100 78
  list 11, 8 70 56 58, size
  button "Add", 12, 68 70 31 10
  button "Rem.", 13, 68 82 31 10
  button "Clear", 14, 68 94 31 10
  check "Auto join channels", 15, 8 128 56 10, left
  button "Close", 16, 68 106 31 10
}

on *:dialog:Settings:sclick:*: {
  if ($did == 17) { if (!$dialog(Programs)) dialog -m Programs Programs }
  if ($did == 6) { set %QUsername $did(4) | set %QPassword $did(5) | msg Q@CServe.quakenet.org AUTH %QUsername %QPassword | dialog -x $dname $dname }
  if ($did == 7) { mode $me +x }
  if ($did == 8) { set %QAuth $iif(%QAuth !== ON,ON,OFF) }
  if ($did == 9) { set %QHide $iif(%QHide !== ON,ON,OFF) }
  if ($did == 15) { set %AutoJoin $iif(%AutoJoin !== ON,ON,OFF) }
  if ($did == 14) { set %Channels | did -r $dname 11 }
  if ($did == 16) { dialog -x $dname $dname }
  if ($did == 12) { var %Auto-Channel $input(Type Channel,eg,Auto join channels) | set %Channels $addtok(%Channels,%Auto-Channel,44) | did -r $dname 11
    var %x = 1
    while ($numtok(%Channels,44) >= %x) {
      did -a $dname 11 $gettok(%Channels,%x,44)
      inc %x
    }
  }
  if ($did == 13) && ($did($dname,11).seltext) { set %Channels $remtok(%Channels,$gettok($did($dname,11).seltext,1,44),1,44) | did -r $dname 11
    var %x = 1
    while ($numtok(%Channels,44) >= %x) {
      did -a $dname 11 $gettok(%Channels,%x,44)
      inc %x
    }
  }
}
on *:dialog:Settings:dclick:11: { join $did($dname,11).seltext }
on *:dialog:Settings:edit:*: {
  if (!$did(Settings,4)) || (!$did(Settings,5)) { did -b Settings 6 }
  if ($did(Settings,4)) && ($did(Settings,5)) { did -e Settings 6 }
}
on *:dialog:Settings:init:*: {
  if (%QUsername) { did -a $dname 4 %QUsername }
  if (%QPassword) { did -a $dname 5 %QPassword }
  if (%QAuth == ON) { did -c $dname 8 }
  if (%QHide == ON) { did -c $dname 9 }
  if (!%QUsername) || (!%QPassword) { did -b $dname 6 }
  if (%AutoJoin == ON) { did -c $dname 15 }
  if (%Connected == ON) {
    var %x = 1
    while ($numtok(%Channels,44) >= %x) {
      did -a $dname 11 $gettok(%Channels,%x,44)
      inc %x
    }
  }
}

on *:connect: {
  if ($network == Quakenet) {
    if (%QAuth == ON) && (%QUsername) && (%QPassword) { msg Q@CServe.quakenet.org AUTH %QUsername %QPassword }
    if (%QHide == ON) { mode $me +x }
    if (%AutoJoin == ON) { timer 1 2 join %Channels }
  }
}
alias opd dialog -m Settings Settings
menu * {
  Auto Connect: opd
}