Mirc alert

on 1:connect: ml
alias ml {
  /window -edSl9 @multichan
  set %destop.multi.nb $chan(0)
  while ( %destop.multi.nb > 0 ) {
    aline -l @multichan $chan(%destop.multi.nb)
    dec %destop.multi.nb 1
  }
  .enable #multilog
}

#multilog on
on 1:TEXT:*:#:{ echo @multichan 14< $+ $chan $nick $+ > $1- }
on 1:ACTION:*:#:{ echo @multichan 6 $+ $chan $nick $1- }
on 1:NOTICE:*:*:{ echo @multichan 5 - $nick - $1- }
on 1:NICK: { echo @multichan 3 *** $nick devient $newnick 12 $_comchan($newnick) }
on 1:QUIT: { echo @multichan 2 *** $nick vient de quitter 6 $+ ( $+ $_comchan($nick) $+ ) 2 $1- }
on 1:join:*: {
  if ($nick == $me ) {
    aline -l @multichan $chan
  }
  echo @multichan 3 *** $nick ( $+ $address($nick,1) $+ ) a rejoint $chan
}

on 1:part:*: {
  if ($nick == $me) {
    set %detop.multichan.chans $line(@multichan,0,1)
    while (%detop.multichan.chans > 0 ) {
      if ($chan == $line(@multichan,%detop.multichan.chans,1)) {
        dline -l @multichan %detop.multichan.chans
        set %detop.multichan.chans 0
      }
      dec %detop.multichan.chans 1
    }
    unset %detop.multichan.*
  }
  echo @multichan 12 *** $nick ( $+ $address($nick,1) $+ ) est prarti de $chan
}

on 1:kick:*: {
  if ($knick == $me) {
    set %detop.multichan.chans $line(@multichan,0,1)
    while (%detop.multichan.chans > 0 ) {
      if ($chan == $line(@multichan,%detop.multichan.chans,1)) {
        dline -l @multichan %detop.multichan.chans
        set %detop.multichan.chans 0
      }
      dec %detop.multichan.chans 1
    }
  }
  unset %detop.multichan.*
}
on 1:input:@multichan: {
  if ($left($1,1) != $chr(47)) {
    echo @multichan < $+ $sline(@multichan,1) $me $+ > $1-
    msg $sline(@multichan,1) $1-
  }
  elseif ($1 == /me ) {
    echo @multichan 6* $+ $sline(@multichan,1) $me $2-
    describe $sline(@multichan,1) $2-

  }
}

#multilog end

on 1:close:@multichan: { .disable #multilog }

alias -l _comchan {
  %comchans = ""
  %i = 1
  :loop
  if (%i > $comchan($1,0)) {
    unset %i
    return %comchans
  }
  %comchans = $addtok(%comchans,$comchan($1,%i),44)
  inc %i
  goto loop
}