prontera,152,212,4	script	Find the Mushroom	1084,{

mes "[ Find The Mushroom ]";
if(getgmlevel() < 98) {
	if(.Event==0) mes "We have Find the Mushroom Event at random times of the day/night. We are giving away hundreds of "+ getitemname($item_id)+"s for every mushroom found! Standby for my broadcasts!";
	else {
		mes "There is a Find the Mushroom event on now!";
		mes "Location: "+ .map_name$[.map_index];
		mes "Prize: " + getitemname($item_id);
		mes "Number of Mushrooms: " + .mushroom;
	}
	close;
}
	mes "Hello "+strcharinfo(0)+"! Please customize this event:";
Main:
next;
mes "[ Find The Mushroom ]";
	switch(select("Item ["+$amount+" x "+getitemname($item_id)+"]:Start Event:End Event")) {
		case 1:
			mes "Which item would you like the Mushroom to drop?";
			mes "Please input the item ID:";
			do{
				input $item_id;
			}while( getitemname($item_id) == "null" );
			mes "Enter amount.";
			input $amount,1,30000;
			mes "Event Prize : "+$amount+" x "+getitemname($item_id);
			goto Main;
		case 2:
			mes "Starting the event now...";
			set .Event,1;
			close2;
			goto OnStart;

		case 3:
			mes "Ending the event now...";
			if(.Event) announce strcharinfo(0)+" ended Find the Mushroom Event!",bc_all;
			killmonster  .map$[.map_index],"All";
			set .Event,0;
		close;
}

OnInit:
setarray .map$[0],"splendide","hugel","yuno","comodo","xmas","aldebaran","izlude","payon","geffen","morocc","prontera";
setarray .map_name$[0],"Splendide","Hugel Town","Yuno Town","Comodo Town","Christmas Town","Alde Baran","Izlude","Payon Town","Geffen Tower","Morocc Desert","Prontera";
set .map_size,getarraysize( .map$ );
end;



OnClock0548:
OnClock0800:
OnClock1000:
OnClock1200:
OnClock1415:
OnClock1601:
OnClock1800:
OnClock2030:
OnClock2230:
OnClock0100:
OnClock0300:
OnStart:
	announce "Mushroom NPC : It's time to play Find the Mushroom Event in PvP!",0;
	sleep2 10000;

	set .map_index,rand( .map_size );
	set .@ran2, rand(1,5);
	if (.@ran2 == 5) set .mushroom,9;
	if (.@ran2 == 4) set .mushroom,7;
	if (.@ran2 == 3) set .mushroom,7;
	if (.@ran2 == 2) set .mushroom,5;
	if (.@ran2 == 1) set .mushroom,3;

	announce "Mushroom NPC : " + .mushroom + " Mushrooms have spawned in map [ "+ .map_name$[.map_index] +" ] with "+$amount+" pcs. "+getitemname($item_id)+"s bounty for each! Gear up for battle now!",0;
	sleep2 10000;
	monster .map$[.map_index],0,0,"Don't kill me please!",1084,.mushroom,"Find the Mushroom::OnMobKilled";
	end;

OnMobKilled:
	mapannounce .map$[.map_index],"Mushroom NPC: " + strcharinfo(0) + " has obtained "+$amount+" pcs. "+getitemname($item_id)+"s for finding a mushroom!",0;
	getitem $item_id,$amount;
	if( !mobcount( .map$[.map_index],"Find the Mushroom::OnMobKilled" ) ) set .Event,0;
	end;

}