igm AD 2

Let's make a game!
name:Antimatter Dimensions
by:slabdrill
desc:A game about making antimatter.
//forum post:
created:24/10/2017
updated:24/10/2017
version:0

Settings
building cost increase:100%
building cost refund:0%

//Buttons

Resources
*m|d0a
 name: Antimatter

*TEMPLATE
 tags: da rl
*d1a
*d2a
*d3a
*d4a
*d5a
*d6a
*d7a
*d8a

*TEMPLATE
 tags:dc rl
 always hidden
*d1c
*d2c
*d3c
*d4c
*d5c
*d6c
*d7c
*d8c

Buildings
*ts
 tag:rl
 cost:1000 m
 cost increase:1000%
 req:1 d2a
 desc:decreases tickspeed by 11%
*resets
 cost:20 d8a
 name:Reset the game for a Boost
 on earn:do reset with core

*TEMPLATE
 limit:10
 tags:db rl
*d1b
 cost:10 m
 passive:grant 1 d1a
*d2b
 cost:100 m
 passive:grant 1 d2a
 req:1 d1a
*d3b
 cost:1e4 m
 passive:grant 1 d3a
 req:1 d2a
*d4b
 cost:1e6 m
 passive:grant 1 d4a
 req:1 d3a
*d5b
 cost:1e9 m
 passive:grant 1 d5a
 req:1 d4a,1 resets
*d6b
 cost:1e13 m
 passive:grant 1 d6a
 req:1 d5a,2 resets
*d7b
 cost:1e18 m
 passive:grant 1 d7a
 req:1 d6a,3 resets
*d8b
 cost:1e24 m
 passive:grant 1 d8a
 req:1 d7a,4 resets

Upgrades
*cheat
 cost:10 m
 on tick:gain 1e6 m
*cheat2
 req:cheat
 desc:you dirty cheater
 cost:1e6 m
 on tick:gain 1e6 d4a

*TEMPLATE
 passive:grant 1 resets
 name:Reset the game for a new Dimension
 on earn:do reset with core
*reset1
 cost:20 d4a
*reset2
 req:reset1
 cost:20 d5a
*reset3
 req:reset2
 cost:20 d6a
*reset4
 req:reset3
 cost:20 d7a

Includes
*include b10c %num %ci %numm
 if (d[%num]b>=10)
  lose 10 d[%num]b
  gain 10 d[%num]a
  gain [%ci] d[%num]c
  multiply cost of d[%num]b by 1e[%ci]
 end
 multiply cost of d[%num]b by pow(10,d[%num]c)
 multiply d[%numm]a yield of core by pow(2,d[%num]c)
 multiply d[%numm]a yield of core by max(pow(2,resets-[%numm]),1)
 multiply d[%numm]a yield of core by d[%num]a
 multiply d[%numm]a yield of core by pow(1/0.89,ts)
 if (d[%num]a:max>0) gain 0.1 d[%numm]a
//the if should be unnecessary but it seems to be anyway

//Items

Achievements
*core
 owned
 always hidden
 passive:
  multiply m yield of core by 10
  [include b10c %num="1" %ci="3" %numm="0"]
  [include b10c %num="2" %ci="4" %numm="1"]
  [include b10c %num="3" %ci="5" %numm="2"]
  [include b10c %num="4" %ci="6" %numm="3"]
  [include b10c %num="5" %ci="8" %numm="4"]
  [include b10c %num="6" %ci="10" %numm="5"]
  [include b10c %num="7" %ci="12" %numm="6"]
  [include b10c %num="8" %ci="15" %numm="7"]
  increase cost of resets by 15*max(resets-4,0)
 end
 on reset:
  lose tag:rl
  m=10
 end
 on start:do reset

//Shinies