gamescope

pkgname=gamescope
pkgver=3.9.5
pkgrel=2
pkgdesc="The micro-compositor formerly known as steamcompmgr"
arch=('x86_64')
url="https://github.com/Plagman/gamescope"
license=('BSD')
depends=(glslang libcap libdrm libinput libliftoff libpng libxcb libxcomposite libxkbcommon
         libxrender libxres libxtst opengl-driver pipewire pixman seatd sdl2
         vulkan-icd-loader wayland wlroots xcb-util-errors xcb-util-wm
         xorg-server-xwayland)
makedepends=('git' 'cmake' 'meson' 'vulkan-headers' 'wayland-protocols')
conflicts=('steamcompmgr')
replaces=('steamcompmgr')
source=("git+https://github.com/Plagman/gamescope.git#tag=$pkgver"
        'git+https://github.com/emersion/libliftoff.git'
        'git+https://github.com/nothings/stb.git'
        'git+https://github.com/swaywm/wlroots.git')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd "$srcdir/$pkgname"
  git submodule init subprojects/libliftoff
  git config submodule.libliftoff.url "$srcdir/libliftoff"

  git submodule init subprojects/packagefiles/stb
  git config submodule.stb.url "$srcdir/stb"

  git submodule init subprojects/wlroots
  git config submodule.wlroots.url "$srcdir/wlroots"

  git submodule update
}

build() {
  arch-meson "$pkgname" build --wrap-mode default
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  # libliftoff & wlroots are statically linked
  rm -rfv "$pkgdir"/usr/{include,lib}

  cd "$srcdir/$pkgname"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}