While 0
{KEY,HP,MAXHP,ARMOR,ATK}
1=KEY 2=ARMOR 3=WEP
{1/0,NUMBER,MATRIXID,HP,ATK}
{RANGE,ARMOR,ATK,HEALNG}
End

Input "20 or 25 - ",D

Lbl 1
ClrHome
Disp "
Disp "PRESS 1 TO CHECK THE
Disp "TUTORIAL
Disp "
Disp "PRESS ANY OTHER KEY TO
Disp "CONTINUE


Repeat K
getKey→K
End
ClrHome

If K=92:Then
Output(1,1,"GO AS DEEP AS YOU CAN     WITHOUT DYING
Output(4,1,"PICK UP THE KEY AND ENTER THE LADDER TO PROGRESS
Output(7,1,"H  -  LADDER
Output(9,1,"  -  KEY
Pause
ClrHome
Output(1,1,"GRAB ITEMS TO GET STRONGER
Output(3,1," /    WEAPONS (+ATK)
Output(5,1," ^    HELMET  (+ARMOR)
Pause
ClrHome
Output(1,1,"MOVE USING THE ARROW KEYS
Output(2,1,"(IN 4 DIRECTIONS ONLY)
Output(3,1,"ATTACK WITH 2nd
Output(4,23,"***
Output(5,1,"YOU MAY ATTACK ON     *°*
Output(6,1,"8 ADJACENT SQUARES    ***
Output(8,1," °  -  YOU
Pause
ClrHome
Output(1,1,"EACH TIME YOU KILL A FOE, YOUR MAX HP GOES UP BY 1
Output(5,1,"EACH SUCCESSIVE FOE HAS   MORE HP AND ATTACK
Output(8,1,"   -  ENEMY
Pause
ClrHome
Output(1,1,"EACH LEVEL HAS STRONGER   ENEMIES AND BETTER ITEMS  THAN THE LAST, AND A PART OF YOUR HP IS RESTORED
Pause
ClrHome
Output(1,1,"NERFS/BUFFS INFO:
Output(3,1,"+ARMOR:
Output(4,1,"ARMOR INCREASES FASTER
Output(5,1,"+ATK:
Output(6,1,"ATTACK INCREASES FASTER
Output(9,1,"+RANGE:
Output(10,1,"CAN HIT 1 SQUARE FARTHER
Output(7,1,"+HEALING:
Output(8,1,"MORE HP RESTORED PER LEVEL
Pause
Output(3,1,"-
Output(4,17,"SLOWER
Output(5,1,"-
Output(6,18,"SLOWER
Output(7,1,"-
Output(8,1,"LESS
Output(9,1,"
Output(10,1,"RANGE CANNOT BE NERFED
Pause
ClrHome
Disp "FOR NEW PLAYERS, I
Disp "RECCOMEND USING 1 OR 2
Disp "BUFFS, BUT LATER ON NERFS
Disp "CAN BE FUN TOO!
Pause
ClrHome
Goto 1
End
ClrHome





{0,0,0,0,0,0}→⌊CLS

ClrHome
Output(1,1,"CUSTOMIZE STATS:

Output(3,3,"RANGE
Output(4,3,"ARMOR
Output(5,3,"ATTACK
Output(6,3,"HEALING

Output(9,1,"USE THE + AND - BUTTONS
Output(10,1,"PRESS ENTER TO PROCEED

1→X
Output(X+2,1,">

Repeat K=105

If K=25 and X>1:Then
Output(X+2,1,"
X-1→X
Output(X+2,1,">
End

If K=34 and X<4:Then
Output(X+2,1,"
X+1→X
Output(X+2,1,">
End

If K=95:Then
If ⌊CLS(X)<1
⌊CLS(X)+1→⌊CLS(X)
End

If K=85:Then
If ⌊CLS(X)>­1
⌊CLS(X)-1→⌊CLS(X)
If ⌊CLS(1)=­1:0→⌊CLS(1)
End

For(T,1,4)
If ⌊CLS(T)=­1
Output(T+2,25,"-
If ⌊CLS(T)=0
Output(T+2,25,"O
If ⌊CLS(T)=1
Output(T+2,25,"+
End

Repeat K=95 or K=85 or K=25 or K=34 or K=105
getKey→K

End

End

For(X,1,4)
If ⌊CLS(X)=1:⌊CLS(5)+1→⌊CLS(5)
If ⌊CLS(X)=­1:⌊CLS(6)+1→⌊CLS(6)
End

If ⌊CLS(1)=1:2→⌊CLS(1
If ⌊CLS(1)=0:1→⌊CLS(1

If ⌊CLS(2)=1:1.3→⌊CLS(2
If ⌊CLS(2)=­1:.8→⌊CLS(2
If ⌊CLS(2)=0:1→⌊CLS(2

If ⌊CLS(3)=1:1.2→⌊CLS(3
If ⌊CLS(3)=­1:.8→⌊CLS(3
If ⌊CLS(3)=0:1→⌊CLS(3

If ⌊CLS(4)=­1:.13→⌊CLS(4
If ⌊CLS(4)=0:.25→⌊CLS(4
If ⌊CLS(4)=1:.5→⌊CLS(4

ClrHome





0→N
{0,10,10,⌊CLS(2),⌊CLS(3)}→⌊INV

ClrHome
For(Y,1,5
For(X,1,21
Output(Y,X,"Ŝ
Output(10-Y,22-X,"Ŝ
End:End
Output(5,11,"H

Lbl 0

N+1→N





If N≥2:Then
For(X,2,D)
Output([D](X,1),[D](X,2),"Ŝ
End:End

If D=20:[[5,11,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0]]→[D]

If D=25:[[5,11,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0][0,0,0]]→[D]

dim([D]):Ans(1)→D

5→Y:11→Z:2→W:0→V

While W≤D
V+1→V

If V=4:Then
randInt(1,W-2)→X
[D](X,1)→Y:[D](X,2)→Z
1→V
End

Y→T:Z→U
randInt(1,10)→θ
If θ≥1 and θ≤4:Z-1→U
If θ≥5 and θ≤8:Z+1→U
If θ=9:Y-1→T
If θ=10:Y+1→T

If T≥2 and T≤8 and U≥2 and U≤20
Then
1→θ
For(X,1,W-1
If [D](X,1)=T and [D](X,2)=U:0→θ
End
If θ:Then
T→Y:U→Z
Y→[D](W,1
Z→[D](W,2
W+1→W:0→V
Output(1,1,int((W-1)/D*100
End:End

End

For(X,2,D)
Output([D](X,1),[D](X,2),"
End

Output(1,1,"ŜŜŜ
Output(5,11,"H
Output(1,1,0

For(X,2,D)
√(([D](X,1)-5)²+([D](X,2)-11)²→V
If V>θ:Then
V→θ
[D](X,1)→Y:[D](X,2)→Z
X→A
End:End
2→[D](A,3)
Output(Y,Z,"^
Output(1,1,33

1→W
For(X,2,D)
abs(√(([D](X,1)-Y)²+([D](X,2)-Z)²)/√(([D](X,1)-5)²+([D](X,2)-11)²→V
If V>.8 and V<1.2:Then
√(([D](X,1)-Y)²+([D](X,2)-Z)²→V
If V>W:Then
V→W
[D](X,1)→T:[D](X,2)→U
X→A
End:End:End
1→[D](A,3)
Output(T,U,"
Output(1,1,66

10→W
For(X,2,D
√(([D](X,1)-5)²+([D](X,2)-11)²→V
If abs(V-θ/3)<W and not([D](X,3):Then
abs(V-θ/3)→W
[D](X,1)→Y:[D](X,2)→Z
X→A
End:End
3→[D](A,3)
Output(Y,Z,"/
Output(1,1,100

DelVar A:DelVar T:DelVar U:DelVar V:DelVar W:DelVar Y:DelVar Z:DelVar θ
Output(1,1,"ŜŜŜ






{0,0,1,0,0}→⌊NMY
0→⌊INV(1)
[D](2,1)→Y:[D](2,2)→Z
Output(Y,Z,"°

Output(1,22,"HP
Output(2,22,⌊INV(2
Output(2,24,"/
Output(2,25,⌊INV(3
Output(3,22,"ARMOR
Output(4,22,⌊INV(4
Output(5,22,"ATK
Output(6,22,⌊INV(5
Output(8,22,"DEPTH
Output(9,22,N
Output(10,1,"FOE HP       ATK

Repeat Y=5 and Z=11 and ⌊INV(1)

Repeat θ

Y→T:Z→U:0→K

Repeat K=24 or K=25 or K=26 or K=34 or K=21
getKey→K
End

If K=24:Z-1→U
If K=25:Y-1→T
If K=26:Z+1→U
If K=34:Y+1→T

If K≠21:Then
0→θ
For(X,1,D)
If T=[D](X,1) and U=[D](X,2)
Then
If [D](X,3):Then
If [D](X,3)=1:Then
0→[D](X,3):1→⌊INV(1
End
If [D](X,3)=2:Then
0→[D](X,3):(1+N)*⌊CLS(2)→⌊INV(4
Output(4,22,"
Output(4,22,⌊INV(4
End
If [D](X,3)=3:Then
0→[D](X,3):(1+N)*⌊CLS(3)→⌊INV(5
Output(6,22,"
Output(6,22,⌊INV(5
End
End
1→θ:31→X
End:End
End
End

If K=21 and abs(T-[D](⌊NMY(3),1))≤⌊CLS(1) and abs(U-[D](⌊NMY(3),2))≤⌊CLS(1) and ⌊NMY(1)
Then
1→X
If rand<.1:2→X
If X=1:Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"*
If X=2:Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"X


⌊NMY(4)-X*int(⌊INV(5→⌊NMY(4
If rand<⌊INV(5)-int(⌊INV(5)):⌊NMY(4)-1→⌊NMY(4)
If ⌊NMY(4)<0:0→⌊NMY(4)
Output(10,8,"
Output(10,8,⌊NMY(4
Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"
End





If ⌊NMY(1) and ⌊NMY(4):prgmCRNMY




If ⌊INV(2)≤0:Goto Z

If not(⌊NMY(1
Then
Repeat X
1→X
randInt(3,D)→θ
If abs([D](θ,1)-T)≤1 and abs([D](θ,2)-U)≤1 or [D](θ,3):0→X
End
{1,⌊NMY(2)+1,θ,int(3*N*1.1^(⌊NMY(2))),1.3*N*1.1^⌊NMY(2)}→⌊NMY
Output(10,8,⌊NMY(4
Output(10,10,"/
Output(10,11,⌊NMY(4
Output(10,18,"
Output(10,18,int(⌊NMY(5)*10)/10
End

If ⌊NMY(4)=0:Then
0→⌊NMY(1)
1+⌊INV(3)→⌊INV(3)
1+⌊INV(2)→⌊INV(2)
Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"
Output(2,22,⌊INV(2
Output(2,25,⌊INV(3
End

Output(Y,Z,"
Output(5,11,"H
T→Y:U→Z
If ⌊NMY(1) and ⌊NMY(4):Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"
Output(Y,Z,"°

End
Output(5,11,"H
Output(10,1,"DESCENDING...
int(⌊INV(3)*⌊CLS(4))+⌊INV(2)→⌊INV(2
If ⌊INV(2)>⌊INV(3):⌊INV(3)→⌊INV(2
Output(2,22,⌊INV(2
Goto 0


Lbl Z
For(X,1,100)
Output(randInt(1,9),randInt(1,21),"
End
For(X,1,500):End
ClrHome
Disp "YOU DIED"
Disp "
Disp "DEPTH
Disp N
Disp "KILLS
Disp ⌊INV(3)-10
Disp "DIFFICULTY
Disp "             BUFFS   NERFS
Output(8,12,⌊CLS(5
Output(8,20,⌊CLS(6
Pause
ClrHome







+





If abs(T-[D](⌊NMY(3),1))≤1 and abs(U-[D](⌊NMY(3),2))≤1
Then

Output(Y,Z,"*
int(⌊NMY(5))-int(⌊INV(4→X:If X<0:0→X
If ⌊NMY(5)>⌊INV(4) and rand<⌊NMY(5)-int(⌊NMY(5)):X+1→X
If X and rand<⌊INV(4)-int(⌊INV(4)):X-1→X
⌊INV(2)-X→⌊INV(2)

Output(2,22,"
Output(2,22,⌊INV(2
Output(Y,Z,"°
Return

Else

⌊NMY(3)→Q:0→O:0→P
If [D](Q,1)-T>0:­1→O
If [D](Q,1)-T<0:1→O
If [D](Q,2)-U>0:­1→P
If [D](Q,2)-U<0:1→P


If O and P:Then
For(X,1,D)
If [D](Q,1)+O=[D](X,1) and [D](Q,2)+P=[D](X,2):Then:If not([D](X,3):Then
X+90→X
Else:D→X
End:End:End
If X=D+1:Then
For(X,1,D)
If [D](Q,2)+P=[D](X,2) and [D](Q,1)=[D](X,1):Then
If not([D](X,3):Then
X+90→X
Else:D→X
End:End:End
If X=D+1:Then
For(X,1,D)
If [D](Q,1)+O=[D](X,1) and [D](Q,2)=[D](X,2):Then
If not([D](X,3):Then
X+90→X
Else:D→X
End:End:End
If X=D+1:Goto N
X-91→⌊NMY(3):Goto N
End
X-91→⌊NMY(3):Goto N
End
X-91→⌊NMY(3):Goto N
End

If P:Then
For(X,1,D)
If [D](Q,2)+P=[D](X,2) and [D](Q,1)=[D](X,1):Then
If not([D](X,3):Then
X+90→X
Else:D→X
End:End:End
If X=D+1:Goto N
X-91→⌊NMY(3):Goto N
End

If O:Then
For(X,1,D)
If [D](Q,1)+O=[D](X,1) and [D](Q,2)=[D](X,2):Then
If not([D](X,3):Then
X+90→X
Else:D→X
End:End:End
If X=D+1:Goto N
X-91→⌊NMY(3):Goto N
End

End

Lbl N
Output([D](Q,1),[D](Q,2),"
Output([D](⌊NMY(3),1),[D](⌊NMY(3),2),"