organ tile

    if (true) {
        string image_name = "__item hell ramen";
        ChecklistSubentry [int] subentries;
        int importance = 11;
        if (availableFullness() > 0) {
            string [int] description;
            if ($effect[Got Milk].have_effect() > 0)
                description.listAppend(pluralise($effect[Got Milk]) + " available (woah).");
            if (!get_property_boolean("_milkOfMagnesiumUsed") && lookupItem("milk of magnesium").available_amount() > 0)
                description.listAppend("Use Milk of Magnesium for +5 adv.");
            if ($effect[barrel of laughs].have_effect() >= 5) {
                int turns = $effect[barrel of laughs].have_effect();
                description.listAppend(pluralise($effect[barrel of laughs]) + " available" + (turns % 5 > 0 ? " (" + (turns - turns % 5) + ")" : "") + ".");
            }
            subentries.listAppend(ChecklistSubentryMake(availableFullness() + " fullness", "", description));
        }
        if (inebriety_limit() > 0) {
            boolean stooperIsEquipped = my_familiar() == lookupFamiliar("Stooper");
            boolean couldEquipStooper = lookupFamiliar("Stooper").familiar_is_usable() && !stooperIsEquipped;
            string title = "";
            string [int] description;
            if (availableDrunkenness() >= 0) {
                boolean shotglassDrinkAvailable = !get_property_boolean("_mimeArmyShotglassUsed") && lookupItem("mime army shotglass").is_unrestricted() && lookupItem("mime army shotglass").available_amount() > 0;
                if (subentries.count() == 0)
                    image_name = "__item gibson";
                if ($effect[ode to booze].have_effect() > 0)
                    description.listAppend(pluralise($effect[ode to booze]) + " available.");
                if ($effect[salty mouth].have_effect() > 0)
                    description.listAppend(pluralise($effect[salty mouth]) + " available. Drink beer for +5 adv!");
                if ($effect[beer barrel polka].have_effect() >= 5) {
                    int turns = $effect[beer barrel polka].have_effect();
                    description.listAppend(pluralise($effect[beer barrel polka]) + " available" + (turns % 5 > 0 ? " (" + (turns - turns % 5) + ")" : "") + ".");
                }

                if (availableDrunkenness() > 0)
                    title = availableDrunkenness() + " drunkenness" + (couldEquipStooper ? " + Stooper" : "");
                else {
                    title = "Can overdrink";
                    if (couldEquipStooper)
                        description.listAppend("Could equip Stooper for +1 drunkenness.");
                }
                if (shotglassDrinkAvailable)
                    description.listAppend("1 free 1-drunkenness booze available.");
                subentries.listAppend(ChecklistSubentryMake(title, "", description));
            } else if (availableDrunkenness() == -1 && couldEquipStooper) {
                importance = -11;
                title = HTMLGenerateSpanFont("Equip the Stooper", "red");
                image_name = "__familiar stooper";
                description.listAppend("Can keep adventuring/overdrink further as long as it's equipped.");
                subentries.listAppend(ChecklistSubentryMake(title, "", description));
            }
        }
        if (availableSpleen() > 0) {
            if (subentries.count() == 0)
                image_name = "__item agua de vida";
            subentries.listAppend(ChecklistSubentryMake(availableSpleen() + " spleen", "", ""));
        }
        if (subentries.count() > 0)
            resource_entries.listAppend(ChecklistEntryMake(image_name, "inventory.php?which=1", subentries, importance));
    }