ED - TAD Lista - Doblemente enlazada (^ini y ^fin) v. 2

UNIT uListaDoblePunteroIniFin;
INTERFACE
    USES uElementoInteger;
        {PARAMETROS GENERICOS: Funciones Asignar(), SonIguales(), Imprimir() propias de cada tipo de elemento}
    TYPE
        TPNodo = ^TNodo;
        TLista = RECORD
            ini, fin: TPNodo;
        END;
        TNodo = RECORD
            info : TElemento;
            sig, ant : TPNodo;
        END;

    {Constructoras generadoras}
        PROCEDURE CrearVacia(VAR l : TLista);
        PROCEDURE Construir(VAR l : TLista; e : TElemento);
    {Constructoras no generadoras}
        PROCEDURE Concatenar(VAR l : TLista; r : TLista);
        PROCEDURE BorrarElemento(VAR l : TLista; e : TElemento);
        PROCEDURE InsertarFinal(VAR l : TLista; e : TElemento);
    {Observadoras selectoras}
        PROCEDURE Primero(l : TLista; VAR e : TElemento);
        PROCEDURE Resto(l : TLista; VAR r : TLista);
    {Observadoras no selectoras}
        FUNCTION EsVacia(l : TLista):boolean;
        FUNCTION Longitud(l : TLista):integer;
        PROCEDURE Ultimo(l : TLista; VAR e : TElemento);
        FUNCTION Pertenece(l : TLista; e : TElemento):boolean;
    {Interacción con el usuario}
        PROCEDURE ImprimirListaCompleta(l : TLista);

IMPLEMENTATION
{Constructoras generadoras}
    PROCEDURE CrearVacia(VAR l : TLista);
        BEGIN
            l.ini := NIL;
            l.fin := NIL;
        END;
    PROCEDURE Construir(VAR l : TLista; e : TElemento);
        VAR
            aux : TPNodo;
        BEGIN
            new(aux);
            Asignar(aux^.info, e);
            aux^.sig := l.ini;
            aux^.ant := NIL;
            IF (NOT EsVacia(l)) THEN
                aux^.sig^.ant := aux
            ELSE
                l.fin := aux;
            l.ini := aux;
        END;

{Constructoras no generadoras}
    PROCEDURE Concatenar(VAR l : TLista; r : TLista);
        BEGIN
            IF(NOT EsVacia(r)) THEN BEGIN
                l.fin^.sig := r.ini;
                r.ini^.ant := l.fin;
                l.fin := r.fin;
            END;
        END;
    PROCEDURE BorrarElemento(VAR l : TLista; e : TElemento);
        VAR
            aux : TPNodo;
            encontrado : boolean;
        BEGIN
            IF (NOT EsVacia(l)) THEN
                aux := l.ini;
                encontrado := FALSE;
                WHILE ((aux <> NIL) AND (NOT encontrado)) DO BEGIN
                    IF (SonIguales(aux^.info, e)) THEN BEGIN
                        IF (aux^.sig <> NIL) THEN
                            aux^.sig^.ant := aux^.ant;
                        IF (aux^.ant <> NIL) THEN
                            aux^.ant^.sig := aux^.sig
                        ELSE
                            l.ini := aux^.sig;
                        IF (l.fin = aux) THEN
                            l.fin := aux^.ant;
                        dispose(aux);
                        encontrado := TRUE;
                    END ELSE
                        aux := aux^.sig;
                END;
        END;
    PROCEDURE InsertarFinal(VAR l : TLista; e : TElemento);
        VAR
            aux : TPNodo;
        BEGIN
            IF (NOT EsVacia(l)) THEN BEGIN
                new(aux);
                Asignar(aux^.info, e);
                aux^.sig := NIL;
                aux^.ant := l.fin;
                l.fin^.sig := aux;
                l.fin := aux;
            END ELSE
                Construir(l, e);
        END;

{Observadoras selectoras}
    PROCEDURE Primero(l : TLista; VAR e : TElemento);
        BEGIN
            IF (NOT EsVacia(l)) THEN
                Asignar(e, l.ini^.info);
        END;
    PROCEDURE Resto(l : TLista; VAR r : TLista);
        BEGIN
            IF (NOT EsVacia(l)) THEN
                r.ini := l.ini^.sig;
        END;

{Observadoras no selectoras}
    FUNCTION EsVacia(l : TLista):boolean;
        BEGIN
            EsVacia := (l.ini = NIL);
        END;
    FUNCTION Longitud(l : TLista):integer;
        VAR
            n : integer;
        BEGIN
            n := 0;
            WHILE (l.ini <> NIL) DO BEGIN
                n := n + 1;
                l.ini := l.ini^.sig;
            END;
            Longitud := n;
        END;
    PROCEDURE Ultimo(l : TLista; VAR e : TElemento);
        BEGIN
            IF (NOT EsVacia(l)) THEN BEGIN
                Asignar(e, l.fin^.info);
            END;
        END;
    FUNCTION Pertenece(l : TLista; e : TElemento):boolean;
        VAR
            encontrado : boolean;
        BEGIN
            encontrado := FALSE;
            WHILE ((l.ini <> NIL) AND (NOT encontrado)) DO BEGIN
                IF (SonIguales(l.ini^.info, e)) THEN
                    encontrado := TRUE
                ELSE
                    l.ini := l.ini^.sig;
            END;
            Pertenece := encontrado;
        END;

{Interacción con el usuario}
    PROCEDURE ImprimirListaCompleta(l : TLista);
        BEGIN
            write('[');
            WHILE (l.ini <> NIL) DO BEGIN
                Imprimir(l.ini^.info);
                write(', ');
                l.ini := l.ini^.sig;
            END;
            writeln(']');
        END;
END.