matchbox-keyboard_git.bb fixes yocto error for .so files

DESCRIPTION = "Matchbox virtual keyboard for X11"
HOMEPAGE = "http://matchbox-project.org"
BUGTRACKER = "http://bugzilla.openedhand.com/"
SECTION = "x11"

LICENSE = "GPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
                    file://src/matchbox-keyboard.h;endline=20;md5=d12cc878e2a99870458c83c61714d99e \
                    file://applet/applet.c;endline=20;md5=16d84e4d1572415c1295d37ca6d05dd4"

DEPENDS = "libfakekey expat libxft gtk+ matchbox-panel-2"

SRCREV = "b38f24036cff3be6c2fbcf9ca9881803e69003ac"
PV = "0.0+git${SRCPV}"
PR = "r4"

SRC_URI = "git://git.yoctoproject.org/${BPN} \
           file://configure_fix.patch;maxrev=1819 \
           file://single-instance.patch \
           file://80matchboxkeyboard.shbg"

S = "${WORKDIR}/git"

inherit autotools pkgconfig gettext gtk-immodules-cache

EXTRA_OECONF = "--disable-cairo --enable-gtk-im --enable-applet"

PACKAGES += "${PN}-im ${PN}-applet"

FILES_${PN} = "${bindir}/ \
	       ${sysconfdir} \
	       ${datadir}/applications \
	       ${datadir}/pixmaps \
	       ${datadir}/matchbox-keyboard"

FILES_${PN}-dbg += "${libdir}/gtk-2.0/*/immodules/.debug"

FILES_${PN} += "${libdir}/libmatchbox-keyboard.so.0.0.0"

FILES_${PN} += "${libdir}/libmatchbox-keyboard.so.0"

FILES_${PN}-im += "${libdir}/gtk-2.0/*/immodules/*.so"

FILES_${PN}-applet += "${libdir}/matchbox-panel/*.so"

do_install_append () {
	install -d ${D}/${sysconfdir}/X11/Xsession.d/
	install -m 755 ${WORKDIR}/80matchboxkeyboard.shbg ${D}/${sysconfdir}/X11/Xsession.d/

	rm -f ${D}${libdir}/gtk-2.0/*/immodules/*.la
	rm -f ${D}${libdir}/matchbox-panel/*.la
}

GTKIMMODULES_PACKAGES = "${PN}-im"

RDEPENDS_${PN} = "formfactor dbus-wait"
RRECOMMENDS_${PN} = "${PN}-applet"