Transform Boost.Test XML output to JUnit format

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:param name="package"/>
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="TestLog">
      <xsl:call-template name="testSuite"/>
  </xsl:template>
  <xsl:template name="testSuite">
    <xsl:for-each select="TestSuite">
      <testsuite>
        <xsl:attribute name="package">
            <xsl:value-of select="$package"/>
        </xsl:attribute>

        <xsl:attribute name="name">
          <xsl:value-of select="@name"/>
        </xsl:attribute>
        <!--results-->
          <xsl:call-template name="testSuite"/>
          <xsl:for-each select="TestCase">
            <testcase>
              <xsl:call-template name="testAttributes"/>
              <xsl:call-template name="testCaseElements"/>
            </testcase>
          </xsl:for-each>
        <!--/results-->
      </testsuite>
    </xsl:for-each>
  </xsl:template>
  <xsl:template name="testAttributes">
    <xsl:attribute name="name">
      <xsl:value-of select="@name"/>
    </xsl:attribute>
    <xsl:attribute name="time">
      <xsl:value-of select="TestingTime div 1000000"/>
    </xsl:attribute>
  </xsl:template>
  <xsl:template name="testCaseElements">
    <xsl:for-each select="Error|Exception">
      <error>
        <xsl:call-template name="caseElement"/>
      </error>
    </xsl:for-each>
    <xsl:for-each select="Warning">
      <failure>
        <xsl:call-template name="caseElement"/>
      </failure>
    </xsl:for-each>
  </xsl:template>
  <xsl:template name="caseElement">
    <xsl:attribute name="type">
      <xsl:value-of select="@file"/>
      <xsl:text>(</xsl:text>
      <xsl:value-of select="@line"/>
      <xsl:text>)</xsl:text>
    </xsl:attribute>
    <xsl:value-of select="."/>
  </xsl:template>
</xsl:stylesheet>