LED Puzzle Code

/* Duncan Flint 1/19/2016
 *
Spring 2015 Final Light Puzzle

This is a complete rewrite of my previous light puzzle code. This rewrite is significantly shorter because it utilizes arrays and global variables to eliminate redundant code

Complete Project Writeup Availible at: https://integrateddiscoveries.wordpress.com/


*/

  // GENERAL NOTE:
  // When looking at the six LED/six button configuration, the leftmost LED is designated as LED 0! The rightmost is LED 5!

  int ledPins[] = {8,9,10,11,12,13}; // The numbers in this array correspond to the pins of the 6 LEDS, when looking from left to right
  int buttonPins[] = {2,3,4,5,6,7}; // The numbers in this array correspond to the pins of the 6 buttons, when looking from left to right

  int ledStatus[] = {0,0,0,0,0,0}; // This array signifies whether or not each LED is on (= 1) or off (= 0). It is (and must be!) updated every time any of the LEDS change state.


void setup()
{
  for (int i = 0; i < 6; i = i + 1)
  {
    pinMode(buttonPins[i], INPUT);  // All our button pins are inputs (We'll read values FROM them)
    pinMode(ledPins[i], OUTPUT);  // All are light pins are outputs (We'll write values TO them)
  }

  //Serial.begin(9600);
  randomSeed(analogRead(0));  // Seed the random number generation with a random value. This random value is obtained from reading an unconnected analog pin
  randomizeGameBoard();       // Randomize the game board
}

void loop()
{
  invertLeds(readButtons()); // This is a little weird without reading the functions first. Basically invertleds takes one parameter, an integer corresponding to the index of the led that must be flipped. We get that from the function readbuttons, which returns whichever button is currently being pressed (or -1 if none are)
  checkWinLoss();            // See if the user has won or lost (all lit up, or all deluminated)

  // Generation Test Code Below. Should be commented out in final build
  //randomizeGameBoard();
  //delay(1000);
}

void randomizeGameBoard() // Randomly generate the values of all leds
{
  int randNum;
  for (int i = 0; i < 6; i++) // Do the following 5 times
  {
    randNum = random(2); // Pick a random number from 0 to 1
    ledStatus[i] = randNum; // Set the LED to be that number
  }
  verifyLEDS(); // This function checks if the leds are set up in a challenging way (so you cant just solve the puzzle in one move)
  updateLEDS(); // This function turns on whatever leds the ledstatus array tells it to
}



int readButtons() // NOTE: This function will return the FIRST button that is being pressed (from left to right). If you press two buttons at the same time, it will only invert the LEDS corresponding to the one closest to the left.
{
  for (int i = 0; i < 6; i++)
  {
    if (digitalRead(buttonPins[i]) == 1)
    {
      return i;
    }
  }
  return -1;
}

void updateLEDS()
{
  for (int i = 0; i < 6; i++)
  {
    digitalWrite(i + 8, ledStatus[i]);
  }
}

int sumLEDS() // This function determines how many LEDS are on, by just adding up all the numbers in the LED array (since 1 is on, 0 is off)
{
  int ledSums = 0;
  for (int i = 0; i < 6; i++)
  {
    if (ledStatus[i] == 1)
    {
    ledSums += 1;
    }
  }
  return ledSums;
}

