Breakfast-script

import <clanhop.ash>;
import <DinseyQuests.ash>;
import <manaburn.ash>;
import <pvploot.ash>;
import <Detective Solver.ash>;

void get_gene_tonics() {
    string campground; int no_to_make;
    campground = visit_url("campground.php?action=workshed");
    no_to_make = 3 - to_int(get_property("_dnaPotionsMade"));

    if (campground.contains_text("genelab.gif") && no_to_make > 0 && length(get_property("dnaSyringe")) > 0) {
        while (no_to_make > 0) {
            visit_url("campground.php?action=dnapotion");
            no_to_make = no_to_make - 1;
        }
    }
}

void use_papier_mache() {
    item it;
    it = $item[papier-m&acirc;ch&eacute; glob];

    if (item_amount($item[papier-m&acirc;ch&eacute; glob]) >= 277) {
        create(item_amount($item[papier-m&acirc;ch&eacute; glob]) / 277, $item[papier-m&acirc;ch&eacute; trophy pi&ntilde;ata]);
        use(item_amount($item[papier-m&acirc;ch&eacute; trophy pi&ntilde;ata]), $item[papier-m&acirc;ch&eacute; trophy pi&ntilde;ata]);
    }
}

void checkForGoodies() {
    buffer warroom = visit_url("clan_war.php");
    string pattern = "Bags of Goodies:<\\/td><td align=left><b>(\\d+?)<\\/b><\\/td><\\/tr>";
    matcher goodie_bags = create_matcher(pattern, warroom);

    if (find(goodie_bags)) {
        if (group(goodie_bags, 1) == 0) {
            // Get new goodiebag
            print("No goodie bags left, purchasing goodie bag.", "green");
            visit_url("clan_war.php?action=Yep.&goodies=1&oatmeal=&cinderblocks=&grunts=&flyers=&recliners=&archers=");
        }
    }
}

void check_clan() {
    string current_clan; string vip_lounge;

    // Chips
    if (visit_url("clan_rumpus.php").contains_text("A Snack Machine") && to_int(get_property("_chipBags")) < 3) {
        for i from 1 to 3 - to_int(get_property("_chipBags")) {
            switch (i) {
                case 1:
                    cli_execute("chips ennui");
                    break;
                case 2:
                    cli_execute("chips wintergreen");
                    break;
                case 3:
                    cli_execute("chips radium");
                    break;
                default:
            }
        }
    }

    // VIP Room actions
    if (item_amount($item[Clan VIP Lounge Key]) > 0 && (!to_boolean(get_property("_olympicSwimmingPool")) || !to_boolean(get_property("_lookingGlass")))) {
        vip_lounge = visit_url("clan_viplounge.php?whichfloor=2");
        // No need to clanjump if the items are in the current clan
        current_clan = get_clan_name();
        if (!vip_lounge.contains_text("vippool.gif") || !vip_lounge.contains_text("lookingglass.gif")) {
            clanhop("Bonus Adventures from Hell");
        }
        // Swimming pool
        if (!to_boolean(get_property("_olympicSwimmingPool"))) {
            cli_execute("swim laps");
        }
        // Drink me potion
        if (!to_boolean(get_property("_lookingGlass"))) {
            visit_url("clan_viplounge.php?action=lookingglass&whichfloor=2");
        }
        // Go home
        if (current_clan != get_clan_name()) {
            clanhop(current_clan);
        }
    }
}

void check_chateau() {
    string chateau;
    if (!to_boolean(get_property("_chateauDeskHarvested")) && to_boolean(get_property("chateauAvailable"))) {
        chateau = visit_url("place.php?whichplace=chateau");
        if (chateau.contains_text("chateau_desk1")) {
            visit_url("place.php?whichplace=chateau&action=chateau_desk1");
        }
        else if (chateau.contains_text("chateau_desk2")) {
            visit_url("place.php?whichplace=chateau&action=chateau_desk2");
        }
        else if (chateau.contains_text("chateau_desk3")) {
            visit_url("place.php?whichplace=chateau&action=chateau_desk3");
        }
    }
}

void check_elemental_planes() {
    item[slot] velvet_items;
    velvet_items[$slot[hat]] = $item[smooth velvet hat];
    velvet_items[$slot[shirt]] = $item[smooth velvet shirt];
    velvet_items[$slot[pants]] = $item[smooth velvet pants];
    velvet_items[$slot[acc1]] = $item[smooth velvet hanky];
    velvet_items[$slot[acc2]] = $item[smooth velvet socks];
    velvet_items[$slot[acc3]] = $item[smooth velvet pocket square];

    boolean have_all_velvet; have_all_velvet = true;
    slot slt;

    if (to_boolean((get_property("stenchAirportAlways"))) || to_boolean((get_property("_stenchAirportToday")))) {
        get_garbage();
    }
    if (to_boolean((get_property("hotAirportAlways"))) || to_boolean((get_property("_hotAirportToday")))) {
        if (!to_boolean(get_property("_infernoDiscoVisited"))) {
            foreach slt in velvet_items {
                if (!(can_equip(velvet_items[slt]) && available_amount(velvet_items[slt]) > 0)) {
                    have_all_velvet = false;
                    break;
                }
            }
            if (have_all_velvet) {
                cli_execute("checkpoint");
                foreach slt in velvet_items {
                    if (!have_equipped(velvet_items[slt])) {
                        equip(slt, velvet_items[slt]);
                    }
                }
                visit_url("place.php?whichplace=airport_hot&action=airport4_zone1");
                run_choice(7);
                cli_execute("outfit checkpoint");
            }
        }
    }
}

