Guest User

Untitled

a guest
Nov 10th, 2014
6
0
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1.     ;; kernelGate handler
  2. kernelGateEntryMarker:
  3.     .db 0
  4. kernelGateOldSP:
  5.     .ds 2
  6. kernelGateAsm:
  7.     ;; Parameter passing
  8.     ;; L: Module ID
  9.     ;; H: Function ID
  10.     ;; BC: par1 (user integer)
  11.     ;; DE: ptr1 (user pointer)
  12.    
  13.     DI
  14.     ;; Do not push HL since it's the return value.
  15.     ;; Everything else is pushed.
  16.     PUSH    AF
  17.     PUSH    BC
  18.     PUSH    DE
  19.     PUSH    IX
  20.     PUSH    IY
  21.    
  22.     ;; Check whether we already entered the kernel.
  23.     ;; If we didn't, save the old SP and set SP to the kernel stack.
  24.     LD  A,(#kernelGateEntryMarker)
  25.     CP  A,#0
  26.     JP  NZ,kernelGateAlreadyEntered
  27.     PUSH    HL
  28.     LD  HL,#0
  29.     ADD HL,SP
  30.     LD  (#kernelGateOldSP),HL
  31.     POP HL
  32.     LD  SP,#stackSpaceEnd-1
  33. kernelGateAlreadyEntered:
  34.    
  35.     ;; Store the old value of kernelGateEntryMarker on the stack
  36.     ;; and set kernelGateEntryMarker to 1, so that calls to
  37.     ;; kernelGate from within kernelmode do not switch stack again.
  38.     PUSH    AF
  39.     LD  A,#1
  40.     LD  (#kernelGateEntryMarker),A
  41.    
  42.    
  43.     ;; Push the parameters onto the stack and call the dispatcher.
  44.     ;; Rightmost parameter: User pointer
  45.     PUSH    DE
  46.     ;; Next parameter: User int
  47.     PUSH    BC
  48.     ;; First parameters: Module ID (L) & function ID (H)
  49.     PUSH    HL
  50.     CALL    _kernelGateDispatcher
  51.     POP DE
  52.     POP DE
  53.     POP DE
  54.    
  55.    
  56.     ;; Restore the old value of kernelGateEntryMarker
  57.     POP AF
  58.     LD  (#kernelGateEntryMarker),A
  59.    
  60.     ;; If we were outside of kernelmode before we entered this instance
  61.     ;; of kernelGate, restore SP and re-activate interrupts.
  62.     CP  A,#0
  63.     JP  NZ,kernelGateStillActive
  64.     EX  DE,HL
  65.     LD  HL,(#kernelGateOldSP)
  66.     LD  SP,HL
  67.     EX  DE,HL
  68.     EI
  69. kernelGateStillActive:
  70.    
  71.     POP IY
  72.     POP IX
  73.     POP DE
  74.     POP BC
  75.     POP AF
  76.     RET
Advertisement
Add Comment
Please, Sign In to add comment