;==================================
; Script Name: Alchemy for Freeshards
; Author: ReDragoN
; Version: 1.1
; Client Tested with: 2.0.3
; EUO version tested with: 1.42.0098
; Shard OSI / FS: Mythik Sphere
; Revision Date: 24.01.05
; Public Release: 02.11.04
; Purpose: Will train alchemy. You can set the pot you want to craft.
; Disclaimer:  You can modify it, but leave this header
;==================================

; ID of the KEG
Set %KegID XXXXXX

; BagPack ID
Set %BackPackID XXXXXX

; ID of the bag with regs
Set %RegBagID XXXXXX

; X/Y where you macro
Set %MoveX X
Set %MoveY Y

; IDTYPE of the reg
Set %IDType HUF ; blackmoor

; Color of the pot (you can find it with #findcol)
Set %ColorPot 1153

; Where you will click on the craft gump
Set %ClickMX 146
Set %ClickMY 67

Set %TheSkill Alchemy
Gosub Skill %TheSkill startskill
Set %AlchCounter #Scnt2 + 300
Set %Pot 0

MakePot:
IgnoreItem Reset
Set %TimeOut #Scnt + 4
FindItem WUF C_ , %BackPackID
If #FindCol = %ColorPot
Goto FillKeg
FindItem %IDType C_ , %BackPackID
If #FindKind = -1 || #FindStack < 2
Goto DragReg
Set #LObjectID #FindID
Event Macro 17
WaitAlchGump:
If #scnt >= %TimeOut
Goto MakePot
If #ContName <> objpicker_gump
Goto WaitAlchGump
ContPos 0 0
Click %ClickMX %ClickMY d f
Gosub Eat
Gosub AlchemySkill
Set %TimeOut #Scnt + 12
Goto FillKeg

FillKeg:
If #Scnt >= %TimeOut
Goto MakePot
FindItem WUF C_ , %BackPackID
If #FindCol = 0 2
IgnoreItem #FindID
Goto FillKeg
If #FindCol = %ColorPot
Goto Keg
Goto FillKeg

Keg:
FindItem WUF C_ , %BackPackID
If #FindCol <> %ColorPot 2
IgnoreItem #FindID
Goto Keg
Set #LTargetID #FindID
Set #LTargetKind 1
FindItem %KegID G_1
Set #LObjectID #FindID
Event Macro 17
Target
Event Macro 22
Gosub Skill %TheSkill skillnow
Gosub Skill %TheSkill gain
SetUoTitle Ultima Online - #Charname - #shard ((( Macroing : %TheSkill ||| Start Skill : %StartSkill ||| Skill Now : %SkillNow ||| Gain : %Gain )))
Set %Pot %Pot + 1
Goto MakePot

DragReg:
Set #LObjectID %RegBagID
Event Macro 17
WaitBagGump:
If #ContName <> container_gump
Goto WaitBagGump
Wait 1s
ContPos 10 10
Gosub Drag %IDType 500 320 200 C_ , %RegBagID
Click 30 30 r
Move %movex %movey 0
Goto MakePot

Sub Eat
FindItem RUD G_2
Set #lObjectID #FindID
Event Macro 17
Return

Sub AlchemySkill
If #Scnt2 > %AlchCounter 5
Msg $
Msg + Alchemy Skill +$
Msg Skill : %SkillNow & Gain : %Gain $
Msg Pot Crafted : %Pot $
Set %AlchCounter #Scnt2 + 300
Return




;========================================
; Script Name: Janus' Drag & Drop Sub
; Author: Janus
; Version: 1.3
; Client Tested with: 4.0.1a client and 4.0.1e
; EUO version tested with: 1.42 B0094
; Shard OSI / FS: Local Pol Server and OSI Oceana
; Revision Date: 07-27-04
; Public Release: 07-27-04
; Purpose: Drags and Drops Items to a specified location in light velocity
;========================================
sub drag
drag:
wait %6
if #contname = drag_gump
goto waitfordraggump
if #contname = stack_gump
goto waitforstackgump
finditem %1 %5
if #findkind = -1
return
Event Drag #FindID
waitforstackgump:
if #contname = drag_gump || #findstack < 2
goto waitfordraggump
if #contname <> stack_gump && #findstack > 1
goto waitforstackgump
if %2 = all
msg $
else
msg %2 $
waitfordraggump:
if #contname <> drag_gump
goto waitfordraggump
click %3 %4 p
if %2 = all
goto drag
else
return


;========================================
; Script Name: Janus' Skillgain Sub
; Author: Janus
; Version: 1.0
; Client Tested with: 4.0.1a client
; EUO version tested with: 1.42 B0094
; Shard OSI / FS: Local Pol Server
; Revision Date: 07-26-04
; Public Release: 07-26-04
; Purpose: Skillgain Check and formation
;========================================

sub skill
chooseskill %1 real
if %2 = startskill
set %src_ss #skill
set %src_skill #skill
set %skill #skill
set %gain %src_skill - %src_ss
if %2 = gain
set %skill %gain
str len %skill
if #strres < 2 2
str ins %skill #dot #strres
set %skill 0 , #strres
else 2
str ins %skill #dot #strres
set %skill #strres
if %2 = gain
set %gain %skill
if %2 = startskill
set %startskill %skill
if %2 = skillnow
set %skillnow %skill
return