Serialization DataContractSerializer (VB.NET)

Imports System.IO
Imports System.Collections
Imports System.Runtime.Serialization

Module Module1

    Sub Main()
        While True
            Console.WriteLine("s=serialize, r=read:")
            Select Case Console.ReadLine()
                Case "s"

                    Dim EmployeeList1 = New List(Of Employee)()

                    ' create some objects adding them to a List
                    EmployeeList1.Add(New Employee(1, "Elenor", "Scheller"))
                    EmployeeList1.Add(New Employee(2, "Kaila", "Wilburn"))
                    EmployeeList1.Add(New Employee(3, "Shea", "Wallen"))
                    EmployeeList1.Add(New Employee(4, "Elliot", "Shaffer"))
                    EmployeeList1.Add(New Employee(5, "Dominica", "Charney"))

                    Try
                        Using stream As New FileStream("data.xml", FileMode.Create)

                            ' create DataContractSerializer
                            Dim serializer = New DataContractSerializer(EmployeeList1.GetType())
                            ' serialize the collection (EmployeeList1) to file (stream)
                            serializer.WriteObject(stream, EmployeeList1)

                        End Using

                    Catch ex As Exception
                    End Try

                Case "r"
                    Try
                        Using stream As New FileStream("data.xml", FileMode.Open)

                            ' create DataContractSerializer
                            Dim serializer = New DataContractSerializer(New List(Of Employee)().GetType())
                            ' deserialize the collection (Employee) from file (stream)
                            Dim EmployeeList2 = DirectCast(serializer.ReadObject(stream), List(Of Employee))

                            ' display the results
                            For Each Employee In EmployeeList2
                                Console.WriteLine("{0}, {1}, {2}",
                                    Employee.id,
                                    Employee.fName,
                                    Employee.sName)
                            Next

                        End Using
                    Catch ex As Exception
                    End Try

            End Select
        End While
    End Sub

    ' The object we are going to Serializing/De-serializing
    <DataContract>
    Class Employee
        <DataMember>
        Property id As Integer
        <DataMember>
        Property fName As String
        <DataMember>
        Property sName As String

        Public Sub New(i As Integer, f As String, s As String)
            id = i
            fName = f
            sName = s
        End Sub
    End Class

End Module