buildscript {
    repositories {
        jcenter()
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

plugins {
    id 'com.github.johnrengelman.shadow' version '1.2.3'
}

apply plugin: 'net.minecraftforge.gradle.forge'

ext.configFile = file "build.properties"

configFile.withReader {
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

version = config.mod_version
group = config.mod_group
archivesBaseName = config.mod_name

if (System.getenv().BUILD_NUMBER)
    version = "${config.mod_version}.b${System.getenv().BUILD_NUMBER}"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "${config.mc_version}-${config.forge_version}"
    runDir = "run"
    // the mappings can be changed at any time, and must be in the following format.
    // snapshot_YYYYMMDD   snapshot are built nightly.
    // stable_#            stables are built at the discretion of the MCP team.
    // Use non-default mappings at your own risk. they may not always work.
    // simply re-run your setup task after changing the mappings to update your workspace.
    mappings = "snapshot_20170624"
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.

}

dependencies {
	compile 'org.apache.httpcomponents:httpcore:4.4.6'
	compile 'org.apache.httpcomponents:httpcore-nio:4.4.6'
	compile 'org.apache.httpcomponents:httpclient:4.5.3'
	compile 'org.apache.httpcomponents:httpasyncclient:4.1.3'
	compile 'org.apache.httpcomponents:httpcore-nio:4.4.6'
	compile 'org.apache.httpcomponents:httpmime:4.5.3'
	compile 'org.json:json:20170516'
	compile 'com.mashape.unirest:unirest-java:1.4.9'
	compile 'commons-logging:commons-logging:1.2'
	compile 'org.bouncycastle:bcprov-jdk15on:1.57'
}

shadowJar {
    dependencies {
        include(dependency('org.apache.httpcomponents:httpcore:4.4.6'))
		include(dependency('org.apache.httpcomponents:httpcore-nio:4.4.6'))
		include(dependency('org.apache.httpcomponents:httpclient:4.5.3'))
		include(dependency('org.apache.httpcomponents:httpasyncclient:4.1.3'))
		include(dependency('org.apache.httpcomponents:httpcore-nio:4.4.6'))
		include(dependency('org.apache.httpcomponents:httpmime:4.5.3'))
		include(dependency('org.json:json:20170516'))
		include(dependency('com.mashape.unirest:unirest-java:1.4.9'))
		include(dependency('commons-logging:commons-logging:1.2'))
    }

    relocate 'org.apache.http', 'com.mattsmeets.lib.org.apache.http'
	relocate 'org.apache.commons.logging', 'com.mattsmeets.lib.org.apache.commons.logging'
	relocate 'org.json', 'com.mattsmeets.lib.org.json'
	relocate 'mozilla', 'com.mattsmeets.lib.mozilla'
	relocate 'com.mashape.unirest', 'com.mattsmeets.lib.com.mashape.unirest'
	relocate 'dummyThing', 'com.mattsmeets.lib.dummyThing'

    classifier ''
}

reobf {
    shadowJar {}
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
		include '**/reference.properties'

        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }

    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
		exclude '**/reference.properties'
    }
}