cpufreqd_PKGBUILD

# Maintainer: Blaž Tomažič <blaz.tomazic@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Kevin Piche <kevin@archlinux.org>
# Contributor: Manolis Tzanidakis <manolis@archlinux.org>

pkgname=cpufreqd
pkgver=2.4.2
pkgrel=5
pkgdesc="A small daemon to adjust cpu speed (and indeed voltage)"
arch=('i686' 'x86_64')
url="http://www.linux.it/~malattia/wiki/index.php/Cpufreqd"
license=('GPL2')
depends=('cpupower' 'lm_sensors')
backup=('etc/cpufreqd.conf')
options=('!libtool')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2"
                'cpufreqd'
                'cpufreqd.service'
                'cpufreqd_acpi_battery.c.patch'
                'cpupower.patch')
md5sums=('2ca80a77849c9a69b81e27c1843c97f5'
         'ae7b0ec1e8e9f9e7f05fb83749af4ed4'
         'ea85c07e21d1b9aeb96380164ebe341c'
         'f3c8c669bee0b5f39a7e1c26e14bead3'
         'df997964122d19068ab1432af780d09a')

build() {
  cd ${srcdir}

  #patch acpi
  patch -p0 < cpufreqd_acpi_battery.c.patch


  cd ${pkgname}-${pkgver}

  #patch for cpupower support
  patch -Np1 -i "${srcdir}/cpupower.patch"
  autoreconf -i

  ./configure --prefix=/usr \
    --sysconfdir=/etc
  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install || return 1

  install -Dm755 ${srcdir}/cpufreqd ${pkgdir}/etc/rc.d/cpufreqd || return 1
  install -Dm644 ${srcdir}/cpufreqd.service ${pkgdir}/usr/lib/systemd/system/cpufreqd.service || return 1
}