Come on!

Let's make a game!
    name:Country Clicker
    by:thedarkwaterbun and Simanalix
    desc:Your goal is to fill this infinite flatland with a glorious empire of many countries. Get started by clicking Explore (the big flag button).
    /*date should be YYYY/MM/DD for clarity among countries*/
    created:2020/05/05
    updated:2020/05/05
    version:0.2
/*
    Let's talk about the gimmick of this game.
    Story Logic:
    We start with a never ending flat world, with plenty of land to form new countries.
    We are an astounding grand president, who can make new countries with ease.
    We click to explore new land, and make new countries. We can set up
    Unions to make new countries. As our union grows it gets more powerful, but it also becomes increasingly difficult to get to new land, and control land we already have. For this reason, (in the beginning) Unions constantly produce the same amounts of countries.
    Continental, and World Unions can be set up, which are bigger and more efficient than normal Unions.
    Unions grow in price, or how many countries are needed to run them, because each Unions gets in the way of the last, and it is harder for us to maintain that many Unions.
        ----
    The story logic above is how we determine names and descriptions of things.
        ----
    Descriptions are to be formatted like this, to make them nice and fancy: <q>Fun description</q></><b>Effect:<b></>Effect Description
    Where Fun description and Effect description can be replaced by whatever the description of the thing is.
    This is a nice template:
    <q>.</q></><b>Effect:</b></>.
*/
Settings
    stylesheet:https://pastebin.com/aJjQUHiH
    background:https://scx2.b-cdn.net/gfx/news/hires/2019/4-space.jpg
    cost refund:0.5%
    cost increase:120%
/*---------------------------------------------------*/
Layout
*g1
contains:Resources
*g2
contains:tag:inmainbox
*g3
contains:Achievements
*g4
contains:Buildings
*g5
contains:tag:inbulkandsellbox
*g6
contains:Upgrades
*g7
contains:Log
/*---------------------------------------------------*/
Resources
    *TEMPLATE
        always hidden
    *hasstarted
    *TEMPLATE
        show earned
    *Country|Countries
        name:Country|Countries
        desc:These are your countries. Make more of these to expand your world!
        icon:
    *PoliPoint|PoliPoints
        name:PoliPoint|PoliPoints
        desc:These are PoliPoints. They increase production (+1% per point to all buildings), and are lost when upgrades are bought!
        icon:
        req:have Politics
    *money
        name:Money
        desc:Coins, bills, this is general currency. It holds inherent economic and resource value. This stuff can be bad though!
        icon:
        req:have Politics
Buttons
    *Explore
        name:Explore
        desc:<q>You are a <b>grand</b> president. Go out, and explore.</q></><b>Effect:</b></>Clicking this gives you 1 country.
        on click:yield 1 Country
        icon:
        class:bigButton hasFlares
        tags:inmainbox
    *Sell
        name:Sell
        desc:Click this to activate selling buildings instead of buying them (not a feature yet).
        /*
        on click:lose Sellmode-1 Sellmode
        */
        tags:inbulkandsellbox
Buildings
/*
    *thing
        name:
        desc:<q>.</q></><b>Effect:</b></>.
        icon:
        on tick:
            yield n Countries
            yield n0 money
        end
        cost:n Countries
        req:n n
*/
    *TEMPLATE
        on click:anim glow
    *Politician|Politicians
        name:Politician|Politicians
        desc:<q>These are your extra politicians</q></><b>Effect:</b></>Keep countries stable, and offer 1 PoliPoint per second, each costing 100 money.
        on tick:yield 1 PoliPoints
        icon:
        cost:10000 money
        req:have Politics

    *StateUnion|StateUnions
        name:State Union|State Unions
        desc:<q>Isn't ‘United States’?</q></><b>Effect:</b></>Produces 1 Country every second (automatically), or 1 CountryPS.
        on tick:
            yield 1*(1+0.01*PoliPoints) Country
            yield 10 money
        end
        icon:
        cost:60 Countries
        req:10 Countries
    *NationUnion|NationUnions
        name:Nation Union|Nation Unions
        desc:<q>Bring together some nations into a bigger union.</q></><b>Effect:</b></>8 CountriesPS
        icon:
        on tick:
            yield 8*(1+0.01*PoliPoints) Countries
            yield 80 money
        end
        cost:640 Countries
        req:10 StateUnions
    *ContinentUnion|ContinentUnions
        name:Continent Union|Continent Unions
        desc:<q>Bring together a whole continent</q></><b>Effect:</b></>64 CountriesPS
        on tick:
            yield 64*(1+0.01*PoliPoints) Countries
            yield 640 money
        end
        icon:
        cost:6400 Countries
        req:10 NationUnions
    *WorldUnion|WorldUnions
        name:World Union|World Unions
        desc:<q>A huge empire made of many worlds.</q></><b>Effect:</b></>510 CountiresPS
        on tick:
            yield 510*(1+0.01*PoliPoints) Countries
            yield 5100 money
        end
        icon:
        cost:61200 Countries
        req:10 ContinentUnions
    *EmpireUnion|EmpireUnions
        name:Empire Union|Empire Unions
        desc:<q>Huge Empires, each of many worlds, put together!!</q></><b>Effect:</b></>4000 CountriesPS
        on tick:
            yield 4000*(1+0.01*PoliPoints) Countries
            yield 40000 money
        end
        icon:
        cost:560000 Countries
        req:10 WorldUnions
Upgrades
    *TEMPLATE
        on click:anim glow
/*
    *thing
        name:
        desc:<q>.</q></><b>Effect:</b></>.
        on earn:
            lose n PoliPoints
            //
            //
        end
        icon:
        cost:n n
        req:n n
*/
    *U0
        name:Personal Army
        desc:<q>Bring an army around with you when you  explore!</q></><b>Effect:</b></>Get twice as many Countries per click (CountriesPC x2)
        on earn:lose 200 PoliPoints
        passive:multiply Country yield of Explore by 2
        icon:
        cost:250 Countries
        req:10 StateUnions
    *U1
        name:Constitutions
        desc:<q>With constitutions, your state unions can keep their states in chek</q></><b>Effect:</b></>double CountryPS from State Unions
        on earn:lose 200 PoliPoints
        passive:multiply Country yield of Explore by 2
        icon:
        cost:600 Countries
        req:5 StateUnions
    *Politics
    name:Politics
        desc:<q>Politics is inevitable, but be careful with it!</q></><b>Effect:</b></>Unlock a new building: <b>Politicians</b>
        icon:
        cost:2000 Countries
        req:10000 Countries:earned
    *Log
        start with
        always hidden
        name:Log
        on start:
            log <g>Welcome to Country Clicker. You are a <b>Grand</b> President, and your goal is to expand your empire, making new countries in this endless flatland.</q></> Click the Explore button (the globe) to get started!
        end
        on load:
            if (hasstarted>0) clear log
            log <i>This is the log. Info on every update can be found here.</i><//><b>Version 0.3</b></><.>Made the alpha game.<.>Added 2 upgrades<.>Added 3 Resources<.>Added 6 Unions<.>Added the Explore button, and a button that currently does nothing.
            yield 1 hasstarted
        end
Achievements
/*
    *A
        name:
        desc:<q>.</q></><b>Requirement:</b></>.
        icon:
        req:n n
*/
    *A0
        name:Whole World
        desc:<q>A world:</>A large collection of places and societies. </q></><b>Requirement:</b></>Have 1000 Countries
        icon:
        req:1000 Countries