dialog hltr {
  title "HighLiter"
  size -1 -1 121 176
  option dbu
  list 1, 3 60 115 93, size
  box "Options", 99, 0 1 121 155
  check "Highliter On/Off", 2, 6 11 50 9, left push
  check "Flash on msg", 3, 6 22 50 9, left push
  check "Log msg On/Off", 4, 6 33 50 9, left push
  check "Change Focus", 5, 65 11 50 9, left push
  check "Beep on msg", 6, 65 22 50 9, left push
  button "Exit", 7, 65 33 23 9, ok
  edit "", 8, 3 161 56 10, autohs
  button "Add", 9, 61 161 17 10
  button "Edit", 10, 80 161 17 10
  button "Delete", 11, 99 161 19 10
  box "Key Words", 12, 0 49 121 107
  box "", 13, 0 152 121 23
  button "Help", 14, 92 33 23 9
}

On *:dialog:hltr:init:0:{
  did -a $dname 1 $me
  hl.chx
  k.wrds
}
menu * {
  -
  Highliter:{
    if ($dialog(hltr) != $null) { dialog -ve hltr }
    else { dialog -mod hltr hltr }
  }
}
Alias hl.chx {
  if (%hl = on) { did -c $dname 2 }
  if (%fom = on) { did -c $dname 3 }
  if (%lgm = on) { did -c $dname 4 }
  if (%hcf = on) { did -c $dname 5 }
  if (%bom = on) { did -c $dname 6 }
}
On *:dialog:hltr:dclick:1:{ k.wrds }
On *:dialog:hltr:sclick:2:{
  if ($did($dname,2).state == 1) { set %hl on }
  else { unset %hl }
}
On *:dialog:hltr:sclick:3:{
  if ($did($dname,3).state == 1) { set %fom on }
  else { unset %fom }
}
On *:dialog:hltr:sclick:4:{
  if ($did($dname,4).state == 1) { set %lgm on }
  else { unset %lgm }
}
On *:dialog:hltr:sclick:5:{
  if ($did($dname,5).state == 1) { set %hcf on }
  else { unset %hcf }
}
On *:dialog:hltr:sclick:6:{
  if ($did($dname,6).state == 1) { set %bom on }
  else { unset %bom }
}
;Add
;---
On *:dialog:hltr:sclick:9:{
  if ($read($+(",$scriptdirkwords.txt,"),w,$+(*‡,$did($dname,8).text,‡*)) != $null) {
    write -dl $+ $readn $+(",$scriptdirkwords.txt,")
    write $+(",$scriptdirkwords.txt,") $+(‡,$did($dname,8),‡)
  }
  else { write $+(",$scriptdirkwords.txt,") $+(‡,$did($dname,8),‡) }
  did -raf $dname 8
  k.wrds
}
;Edit
;----
On *:dialog:hltr:sclick:10:{
  if ($did($dname,10).text == apply) {
    did -ra $dname 10 Edit
    if ($read($+(",$scriptdirkwords.txt,"),w,$+(*‡,$did($dname,1).seltext,‡*)) != $null) {
      write -dl $+ $readn $+(",$scriptdirkwords.txt,")
      write $+(",$scriptdirkwords.txt,") $+(‡,$did($dname,8),‡)
    }
    else { write $+(",$scriptdirkwords.txt,") $+(‡,$did($dname,8),‡) }
    did -raf $dname 8
    k.wrds
  }
  else { did -ra $dname 10 Apply | did -raf $dname 8 $did($dname,1).seltext }
}
;Delete
;------
On *:dialog:hltr:sclick:11:{
  var %d = $did($dname,1).seltext
  if (%d != $null) {
    write -dw"‡ $+ %d $+ ‡" $+(",$scriptdirkwords.txt,")
    k.wrds
  }
}
;Help
;----
On *:dialog:hltr:sclick:14:{
  if ($did($dname,14).text == help) { did -r $dname 1 | hltr.hlp | did -ra $dname 14 List | return }
  if ($did($dname,14).text == List) { k.wrds | did -ra $dname 14 Help }
}
;List
;----
Alias k.wrds {
  did -ra $dname 1 $me | var %k = 1
  while (%k <= $lines($+(",$scriptdirkwords.txt,"))) {
    var %kw = $read($+(",$scriptdirkwords.txt,"),%k)
    if (%kw != $null) { did -a $dname 1 $remove(%kw,‡) | inc %k }
    else { inc %k }
  }
}
Alias k.mtch {
  var %k = 1
  if ($me isin $strip($4-,burc)) {
    %hmsg = $timestamp - $+ 11Hltr $+ - $3 $+(-,$1,-) $4-
    if (%lgm == on) { write logs\highliter.log %hmsg }
    return %hmsg $m.alert($3)
  }
  while (%k <= $lines($+(",$scriptdirkwords.txt,"))) {
    var %kw = $remove($read($+(",$scriptdirkwords.txt,"),%k),‡)
    if (%kw != $null) {
      if ($1 == %kw) || ($2 isin %kw) || (%kw isin $2) || ($3 == %kw) || (%kw isin $strip($4-,burc)) {
        %hmsg = $timestamp - $+ 11Hltr $+ - $3 $+(-,$1,-) $4-
        if (%lgm == on) { write logs\highliter.log %hmsg }
        return %hmsg $m.alert($3)
      }
      else { inc %k }
    }
    else { inc %k }
  }
  else { return }
}
Alias m.alert {
  if (%bom = on) { beep 3 }
  if (%fom = on) { flash -r3 $1 }
  if (%hcf = on) { .timerHCF 1 1 window -a $1 }
}
On *:text:*:#:{
  if (%hl = on) {
    if ($chan != $active) {
      var %mtxt = $k.mtch($nick,$address($nick,4),$chan,$1-)
      if (%mtxt) { echo -a %mtxt }
    }
  }
}
On *:action:*:#:{
  if (%hl = on) {
    if ($chan != $active) {
      var %mtxt = $k.mtch($nick,$address($nick,4),$chan,$1-)
      if (%mtxt) { echo -a %mtxt }
    }
  }
}
On *:join:#:{
  if (%hl = on) {
    if ($chan != $active) {
      var %mtxt = $k.mtch($nick,$address($nick,4),$chan,$1-)
      if (%mtxt) { echo -a .:Join: %mtxt }
    }
  }
}
On *:part:#:{
  if (%hl = on) {
    if ($chan != $active) {
      var %mtxt = $k.mtch($nick,$address($nick,4),$chan,$1-)
      if (%mtxt) { echo -a .:Part: %mtxt }
    }
  }
}
On *:quit:{
  if (%hl = on) {
    if ($chan != $active) {
      var %mtxt = $k.mtch($nick,$address($nick,4),$chan,$1-)
      if (%mtxt) { echo -a .:Quit: %mtxt }
    }
  }
}
Alias hltr.hlp {
  did -a hltr 1 ------------------------------------------------------------------------
  did -a hltr 1 Highliter By -KiX-
  did -a hltr 1 ------------------------------------------------------------------------
  did -a hltr 1 Place this file in your mirc directory
  did -a hltr 1 Load this to your mirc with:
  did -a hltr 1 //load -rs pathtothisfile\hltr.mrc
  did -a hltr 1
  did -a hltr 1 Usage: right click and go to Highliter
  did -a hltr 1 ------------------------------------------------------------------------
  did -a hltr 1
  did -a hltr 1 Theres a few features:
  did -a hltr 1 ------------------------------------------------------------------------
  did -a hltr 1
  did -a hltr 1 -Flash: Flashes the channel where
  did -a hltr 1 keyword has been said
  did -a hltr 1
  did -a hltr 1 -Log msgs: logs highliter stuff
  did -a hltr 1 -Change Focus: Changes focus to the last
  did -a hltr 1 chan a keyword was said in
  did -a hltr 1
  did -a hltr 1 -Beep on msg: Beeps mirc when a keyword
  did -a hltr 1 was last said
  did -a hltr 1
  did -a hltr 1 ------------------------------------------------------------------------
  did -a hltr 1
  did -a hltr 1 Key Words:
  did -a hltr 1 Key words can be anything, a #channel,
  did -a hltr 1 a persons nick, a persons isp,
  did -a hltr 1 or specific word like Blah
  did -a hltr 1
  did -a hltr 1 *Note: your own nick is automaticly
  did -a hltr 1 added you cannot edit or delete it.
  did -a hltr 1 it keeps up with your nick chg as well.
  did -a hltr 1 ----------------------------------------------------------------
  did -a hltr 1
  did -a hltr 1 When someone says a keyword, it is echo'd
  did -a hltr 1 to your active channel.
  did -a hltr 1
}