screencast-git PKGBUILD

# Maintainer: Daniel Bermond < yahoo-com: danielbermond >

_srcname=screencast
pkgname=screencast-git
pkgver=1.4.0.r166.gd8923d6
pkgrel=1
pkgdesc='Command line interface to record a X11 desktop (git version)'
arch=('any')
url='https://github.com/dbermond/screencast/'
license=('GPL')
depends=('ffmpeg' 'xorg-xdpyinfo' 'libnotify' 'oxygen-icons')
makedepends=('git')
optdepends=('bc: fade effect support'
            'imagemagick: watermark effect support'
            'slop: graphical screen region selection support'
            'sound-theme-freedesktop: sound notification support'
            'truepng: watermark optimization support'
            'pingo: watermark optimization support'
            'optipng: watermark optimization support'
            'littleutils-full: watermark optimization support'
            'advancecomp: watermark optimization support')
provides=('screencast')
conflicts=('screencast')
source=("$_srcname"::'git+https://github.com/dbermond/screencast.git')
sha256sums=('SKIP')

pkgver() {
    cd "$_srcname"

    # git, tags available
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cd "$srcdir/$_srcname"
    make
}

package() {
    cd "$srcdir/$_srcname"
    make install \
        DESTDIR="$pkgdir/" \
        PREFIX="/usr" \
        DOCDIR="/usr/share/doc"
        MANDIR="/usr/share/man" \
        BCOMPDIR="/usr/share/bash-completion/completions"
}