//===== Hercules Script ======================================
//= Banker Script
//===== By: ==================================================
//= Syrus22 (1.0)
//===== Current Version: =====================================
//= 2.0
//===== Description: =========================================
//= An account wide Banker to store Zeny
//===== Additional Comments: =================================
//= Syrus22 - There's an optional transaction fee at the top of
//= the script. To use it simply change the first set command
//= to set the cost variable to whatever you want the fee to be.
//= Version 2.0: Optimized and brought the script up to standard. [Jguy]
//============================================================

prontera,132,217,5	script	Banqueiro	4_M_MANAGER,{
set @cost,0;
mes "[Banqueiro]";
mes "Bem-vindo ao Primeiro Banco de Prontera. Como posso ajudá-lo hoje?";
next;
switch(select("Gostaria de fazer um depósito.:Gostaria de fazer uma retirada.:Qual é o meu saldo atual?:Cancelar")) {
	case 1:
		mes "[Banqueiro]";
		mes "Muito bem ... Quanto você gostaria de depositar? O máximo que você pode depositar imediatamente é 2.000,000 Zeny.";
		next;
		if (@cost > 0) {
			mes "[Banqueiro]";
			mes "Ah, lembrando que há uma taxa de: " +@cost + " Zeny, para cada transações!";
			next;
		}
		input @deposit;
		if (@deposit < 1) {
			mes "Certifique-se de me pedir para depositar uma quantia real.";
			close;
		}
		else if (@deposit > Zeny) {
			mes "Não parece que você tem a quantidade de zeny que você está tentando depositar!";
			close;
		}
		else if (@deposit > (Zeny - @cost)) {
			mes "Você precisa de " + @cost + " Zeny para cobrir a taxa de transação!";
			close;
		}
		else {
		Zeny -= @deposit;
		Zeny -= @cost;
		set #bankstorage,#bankstorage + @deposit;
		mes "[Banqueiro]";
		mes "Muito obrigado ... Seu zeny está em boas mãos.";
		close;
		}

	case 2:
		mes "[Banqueiro]";
		mes "Muito bem ... Quanto você gostaria de retirar? O máximo que você pode retirar de uma só vez é 2.000,000 Zeny";
		next;
		if (@cost > 0) {
			mes "[Banqueiro]";
			mes "Ah, lembrando que há uma taxa de: " +@cost + " Zeny, para cada transações!";
			next;
		}
		input @withdrawl;
		if (@withdrawl < 1) {
			mes "Por favor, não jogue. Preciso de uma quantia real para retirar.";
			close;
		}
		else if (@withdrawl > #bankstorage) {
			mes "Eu vejo que você só tem ^00FF00" + #bankstorage +"^000000 zeny em sua conta!";
			close;
		}
		else if ((@cost > Zeny) && ((Zeny + @withdrawl) > @cost)) {
			mes "[Banqueiro]";
			mes "Você não tem o Zeny para a taxa de transação agora. Gostaria que eu tomasse a taxa diretamente de sua retirada?";
			next;
			switch(select("Sim, obrigado.:Não, obrigado")){
			case 1:
				mes "[Banqueiro]";
				mes "Tirando " + @cost + " de sua retirada para cobrir a taxa de depósito...";
				set @withdrawl,@withdrawl - @cost;
				set #bankstorage,#bankstorage - @cost;
				set @cost,0;
				next;
				Zeny -= @cost;
				Zeny += @withdrawl;
				set #bankstorage,#bankstorage - @withdrawl;
				mes "[Banqueiro]";
				mes "Aí está seu Zeny. Tenha um bom dia.";
				close;
			case 2:
				mes "[Banqueiro]";
				mes "Muito bem ... Volte em breve.";
				close;
			}
		}
		else {
			Zeny -= @cost;
			Zeny += @withdrawl;
			set #bankstorage,#bankstorage - @withdrawl;
			mes "[Banqueiro]";
			mes "Aí está seu Zeny. Tenha um bom dia.";
			close;
		}
	case 3:
		mes "[Banqueiro]";
		mes "Hmmmm deixe-me checar a papelada.";
		next;
		mes "[Banqueiro]";
		mes "Você tem atualmente " + #bankstorage + " Zeny em sua conta.";
		close;
	case 4:
		mes "[Banqueiro]";
		mes "Muito bem ... Volte em breve.";
		close;
	}
}