5 rem pulizia schermo e azzeramento indice lettura
10 print chr$(147):restore
15 rem impostazione variabili
20 y=0:te=0:ih=1024:ic=40:il=0:d=0:pk=0:pc=55296
24 rem y indice lettura, te carattere da stampare
26 rem ih memoria video caratteri, ic 40 caratteri=va a capo
28 rem il indice laterale, d = direzione di scrittura 0 destra 1 sinistra,pk memorizza la riga video, pc indirizzo iniziale memoria colore
29 rem inizio ciclo principale, legge un carattere
30 read te
35 pk= (ih+il) :rem memoria video piu indice laterale
40 poke pk+y,te:poke 53280,y :rem scrive il carattere e cambia il bordo
45 poke pc+il+y,te : rem cambia il colore del carattere
50 y=y+1 :rem incrementa indice di lettura
60 if y >21 then gosub 90 :rem controlla se ha finito i caratteri
70 if ih=2024 then goto 100 :rem controlla se ha raggiunto la fine dello schermo
80 goto 30 :rem torna al ciclo principale
85 rem se il=0 scrive uno spazio dopo la frase
90 if il =0 then poke pk+22,32:goto 95
91 rem se il tra 1 e 18 scrive uno spazio prima e dopo la frase
92 if il>0 and il <19 then poke pk+22,32:poke pk-1,32
94 rem azzera indice lettura, incrementa indirizzi video e colore
95 y=0:restore:ih=ih+ic:pc=pc+ic:return
100 ih=1024:pc=55296: rem ripristina indirizzi video e colore
105 if d=1 then goto 130 : controlla la direzione di scrittura
110 if il=18 then goto 130:rem se direzione destra ha raggiunto il limite
115 il=il+1:rem incrementa indice laterale
120 goto 30
130 d=1:il=il-1 :rem inverte direzione a sinistra
140 if il=0 then goto 155 :rem se limite =0 inverte direzione verso destra
150 goto 30
155 d=0
158 goto 30
160 data 02,21,15,14,32,03,15,13
170 data 16,12,05,01,14,14,15,32
180 data 13,01,18,03,15,33,0