PKGBUILD: dxfplotter version 1.5.2

# Maintainer:  Tristan Porteries <[email protected]>
# Contributor: dreieck (https://aur.archlinux.org/account/dreieck)
# Contributor: Tristan Porteries <[email protected]>

pkgname=dxfplotter
pkgver=1.5.2
pkgrel=1
pkgdesc="Fast and easy to use DXF to GCode converter for laser and router CNC"
arch=("x86_64" "i686" "aarch64")
url="https://github.com/panzergame/dxfplotter"
license=("MIT")
makedepends=(git cmake make python python-jinja "eigen>=3")
depends=("qt6-3d" "qt6-base")
provides=("dxfplotter")
source=(
  "$pkgname-$pkgver::git+https://github.com/panzergame/$pkgname.git#tag=v${pkgver}"
  "nanoflann::git+https://github.com/jlblancoc/nanoflann.git"
  "CavalierContours::git+https://github.com/jbuckmccready/CavalierContours.git"
  "cereal::git+https://github.com/USCiLab/cereal.git"
  "yaml-cpp::git+https://github.com/jbeder/yaml-cpp.git"
  "fmt::git+https://github.com/fmtlib/fmt.git"
  "or-tools::git+https://github.com/google/or-tools.git"
)
md5sums=(
  'SKIP'
  'SKIP'
  'SKIP'
  'SKIP'
  'SKIP'
  'SKIP'
  'SKIP'
)

prepare() {
  cd "$pkgname-$pkgver"
  git submodule init
  local _gitmodule
  for _gitmodule in nanoflann CavalierContours cereal yaml-cpp fmt or-tools; do
    git config submodule.thirdparty/"${_gitmodule}".url  "${srcdir}/${_gitmodule}"
  done
  git -c protocol.file.allow=always submodule update
}

build() {

# Silence some compiler warnings:
local _SILENCEWARNINGS=("misleading-indentation" "dangling-reference" "unused-parameter" "sfinae-incomplete" "implicit-fallthrough")
local _CFLAGSADDITIONS=""
local _warning
for _warning in "${_SILENCEWARNINGS[@]}"; do
  _CFLAGSADDITIONS+=" -Wno-${_warning}"
done
CXXFLAGS+="${_CFLAGSADDITIONS}"
export CXXFLAGS

  cmake \
    -S "$pkgname-$pkgver" -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_BINDIR=/usr/bin \
    -DCMAKE_INSTALL_SBINDIR=/usr/bin \
    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
    -DCMAKE_INSTALL_DATAROOTDIR=/usr/share \
    -DCMAKE_INSTALL_INCLUDEDIR=/usr/include \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCMAKE_INSTALL_LIBEXECDIR=/usr/libexec \
    -DCMAKE_INSTALL_DOCDIR=/usr/share/doc \
    -DCMAKE_INSTALL_INFODIR=/usr/share/info \
    -DCMAKE_INSTALL_MANDIR=/usr/share/man \
    -DCMAKE_INSTALL_LOCALSTATEDIR=/var \
    -DCMAKE_INSTALL_RUNSTATEDIR=/var/run \
    -DWITH_ORTOOLS=OFF \
    -DBUILD_TESTING=OFF \
    -DWITH_WERROR=OFF \
    -Wno-dev
  cmake --build build --target "$pkgname"
}

package() {
  cmake --install build --prefix "$pkgdir"

  # Fixup messed up installation directories
  install -dvm 755 "${pkgdir}/usr/bin"
  mv -v "${pkgdir}/bin"/* "${pkgdir}/usr/bin"/
  rmdir -v "${pkgdir}/bin"
  install -dvm 755 "${pkgdir}/usr/share"
  mv -v "${pkgdir}/share"/* "${pkgdir}/usr/share"/
  rmdir -v "${pkgdir}/share"

  cd "$pkgname-$pkgver"
  install -Dvm644 -t "${pkgdir}/usr/share/doc/${pkgname}"      CHANGELOG.md README.md
  install -Dvm644 -t "${pkgdir}/usr/share/doc/${pkgname}/doc"  doc/*
  install -Dvm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENCE.txt
}