void verifyLEDS()
{
  bool allOn = false;
  bool allOff = false;
  int ledSums = 0;

  ledSums = sumLEDS();

  //The statements below determine what light configurations are unacceptable and must be reset. The comments indicate these configurations "look like". X's are on, O's are off
  //Unacceptable configurations include all on/all off (since it means the user doesn't get to do anything), or configurations where only one button needs to be pressed to win (Have all leds lit)
  if ((ledSums == 0) || (ledSums == 6))                                                                   // OOOOOO, XXXXXX
  {
    randomizeGameBoard();
  }

  else if ((ledSums == 2) &&  (ledStatus[2] == 1) && (ledStatus[3] == 1))                             // OOXXOO
  {
    randomizeGameBoard();
  }

  else if (ledSums == 1)                                                                              // XOOOOO, OXOOOO, OOXOOO, OOOXOO, OOOOXO, OOOOOX
  {
    randomizeGameBoard();
  }
  else if ((ledSums == 3) && (ledStatus[0] == 1) && (ledStatus[1] == 1) && (ledStatus[2] == 1))       // XXXOOO
  {
    randomizeGameBoard();
  }
  else if ((ledSums == 3) && (ledStatus[3] == 1) && (ledStatus[4] == 1) && (ledStatus[5] == 1))       // OOOXXX
  {
    randomizeGameBoard();
  }
  else if ((ledSums == 4) && (ledStatus[4] == 0) && (ledStatus[5] == 0))                              // XXXXOO
  {
    randomizeGameBoard();
  }
  else if ((ledSums == 4) && (ledStatus[0] == 0) && (ledStatus[1] == 0))                              // OOXXXX
  {
    randomizeGameBoard();
  }

  else if ((ledSums == 3) && (ledStatus[1] == 0) && (ledStatus[2] == 0) && (ledStatus[3] == 0))       // XOOOXX
  {
    randomizeGameBoard();
  }

  else if ((ledSums == 3) && (ledStatus[2] == 0) && (ledStatus[3] == 0) && (ledStatus[4] == 0))       // XXOOOX
  {
    randomizeGameBoard();
  }



}

void invertLeds(int ledToInvt)
{
  if (ledToInvt == -1)
  {
  return;
  }
  int ledToInvtPin = ledToInvt + 8; // Because our first light would correspond to i = 0, but the pin our first light is controlled by is at 2. Same for (1,3), (2,4), etc..
  switch (ledToInvtPin)
  {
    case 8:
    digitalWrite(ledToInvtPin, !ledStatus[ledToInvt]);
    digitalWrite(ledToInvtPin + 1, !ledStatus[ledToInvt + 1]);
    ledStatus[ledToInvt] = !ledStatus[ledToInvt];
    ledStatus[ledToInvt + 1] = !ledStatus[ledToInvt + 1];
    delay(200);
    break;

    case 9:                                                         // Exact same behavior for cases 9-12 (LEDS 1-4), so case statements without breaks used to cause identical behavior
    case 10:
    case 11:
    case 12:
    digitalWrite(ledToInvtPin - 1, !ledStatus[ledToInvt - 1]);
    digitalWrite(ledToInvtPin, !ledStatus[ledToInvt]);
    digitalWrite(ledToInvtPin + 1, !ledStatus[ledToInvt + 1]);
    ledStatus[ledToInvt - 1] = !ledStatus[ledToInvt - 1];
    ledStatus[ledToInvt] = !ledStatus[ledToInvt];
    ledStatus[ledToInvt + 1] = !ledStatus[ledToInvt + 1];
    delay(200);
    break;

    case 13:
    digitalWrite(ledToInvtPin - 1, !ledStatus[ledToInvt - 1]);
    digitalWrite(ledToInvtPin, !ledStatus[ledToInvt]);
    ledStatus[ledToInvt - 1] = !ledStatus[ledToInvt - 1];
    ledStatus[ledToInvt] = !ledStatus[ledToInvt];
    delay(200);
    break;

  }
}

void checkWinLoss()           // Determines if all leds are on (win) or off (lose) by summing LED status array
{
  int ledSums= sumLEDS();
  if (ledSums == 0)
  {
    youLose();
  }
  else if (ledSums == 6)
  {
    youWin();
  }
}

void youWin()                 // Flashes lights on/off to indicate victory, and resets board
{
  for (int j = 0; j < 8; j++)
{
  for (int i = 0; i < 6; i++)
  {
    digitalWrite(i+8, HIGH);
  }
  delay(200);
  for (int i = 0; i < 6; i++)
  {
    digitalWrite(i+8, LOW);
  }
  delay(200);
}

randomizeGameBoard();
}

void youLose()
{
  randomizeGameBoard();
}