Vine Bot 3

$${
// http://i.imgur.com/OgnANA5.jpg

volume(0);

#south = 4144;
#north = 4103;
#minfood = 17;

#wait = 200;

pick(shears);

#y_anchor = %YPOS%
do;
	//Eat
	look(0,90);
	if(%HUNGER% < %#minfood%);
		&foods[] = split(" ",$$<foods.txt>);
		foreach(&foods,&cfood);
			pick("%&cfood%");
		next;
		wait(%#wait%ms);
		do(150);
			key(use);
		loop;
	endif;

	keyup(back);
	keydown(forward);
	look(west);
	if(%ZPOS%!=#north);
		// crouch, look north, and attack until north end of farm is reached
		do;
			#cx=%ZPOS%;
			do;
				// Disconnect if we've fallen in the water
				if(#y_anchor != %YPOS%);
					disconnect();
				endif;
				pick("shears");
				if(%ITEM% = "shears");
						keydown(right);
						keydown(sneak);
						look(west);
						key(attack);
						key(use);

				else;
					$$<get_shears.txt>
					wait(%#wait%ms);
					pick("shears");
					wait(%#wait%ms);
				endif;
			until(%#cx%!=%ZPOS%);
		until(%ZPOS% = #north);
		wait(200ms);
		keyup(left);
	endif;

	if(%ZPOS% !=#south);
		keyup(forward);
		keydown(back);
		// crouch, look east, and attack until south end of farm is reached
		do;
			#cx=%ZPOS%;
			do;
				// Disconnect if we've fallen in the water
				if(#y_anchor != %YPOS%);
					disconnect();
				endif;
				pick("shears");
				if(%ITEM% = "shears");
					keydown(right);
					keydown(sneak);
					look(east);
					key(attack);
					key(use);
				else;
					$$<get_shears.txt>
					wait(%#wait%ms);
					pick("shears");
				endif;
			until(%#cx%!=%ZPOS%);
		until(%ZPOS% = #south);
		wait(200ms);
		keyup(right);
	endif;
loop;

stop();
}$$