// mallcuppa by darkcodelagsniper
void harvest_teatree(boolean silent) {
    #int[item] campground = get_campground();
    item [int] cuppas;
    float pricetotal;
    int shaketree;
    item tea;
    string cuppacmd; string cuppaconfirm;

    if (!to_boolean(get_property("_pottedTeaTreeUsed")) && get_campground() contains $item[potted tea tree]) {
        for i from 8601 to 8637 {
            tea = to_item(i);
            cuppas[count (cuppas)] = tea;
            pricetotal += get_price(tea, 0.5);
        }

        sort cuppas by -get_price(value, 0.5);
        shaketree = pricetotal * 3 / 37;

        #if (!silent) {
            print("Avg value from shaking the tree is " + shaketree + " meat","blue");
            print("Best tea is " + cuppas[0] + " at " + historical_price(cuppas[0]) + " meat","blue");
        #}

        if (shaketree > historical_price(cuppas[0])) {
            cuppacmd = "shake";
            cuppaconfirm = "Shake teatree?";
        } else {
            cuppacmd = cuppas[0].to_string().substring(6);
            cuppaconfirm = "Pick " + cuppacmd + " from teatree?";
        }

        if (silent || user_confirm(cuppaconfirm)) {
            cli_execute("teatree " + cuppacmd);
        }
    }
}

void use_fire_starting_kit() {
    // Fire-starting kit
    if (item_amount($item[CSA fire-starting kit]) >= 1 && !to_boolean(get_property("_fireStartingKitUsed"))) {
        if (hippy_stone_broken()) {
            set_property("choiceAdventure595", 1);
        } else {
            set_property("choiceAdventure595", 2);
        }
        use(1, $item[CSA fire-starting kit]);
        set_property("choiceAdventure595", 0);
    }
}

void pull_stuff() {
    int[item] max_to_pull; string current_clan;

    if (my_name() == "ereinion") {
        current_clan = get_clan_name();
        max_to_pull[$item[jekyllin hide belt]] = 3;
        max_to_pull[$item[hypnodisk]] = 1;

        if (current_clan != "Hardcore Oxygenation") {
            clanhop("Hardcore Oxygenation");
        }
        batch_open();
        foreach it in max_to_pull {
            if (stash_amount(it) > 0) {
                take_stash(min(max_to_pull[it], stash_amount(it)), it);
            }
        }
        batch_close();
        // Go home
        if (current_clan != get_clan_name()) {
            clanhop(current_clan);
        }
    }
}

void main() {
    // Stuff we always do
    if (item_amount($item[personal massager]) > 0) {
        print ("Putting " + item_amount($item[personal massager]) + " " + ((item_amount($item[personal massager]) > 1)? to_plural($item[personal massager]) : to_string($item[personal massager])) + ".", "blue");
        put_display(item_amount($item[personal massager]), $item[personal massager]);
    }
    set_property("allowNonMoodBurning", "true");
    if (my_name() == "ereinion" && can_interact()) {
        set_property("allowNonMoodBurning", "false");
    }

    // Stuff to do when out of ronin
    if (can_interact()) {// && !to_boolean(get_property("breakfastCompleted"))) {
        // BittyCar
        if (item_amount($item[BittyCar MeatCar]) >= 1 && get_property("_bittycar") != "meatcar") {
            use(1, $item[BittyCar MeatCar]);
        } else if (item_amount($item[BittyCar SoulCar]) >= 1 && get_property("_bittycar") == "") {
            use(1, $item[BittyCar SoulCar]);
        }

        // Deck of Every Card
        if (item_amount($item[Deck of Every Card]) > 0) {  // && my_name() != "ereinion") {
            switch (to_int(get_property("_deckCardsDrawn"))) {
                // Kan trekke tre kort
                case 0:
                    cli_execute("play 1952 mickey mantle");
                // Kan trekke to
                case 1: case 2: case 3: case 4:  case 5:
                  cli_execute("play ancestral recall");
                // Kan trekke eittcase 6:
                case 7: case 8: case 9: case 10:
                  cli_execute("play island");
                default:
            }
        }

        // Trade yeti skins
        if (is_accessible($coinmaster[The Trapper])  && item_amount($item[yeti fur]) >  0) {
            buy ($coinmaster[The Trapper], item_amount($item[yeti fur]), $item[yak skin]);
        }

        use_fire_starting_kit();
        check_chateau();
        check_clan();

        // Summoning
        if (have_skill($skill[Summon Annoyance])) {
            use_skill(1, $skill[Summon Annoyance]);
        }

        // Rainbow Gravitation & Summon Clip Art
        if (my_name() == "ereinion" || my_name() == "algen" || my_name() == "the conqueror worm") {
            cli_execute("call Profitable summons.ash");
            if (my_name() == "ereinion") {
                cli_execute("call Rainbow Gravitation.ash");
            }
        }

        if (to_boolean(get_property("hasDetectiveSchool"))) {
            solveAllCases(false);
        }
        // Harvest teatree
        harvest_teatree(false);

        // Restock goodie bags
        if (get_clan_name() == "'); drop table clans;--") {
            checkForGoodies();
        }

        // Pull stuff
        pull_stuff();

        check_elemental_planes();
        get_gene_tonics();

        // Demand sandwich
        if (my_path() == "Avatar of Boris") {
            use_skill(3, $skill[Demand Sandwich]);
        }

        // Restock stolen items
        main@pvploot();
    }
}