clock_kong final ver999

#include "SevSeg.h"
#include <Wire.h>
#include <TimeLib.h>
#include <DS1307RTC.h>
SevSeg Display;

//Source https://github.com/robsoncouto/arduino-songs/tree/master/happybirthday
#define NOTE_C4  262 //Đặt tần số còi ~> nốt nhạc
#define NOTE_D4  294
#define NOTE_E4  330
#define NOTE_F4  349
#define NOTE_G4  392
#define NOTE_A4  440
#define NOTE_AS4 466
#define NOTE_C5  523
int melody[] = { //Giai điệu bài Happy Birthday
  NOTE_C4,4, NOTE_C4,8,
  NOTE_D4,-4, NOTE_C4,-4, NOTE_F4,-4,
  NOTE_E4,-2, NOTE_C4,4, NOTE_C4,8,
  NOTE_D4,-4, NOTE_C4,-4, NOTE_G4,-4,
  NOTE_F4,-2, NOTE_C4,4, NOTE_C4,8,
  NOTE_C5,-4, NOTE_A4,-4, NOTE_F4,-4,
  NOTE_E4,-4, NOTE_D4,-4, NOTE_AS4,4, NOTE_AS4,8,
  NOTE_A4,-4, NOTE_F4,-4, NOTE_G4,-4,
  NOTE_F4,-2,
};
int buzzer = A1;
int notes = sizeof(melody) / sizeof(melody[0]) / 2;
int wholenote;
int divider = 0, noteDuration = 0;
int baothuc1lanthoi;
//__________________________________________________

const int ledPin =  A0; //Led nhấy nháy và millis()
int ledState = LOW;
unsigned long currentMillis;
unsigned long previousMillis = 0;
const long interval = 500;
unsigned long Millis1;

// Các nút
const int  Mode_btn = 1;
const int  btn2 = A2;
const int  btn3 = A3;
int State_btn1 = 0;
int State_btn2 = 0;
int State_btn3 = 0;
int PushCounter_btn1 = 0;
int lastState_btn1 = 1;
int lastState_btn2 = 1;
int lastState_btn3 = 1;

unsigned int Time;
unsigned int Time_alarm;
unsigned int hrs_alarm = 21; // đặt giá trị giờ báo thức ban đầu
unsigned int min_alarm = 26; // đặt giá trị nút báo thức ban đầu

void setup()
{
  pinMode(ledPin, OUTPUT);
  pinMode(buzzer, OUTPUT);
  pinMode(Mode_btn, INPUT_PULLUP);
  pinMode(btn2, INPUT_PULLUP);
  pinMode(btn3, INPUT_PULLUP);

  //Setup led 7 segments
  byte numDigits = 4;
  byte digitPins[] = {10, 11, 12, 13};
  byte segmentPins[] = {2, 3, 4, 5, 6, 7, 8, 9};
  bool resistorsOnSegments = true;
  bool updateWithDelaysIn = true;
  byte hardwareConfig = COMMON_ANODE;
  Display.begin(hardwareConfig, numDigits, digitPins, segmentPins, resistorsOnSegments);
  Display.setBrightness(100);
}

//Chương trình con chạy còi báo thức__________________________________________________
void sound_alarm(int speed) {
  wholenote = (60000 * 4) / speed;
  for (int thisNote = 0; thisNote < notes * 2; thisNote = thisNote + 2) {
    divider = melody[thisNote + 1];
    if (divider > 0) {
      noteDuration = (wholenote) / divider;
    } else if (divider < 0) {
      noteDuration = (wholenote) / abs(divider);
      noteDuration *= 1.5;
    }
    tone(buzzer, melody[thisNote], noteDuration * 0.9); //Chỉ chạy 90% thời lượng, còn lại 10% để dừng
    delay(noteDuration); // Dừng 1 tí trước khi lặp lần tiếp theo
    noTone(buzzer); // Tắt còi
  }
}

void loop(){
  // Led nhấp nháy theo giây__________________________________________________
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval)
  {
    previousMillis = currentMillis;
    if (ledState == LOW)
    {
      ledState = HIGH;
    }
    else
    {
      ledState = LOW;
    }
    digitalWrite(ledPin, ledState);
  }

 // Đặt giờ__________________________________________________
  tmElements_t tm;
  if (RTC.read(tm))
  {
    Time = tm.Hour * 100 + tm.Minute;
  }

 // Đặt giờ báo thức __________________________________________________
  if (hrs_alarm == 24){
    hrs_alarm = 0;
  }
  if (min_alarm == 60){
    min_alarm = 0;
    hrs_alarm++;
  }
  Time_alarm = hrs_alarm*100+ min_alarm;

 //Nhận giá trị các nút__________________________________________________
  if (millis() - Millis1 >= 500){
	  State_btn1 = digitalRead(Mode_btn);
	  State_btn2 = digitalRead(btn2);
	  State_btn3 = digitalRead(btn3);
	  if (State_btn1 != lastState_btn1) {
		  if (State_btn1 == HIGH) {
			  PushCounter_btn1++;
		  }
	  }
	  lastState_btn1 = State_btn1;
	  Millis1 = millis();
  }

 //Chỉnh nút__________________________________________________
  if (PushCounter_btn1 % 2 == 0) {   // Chia hết cho 2 ~~> hiện giờ
	  Display.setNumber(Time,2);
  }
  else { // Chia 2 dư 1 ~~> chỉnh báo thức
      Display.setNumber(Time_alarm,2);
	  if (State_btn2 != lastState_btn2) {
		  if (State_btn2 == HIGH) {hrs_alarm++;}
		  lastState_btn2 = State_btn2;
	  }
	  if (State_btn3 != lastState_btn3) {
		  if (State_btn3 == HIGH) {min_alarm++;}
		  lastState_btn3 = State_btn3;
      }
  }

 //Báo thức__________________________________________________
  if (Time == Time_alarm) {
	  if (baothuc1lanthoi == 0){
		  sound_alarm(140);
		  sound_alarm(160);
		  sound_alarm(190);
		  sound_alarm(220);
		  baothuc1lanthoi++;
	  }
  }
  Display.refreshDisplay();
}