class PostEarthFactionSelect : UIScriptedMenu
{
    private autoptr Widget m_LayoutRoot;

    private autoptr PlayerPreviewWidget m_UnitedNationsPlayerPreview;
    private autoptr PlayerPreviewWidget m_RedStarPlayerPreview;
    private autoptr PlayerPreviewWidget m_DefenseForcePlayerPreview;

    private autoptr Widget m_UnitedNationsFactionPanel;
    private autoptr Widget m_RedStarFactionPanel;
    private autoptr Widget m_DefenseForcesFactionPanel;

    private autoptr Widget m_UnitedNationsSelectedPanel;
    private autoptr Widget m_RedStarSelectedPanel;
    private autoptr Widget m_DefenseForcesSelectedPanel;

    private autoptr RichTextWidget m_FactionHeaderText;
    private autoptr RichTextWidget m_FactionBodyText;

    void PostEarthFactionSelect()
    {
    }

    override Widget Init()
    {
        BuildLayout();

        WidgetEventHandler.GetInstance().RegisterOnClick(m_LayoutRoot, this, "OnClick");

        return m_LayoutRoot;
    }

    private void BuildLayout()
    {
        m_LayoutRoot = GetGame().GetWorkspace().CreateWidgets("PostEarth/gui/layouts/PostEarthFactionSelect.layout");

        m_UnitedNationsPlayerPreview = PlayerPreviewWidget.Cast(m_LayoutRoot.FindWidget("factionPanel.unPanel.unPlayerPreview"));
        m_RedStarPlayerPreview       = PlayerPreviewWidget.Cast(m_LayoutRoot.FindWidget("factionPanel.redstarPanel.redstarPlayerPreview"));
        m_DefenseForcePlayerPreview  = PlayerPreviewWidget.Cast(m_LayoutRoot.FindWidget("factionPanel.cdfPanel.cdfPlayerPreview"));

        m_UnitedNationsFactionPanel  = m_LayoutRoot.FindWidget("factionPanel.unPanel");
        m_RedStarFactionPanel        = m_LayoutRoot.FindWidget("factionPanel.redstarPanel");
        m_DefenseForcesFactionPanel  = m_LayoutRoot.FindWidget("factionPanel.cdfPanel");

        m_UnitedNationsSelectedPanel = m_LayoutRoot.FindWidget("factionPanel.unPanel.unSelectedPanel");
        m_RedStarSelectedPanel       = m_LayoutRoot.FindWidget("factionPanel.redstarPanel.redstarSelectedPanel");
        m_DefenseForcesSelectedPanel = m_LayoutRoot.FindWidget("factionPanel.cdfPanel.cdfSelectedPanel");

        m_FactionHeaderText         = RichTextWidget.Cast(m_LayoutRoot.FindWidget("factionPanel.factionInfoPanel.headerText"));
        m_FactionBodyText           = RichTextWidget.Cast(m_LayoutRoot.FindWidget("factionPanel.factionInfoPanel.bodyText"));

        SetupFactionDummys();
    }

    private void SetupFactionDummys()
    {

        vector localPos = GetGame().GetPlayer().GetPosition();

        // Setup UN dummy:
        autoptr PlayerBase unitedNationsDummy = PlayerBase.Cast(GetGame().CreateObject("SurvivorM_Mirek", localPos + "5 0 0", true, false));
        unitedNationsDummy.GetInventory().CreateAttachment("MilitaryBeret_UN");
        unitedNationsDummy.GetInventory().CreateAttachment("USMCJacket_Woodland");
        unitedNationsDummy.GetInventory().CreateAttachment("USMCPants_Woodland");
        unitedNationsDummy.GetInventory().CreateAttachment("M4A1");

        m_UnitedNationsPlayerPreview.SetPlayer(unitedNationsDummy);
        m_UnitedNationsPlayerPreview.SetSize(1.34, 1.34);
        m_UnitedNationsPlayerPreview.SetModelPosition("-0.4 -0.55 4");

        // Setup Red Star dummy:
        autoptr PlayerBase redstarDummy = PlayerBase.Cast(GetGame().CreateObject("SurvivorM_Boris", localPos, true, false));
        redstarDummy.GetInventory().CreateAttachment("MilitaryBeret_ChDKZ");
        redstarDummy.GetInventory().CreateAttachment("TTsKOJacket_Camo");
        redstarDummy.GetInventory().CreateAttachment("TTSKOPants");
        redstarDummy.GetInventory().CreateAttachment("AKM");

        m_RedStarPlayerPreview.SetPlayer(redstarDummy);
        m_RedStarPlayerPreview.SetSize(1.34, 1.34);
        m_RedStarPlayerPreview.SetModelPosition("0 -0.55 4");

        // Setup CDF dummy:
        autoptr PlayerBase cdfDummy = PlayerBase.Cast(GetGame().CreateObject("SurvivorM_Cyril", localPos - "5 0 0", true, false));
        cdfDummy.GetInventory().CreateAttachment("MilitaryBeret_CDF");
        cdfDummy.GetInventory().CreateAttachment("BDUJacket");
        cdfDummy.GetInventory().CreateAttachment("BDUPants");
        cdfDummy.GetInventory().CreateAttachment("SKS");

        m_DefenseForcePlayerPreview.SetPlayer(cdfDummy);
        m_DefenseForcePlayerPreview.SetSize(1.34, 1.34);
        m_DefenseForcePlayerPreview.SetModelPosition("0.42 -0.55 4");
    }

    override bool OnClick(Widget w, int x, int y, int button)
    {
        super.OnClick(w, x, y, button);

        bool isUNSelected            = (w == m_UnitedNationsFactionPanel);
        bool isRedStarSelected       = (w == m_RedStarFactionPanel);
        bool isDefenSeForcesSelected = (w == m_DefenseForcesFactionPanel);

        m_UnitedNationsSelectedPanel.Show(isUNSelected);
        m_RedStarSelectedPanel.Show(isRedStarSelected);
        m_DefenseForcesSelectedPanel.Show(isDefenSeForcesSelected);

        if (isUNSelected || isRedStarSelected || isDefenSeForcesSelected)
        {
            return true;
        }

        return false;
    }
}