* Delineamento e An�lise de Experimentos 1
* Delineamentos Fatoriais completamente casualizados
* Exemplo 15.8 de Ott e Longnecker - Entregue em sala de aula
* Prof. George von Borries;


data fruit;
  input pesticide variety yield @@;
  datalines;
  1 1 49 1 1 39 1 2 55 1 2 41 1 3 66 1 3 68
  2 1 50 2 1 55 2 2 67 2 2 58 2 3 85 2 3 92
  3 1 43 3 1 38 3 2 53 3 2 42 3 3 69 3 3 62
  4 1 53 4 1 48 4 2 85 4 2 73 4 3 85 4 3 99
;

proc glm data=fruit;
  class pesticide variety;
  model yield = pesticide|variety / e solution;
  lsmeans pesticide|variety / stderr;
run; quit;

* Obtendo algumas estimativas de Ott e Longnecker;

proc glm data=fruit;
  class pesticide variety;
  model yield = pesticide|variety / e solution;
  lsmeans pesticide|variety / stderr;
  ESTIMATE 'MEDIA GLOBAL' INTERCEPT 12 PESTICIDE 3 3 3 3 VARIETY 4 4 4
    PESTICIDE*VARIETY 1 1 1 1 1 1 1 1 1 1 1 1 / divisor=12;
  ESTIMATE 'PESTICIDE 1 - PESTICIDE 2' PESTICIDE 3 -3 0 0
        PESTICIDE*VARIETY 1 1 1 -1 -1 -1 0 0 0 0 0 0 / DIVISOR=3;
  CONTRAST 'PESTICIDE 1 - PESTICIDE 2' PESTICIDE 3 -3 0 0
        PESTICIDE*VARIETY 1 1 1 -1 -1 -1 0 0 0 0 0 0;
  * SOLU��ES SUM TO ZERO DE OTT E LONGNECKER;
  ESTIMATE 'MEDIA PESTICIDE 1' INTERCEPT 3 PESTICIDE 3 0 0 0
            VARIETY 1 1 1 PESTICIDE*VARIETY 1 1 1 0 0 0 0 0 0 0 0 0 / DIVISOR=3;
run; quit;