Status_Bar

	LDA $1BE3						;\ Load layer 3 tilemap value
	BNE Boss_Battle_05				;/ If not equal, status bar is on top
	LDA $0D9B						;\ Load fight mode value
	BNE Boss_Battle_05				;/ If not equal, status bar on top
	LDA #$09						;\ Layer 3 has
	STA $3E							;/ priority
	STZ $22							;\
	STZ $23							;| Fixed layer 3
	STZ $24							;| position
	STZ $25							;/
	STZ $2115						;\ Set VRAM Address Increment Value to x00
	LDA #$22						;|
	STA $2116						;| Set Address for VRAM Read/Write to x5322
	LDA #$53						;| Address for VRAM Read/Write (Low Byte)
	STA $2117						;|
	BRA Before_SB_Loop_01			;/ Continue code
Boss_Battle_05:
	STZ $2115						;\ Set VRAM Address Increment Value to x00
	LDA #$42						;|
	STA $2116						;| Set Address for VRAM Read/Write to x5042
	LDA #$50						;| Address for VRAM Read/Write (Low Byte)
	STA $2117						;/
Before_SB_Loop_01:
	LDX #$06						;\ $06 bytes
SB_Loop_01:
	LDA SB_DMA_Table_01,X			;| Get data from table
	STA $4310,X						;| Store to DMA registers
	DEX								;| Decrease X
	BPL SB_Loop_01					;/ Loop code
	LDA #$02						;\ Activate DMA channel 1
	STA $420B						;/ Regular DMA Channel Enable
	LDA $1BE3						;\ Load layer 3 tilemap value
	BNE Boss_Battle_06				;/ If not equal, status bar is on top
	LDA $0D9B						;\ Load fight mode value
	BNE Boss_Battle_06				;/ If not equal, status bar on top
	STZ $2115						;\ Set VRAM Address Increment Value to x00
	LDA #$43						;|
	STA $2116						;| Set Address for VRAM Read/Write to x5343
	LDA #$53						;| Address for VRAM Read/Write (Low Byte)
	STA $2117						;|
	BRA Before_SB_Loop_02			;/ Continue code
Boss_Battle_06:
	STZ $2115						;\ Set VRAM Address Increment Value to x00
	LDA #$63						;|
	STA $2116						;| Set Address for VRAM Read/Write to x5063
	LDA #$50						;| Address for VRAM Read/Write (Low Byte)
	STA $2117						;/
Before_SB_Loop_02:
	LDX #$06						;\ $06 bytes
SB_Loop_02:
	LDA SB_DMA_Table_02,X			;| Get data from table
	STA $4310,X						;| Store to DMA registers
	DEX								;| Decrease X
	BPL SB_Loop_02					;/ Loop code
	LDA #$02						;\ Activate DMA channel 1
	STA $420B						;| Regular DMA Channel Enable
	RTL								;/ Return
SB_DMA_Table_01:
	db $00,$18,$F9,$0E,$00,$1C,$00	;| DMA settings 2nd row (timers,etc)
SB_DMA_Table_02:
	db $00,$18,$15,$0F,$00,$1B,$00	;| DMA settings 3rd row (timers,etc)