ModTweaker 1.11.2 - Tinker's Construct mod commands

/* ModTweaker 1.11.2 - Tinker's Construct mod commands */

/* Casting */

# Basin Casting
// OutputStack, InputFluid, CastStack, ConsumeCast (Optional), TimeInTicks (Optional)
mods.tconstruct.Casting.addBasinRecipe(<minecraft:magma>, <liquid:lava> * 250, <minecraft:netherrack>, true);
// OutputStack, InputFluid, CastStack, ConsumeCast (Optional), TimeInTicks (Optional)
mods.tconstruct.Casting.addTableRecipe(<minecraft:nether_star>, <liquid:iron> * 500, <minecraft:emerald>, true, 300);
# Table Casting
// OutputStack, InputFluid (Optional), CastStack (Optional)
mods.tconstruct.Casting.removeBasinRecipe(<minecraft:sand:1>, <liquid:blood>, <minecraft:sand>);
// OutputStack, InputFluid (Optional), CastStack (Optional)
mods.tconstruct.Casting.removeTableRecipe(<minecraft:iron_ingot>, <liquid:iron>, <tconstruct:cast_custom>);


/* Drying Rack */

// InputStack, OutputStack, TimeInTicks
mods.tconstruct.Drying.addRecipe(<minecraft:tallgrass:1>, <minecraft:deadbush>, 50);
// OutputStack
mods.tconstruct.Drying.removeRecipe(<tconstruct:edible:10>);


/* Smeltery */

# Entity Melting
// OutputFluid, InputEntity
mods.tconstruct.Smeltery.addEntityMelting(<liquid:gold>, <entity:cow>);
// InputEntity
mods.tconstruct.Smeltery.removeEntityMelting(<entity:villager>);

# Alloys
// OutputFluid, InputFluidArray
mods.tconstruct.Smeltery.addAlloy(<liquid:emerald>, [<liquid:blood> * 2, <liquid:clay>]);
// OutputFluid
mods.tconstruct.Smeltery.removeAlloy(<liquid:obsidian>);

# Item Melting
// OutputFluid, InputStack, TemperatureAmount (Optional)
mods.tconstruct.Smeltery.addMelting(<liquid:blood> * 200, <minecraft:porkchop>, 320);
// InputStack
mods.tconstruct.Smeltery.removeMelting(<minecraft:rotten_flesh>);

# Fuels
// InputFluid, TimeInTicks (Optional)
mods.tconstruct.Smeltery.addFuel(<liquid:gold>);
// InputFluid
mods.tconstruct.Smeltery.removeFuel(<liquid:lava>);


/* Materials */

// Material.HeadModifier = Amount
<material:stone>.durabilityHead = 5;
<material:stone>.miningSpeedHead = 5.0;
<material:stone>.attackHead = 5.0;
<material:stone>.harvestLevelHead = 5;
// Material.HandleModifier = Amount
<material:obsidian>.durabilityHandle = 5;
<material:obsidian>.modifierHandle = 5.0;
// Material.ExtraModifier = Amount
<material:obsidian>.durabilityExtra = 5;
// Material.BowModifier = Amount
<material:wood>.drawspeedBow = 5.0;
<material:wood>.rangeBow = 5.0;
<material:wood>.bonusDamageBow = 5.0;
// Material.BowStringModifier = Amount
<material:string>.modifierBowString = 2.0;
// Material.ArrowShaftModifier = Amount
<material:wood>.modifierArrowShaft = 5.0;
<material:wood>.bonusAmmoArrowShaft = 5;
// Material.FletchingModifier = Amount
<material:feather>.accuracyFletching = 0.7;
<material:feather>.modifierFletching = 2.0;