Wolfenstein: TNO Streams Extractor

open FDSE streamed.resources 1 MAIN_SOUND
open FDSE english.streamed 2 ENG_SOUND
#open FDSE french.streamed 3 FRA_SOUND
#open FDSE italian.streamed 4 ITA_SOUND
#open FDSE spanish.streamed 5 SPA_SOUND
#open FDSE japanese.streamed 6 JAP_SOUND

endian big
goto 0x24
get files long
get unk long
math TMP = files
math TMP - 1
for i = 0 < files
	endian little
	get FNsize1 long
	getdstring FN1 FNsize1
	get FNsize2 long
	getdstring FN2 FNsize2
	get namesize long
	getdstring name namesize
	endian big
	get offset long
	get size long
	get zsize long
	get streams long

	string bname = name
	string bname > "."

	for j = 0 < streams
		getdstring lang 0x10
		get offset long
		get size long

		string sname = bname

		if lang == ""
			if streams > 1
				# .samplepack files
				string sname p "%s_%d" sname j
			endif

			if MAIN_SOUND == 1
				log sname offset size 1
			endif
		else
			string sname p "%s_%s" sname lang
			if lang == "english"
				if ENG_SOUND == 1
					log sname offset size 2
				endif
			elif lang == "french"
				if FRA_SOUND == 1
					log sname offset size 3
				endif
			elif lang == "italian"
				if ITA_SOUND == 1
					log sname offset size 4
				endif
			elif lang == "spanish"
				if SPA_SOUND == 1
					log sname offset size 5
				endif
			elif lang == "japanese"
				if JAP_SOUND == 1
					log sname offset size 6
				endif
			endif
		endif
	next j

	goto 0x05 0 SEEK_CUR

	if i != TMP
		get filenumber long
	endif
next i