window.addEvent 'domready', ->
  $$('[toggle_id]').each(hookupIDToggler)


hookupIDToggler = (element) ->
  respondToClickOrChange element
  initialToggleIfChecked element


respondToClickOrChange = (element) ->
  action = if element.match('input[type=checkbox]') then 'change' else 'click'
  element.addEvent action, (event) ->
    event.stop() if element.match('a')
    toggleIDs(this)


initialToggleIfChecked = (element) ->
  return unless element.match('input[type=checkbox]')
  toggleIDs(element) if element.checked


toggleIDs = (element) ->
  ids = element.get('toggle_id').split(', ')
  ids.each (id) ->
    $(id).toggle()
    rememberState(element, id)

  setFocus(element)
  swapText(element)


rememberState = (element, id) ->
  return unless element.get('remember_state') is 'true'
  Cookie.write("remember_state_#{id}", $(id).isVisible(), { duration: 5000 })


setFocus = (element) ->
  focusID = element.get('focus_id')
  $(focusID).focus() if focusID?


swapText = (element) ->
  swap = element.get('swap_text')
  return unless swap?
  element.set('swap_text', element.get('html')).set('html', swap)