# Captured in 720x536 with Fraps and resized to 1920x1072 (letterboxed)
# I didn't include the code of the original functions used (it bloated the script), you can search for them on doom9.org

# File Opening
AviSource("D:\Videos\Shen41.avi") + AviSource("D:\Videos\Shen42.avi") + AviSource("D:\Videos\Shen43.avi")
AssumeFPS(59.95)
ConvertToYV12()

# Cuts the end of the last assembled video
Trim(0, 32650)

# Framerate (59.95 -> 29.97)
salfps3(framerate() / 2)

# Resize x2
nnedi3_rpow2(rfactor=2, nsize=6, nns=3, qual=2, pscrn=True, cshift="Spline36Resize", fapprox=0)
mt_lutxy(binomialblur(1.0),yexpr="x x y - abs 1 x y - 10 / / atan * +",u=2,v=2)

clpo = last
# Apply light Gauss blur to luma (maybe...me prefer not).
Clp2 = clpo.BinomialBlur(vary=2) # From tsp's VariableBlur filter

# Apply contrast S-curve to luma; slight bias to 'mid-to-highlights':
Blend_MT_alpha3(Clpo, clp2=clp2, BLMode="Overlay", Opac1=0.6, Opac2=0.7)

# Apply tint (Sienna or whatever) favouring mid-tones.
merge(Stint_v1($BAC4FF, 0.35, 140, 180, 0, 210, clp2=clpo), 0.2)

# Gamma
SmoothLevels(gamma=1.20, Smode=4)
SmoothTweak(contrast=1.1, Smode=4)

# Sharpen
source = last
sharp0 = source.sharpen(0.5)
sharpD = mt_makediff(source,sharp0)
zeroD = sharpD.mt_lut("x",Y=-128)

sup1   = source.MSuper(pel=2,sharp=1)
sup2   = sharpD.MSuper(pel=2,sharp=1,levels=1)
bv1    = sup1.MAnalyse(isb=true, delta=1)
fv1    = sup1.MAnalyse(isb=false,delta=1)
bv2    = sup1.MAnalyse(isb=true, delta=2)
fv2    = sup1.MAnalyse(isb=false,delta=2)

zeroD.MDegrain2(sup2,bv1,fv1,bv2,fv2)
source.mt_makediff(last,U=2,V=2)

# Denoiser to help compressibility
Undot()
FFT3DGPU(Sigma=1, Sharpen=0, Precision=2)

# Bloom
merge(Bloom(255), 0.25)

# "crops out bad luma/chroma values, and thus helps compression"
Limiter()

# Crop
crop(6, 0, -6, 0)

# Borders to fit 1080p
AddBorders(246, 0, 246, 0)

# Fades In & Out
FadeIn(12)
FadeOut(500)

# Audio dub
video = last
audio = WAVSource("G:\Shenmue.wav")
AudioDub(video, audio).DelayAudio(0)