2 point coordinate system

macroScript igorznag_2_point_coordinate_system category:"_igorznag" buttonText:"2 Point CS"
(
	global igorznag_2_point_coordinate_system_point1, igorznag_2_point_coordinate_system_draw_info
	fn igorznag_2_point_coordinate_system_draw_info =
	(
		gw.setTransform(Matrix3 1)
		p = gw.hTransPoint igorznag_2_point_coordinate_system_point1; gw.hText p "Point 1" color:[0,255,0]
		gw.enlargeUpdateRect #whole; gw.updateScreen()
	)--fn igorznag_2_point_coordinate_system_draw_info =
	snapMode.Active = true; pt1 = pickpoint snap:#3d
	if classof pt1 == point3 then
	(
		igorznag_2_point_coordinate_system_point1=pt1
		unregisterRedrawViewsCallback igorznag_2_point_coordinate_system_draw_info
		registerRedrawViewsCallback igorznag_2_point_coordinate_system_draw_info
		pt2 = pickpoint snap:#3d rubberband:pt1
		unregisterRedrawViewsCallback igorznag_2_point_coordinate_system_draw_info
		if classof pt2 == point3 then
		(
			t=matrixfromnormal (normalize (pt2-pt1)); t.pos=1.0*(pt1+pt2)/2.0
			try delete $igorznag_dummy catch ()
			d=dummy(); d.name="igorznag_dummy"; freeze d; hide d
			d.transform=t; toolmode.coordsys d; completeredraw()
		)--if classof pt2 == point3 then
	)--if classof pt1 == point3 then
	snapMode.Active = false
)--macroscript