Rolling a Parabola

x0 = -10;
integral[xt_] := (1/2 xt Sqrt[1 + 4 xt^2] + 1/4 ArcSinh[2 xt]);
s[x_] := integral[x] - 0 integral[x0];
transform[t_, p_] :=
  RotationMatrix[-ArcTan[2 t]]. (p - {t, t^2}) + { s[t], 0};
frame[t_, t2_, t3_] := Module[{tt = 2 Tanh[(t + 2)] + 2 Tanh[(t - 2)]},
   (Show[
     Graphics[
      {
       PointSize[Medium],
       Point[transform[tt, {0, 1/4}]],
       {
        Table[
         {
          Opacity[0.5],
          ColorData["RedBlueTones"][Abs[xt]],
          Line[{
            transform[tt, {xt, 100}],
            transform[tt, {xt, Max[3 - 6 t2, xt^2]}]
            }],
          If[3 - 6 t2 < xt^2,
           Line[{
             transform[tt, {xt, xt^2}],

             transform[
               tt, {xt, xt^2}] - (6 t2 - 3 + xt^2) Normalize[
                transform[tt, {xt, xt^2}] - transform[tt, {0, 1/4}]]
             }],
           {}]
          }
         , {xt, -1, 1, 0.05}]
        },
       {Thick, Line[{{-100, 0}, {100, 0}}]}
       }
      , PlotRange -> {{-2, 2}, {0, 3}}, ImagePadding -> 10],
     ParametricPlot[transform[tt, {x, x^2}], {x, -10, 10},
      PlotStyle -> Directive[Thick, Darker@Blue]],
     ParametricPlot[{
       transform[tt, {0, 1/4}]
       (*,{tt,Cosh[4tt]/4}*)
       }, {tt, -4.001, Min[tt, t3]},
      PlotStyle -> Darker@Red]
     ])
   ];
Manipulate[
 frame[t, t2, t3],
 {{t, 0}, -4, 4},
 {{t2, 0}, -2, 0.54444},
 {{t3, 0}, -4, 4}]