pkgname=watchit
_pkgver=0.1.0-beta.2
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Watch movies everywhere"
arch=('x86_64')
url="http://watchitapp.site"
license=('LGPL3')
depends=('electron9')
makedepends=('npm' 'python2')
source=("$pkgname-$pkgver.tar.gz::https://github.com/ZorrillosDev/watchit-desktop/archive/v$_pkgver.tar.gz"
        "$pkgname.desktop"
        "$pkgname.sh")
sha256sums=('2bc80991bff1284712890553c5d78a24ad12980ca5a784ec34d7887eedf48d21'
            '7fd1f624a305246fc18420e4bde343e4de70f1b83a878f84b66f1293e95c01af'
            '40edbecf7a6642ca10e61dfaead949086f23ad702bfcee49bf02c562bbb57352')

prepare() {
    cd "$pkgname-desktop-$_pkgver"

    # Skip building dist packages
    sed -i 's/"deb",/"dir"/g' package.json
    sed -i '/"AppImage",/d' package.json
    sed -i '/"tar.gz"/d' package.json
}

build() {
    cd "$pkgname-desktop-$_pkgver"
    npm install --cache "$srcdir/npm-cache"
    npm run build
    npm run package:linux
}

package() {
    cd "$pkgname-desktop-$_pkgver"
    install -d "$pkgdir/usr/lib/$pkgname"
    cp -r release/linux-unpacked/resources "$pkgdir/usr/lib/$pkgname"

    install -Dm644 src/media/icons/icon.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
    install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
    install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
}