GROSSE BITE

; ###### Dialog ######

dialog smemory {
  title "Celui qui rêve éternellement ne peut mourir..."
  size 100 100 250 280
  option dbu
  button "Quitter" , 1 , 5 265 240 10 , ok
  icon 2 , 45 0 250 100
  list 3 , 5 205 240 60 , multi , vsbar , read
  tab "Options I" , 4 , 5 5 240 195
  tab "Options II" , 5
  tab "Gestionnaire" , 6
  tab "Rechercher un nick" , 7
  tab "Recherches diverses" , 8

  box "Activation de Seen Memory..." , 45 , 10 80 230 25 , tab 4
  button "?" , 46 , 15 89 7 10 , tab 4
  radio "Oui" , 47 , 25 90 30 10 , group , tab 4
  radio "Non" , 48, 215 90 20 10 , tab 4
  text "<----------------------------------------------- Ou ------------------------------------------------------>" , 49 , 45 91 170 10 , tab 4
  box "Status de la base de donnée..." , 50 , 10 110 230 45 , tab 4
  button "?" , 51 , 15 119 7 10 , tab 4
  text "0% " , 52 , 25 121 20 10 , tab 4
  text "" , 53 , 36 121 182 10 , tab 4
  text "100% " , 54 , 218 121 20 10 , tab 4
  button "?" , 55 , 15 135 7 10 , tab 4
  text "Maximum de personnes dans la database ==>  Min ( 100 ) " , 56 , 25 137 150 10 , tab 4
  edit "" , 57 , 165 135 17 10 , tab 4
  text "Max ( 4000 )" , 58 , 185 137 30 10 , tab 4
  button "OK" , 59 , 220 135 15 10 , tab 4
  box "Options de fonctionnement de Seen Memory..." , 60 , 10 160 230 35 , tab 4
  button "?" , 61 , 15 169 7 10 , tab 4
  text "Commande d'activation => " , 62 , 25 170 70 10 , tab 4
  edit "" , 63 , 90 169 30 10 , autohs , tab 4
  check "Indiquer le temps de recherche" , 64 , 150 169 90 10 , tab 4
  button "?" , 65 , 15 182 7 10 , tab 4
  text "Réponse channel par => " , 66 , 25 183 70 10 , tab 4
  radio "Message sur channel" , 67 , 90 182 60 10 , group , tab 4
  radio "Privé" , 68, 167 182 30 10 , tab 4
  radio "Notice" , 69 , 207 182 30 10 , group , tab 4

  box "Options de fonctionnement de Seen Memory...( suite )" , 100 , 10 25 230 170 , tab 5
  button "?" , 101 , 15 34 7 10 , tab 5
  check "Répondre aux demandes par message privé ?" , 102 , 30 34 120 10 , tab 5
  button "?" , 103 , 15 49 7 10 , tab 5
  check "Répondre aux demandes par Dcc Chat ?" , 104 , 30 49 120 10 , tab 5
  button "?" , 105 , 15 79 7 10 , tab 5
  check "Seen Flood protection ?" , 106 , 30 79 120 10 , tab 5
  text "Maximum de " , 107 , 15 94 40 10 , tab 5
  edit "" , 108 , 50 93 20 10 , tab 5
  text "requêtes par adresse en " , 109 , 75 94 60 10 , tab 5
  edit "" , 110 , 140 93 20 10 , tab 5
  text "secondes." , 111 , 170 94 40 10 , tab 5
  button "?" , 112 , 15 64 7 10 , tab 5
  check "Afficher dans la fenêtre status les demandes seen ?" , 113 , 30 64 150 10 , tab 5
  button "?" , 114 , 15 109 7 10 , tab 5
  text "Channels à ne pas logger..." , 115 , 30 110 110 10 , tab 5
  edit "" , 116, 15 122 90 10 , tab 5
  button "Ajouter" , 117 , 15 137 40 10 , tab 5
  button "Effacer" , 118 , 65 137 40 10 , tab 5
  list 119 , 120 113 115 42 , multi , vsbar , hsbar, read , sort , tab 5
  button "?" , 120 , 15 152 7 10 , tab 5
  text "Channels sur lesquels aucune demande seen ne sera traitée..." , 121 , 30 151 80 12 , tab 5
  edit "" , 122, 15 167 90 10 , tab 5
  button "Ajouter" , 123 , 15 182 40 10 , tab 5
  button "Effacer" , 124 , 65 182 40 10 , tab 5
  list 125 , 120 156 115 42 , multi , vsbar , hsbar, read , sort , tab 5

  box "Sauvegarder la base de donnée sur le HD..." , 200 , 10 25 230 40 , tab 6
  button "?" , 201 , 15 34 7 10 , tab 6
  radio "A chaque déconnection ( Recommandé )" , 202 , 30 34 120 10 , group , tab 6
  button "?" , 203 , 15 49 7 10 , tab 6
  radio "Toutes les heures et à la déconnection ( Non recommandé )" , 204 , 30 49 180 10 , tab 6
  box "Epuration de la base de donnée..." , 205 , 10 70 230 70 , tab 6
  button "?" , 206 , 15 79 7 10 , tab 6
  text "Epurer les éléments datant de plus de:" , 207 , 30 80 100 10 , tab 6
  edit "" , 208 , 130 79 20 10 , tab 6
  text "jours..." , 209 , 160 80 20 10 , tab 6
  check "A chaque démarrage de mIRC..." , 210 , 15 95 120 10 , tab 6
  button "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!        Maintenant        !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!" , 211 , 15 110 220 10 , tab 6
  button "/_!_\   EFFACER TOUTE LA LISTE   /_!_\" , 212 , 15 125 220 10 , tab 6

  box "Rechercher un nick dans la base de donnée..." , 300 , 10 25 230 170 , tab 7
  button "?" , 301 , 15 34 7 10 , tab 7
  text "Recherche de: " , 302 , 30 35 40 10 , tab 7
  edit "" , 303 , 70 34 80 10 , tab 7
  button "Lancer la recherche" , 304 , 155 34 80 10 , tab 7
  box "Résultats de la recherche..." , 305 , 20 55 210 130 , tab 7
  text "Nick:" , 306 , 30 65 180 15 , tab 7
  text "Adresse:" , 307 , 30 80 180 15 , tab 7
  text "Action:" , 308 , 30 95 180 15 , tab 7
  text "Message:" , 309 , 30 125 180 15 , tab 7
  text "Date:" , 310 , 30 140 180 15 , tab 7
  text "Status actuel:" , 311 , 30 155 180 15 , tab 7
  text "Temps de recherche:" , 312 , 30 170 180 15 , tab 7
  text "Channel:" , 313 , 30 110 180 15 , tab 7

  box "Recherches diverses..." , 400 , 10 25 230 170 , tab 8
  button "?" , 401 , 15 34 7 10 , tab 8
  text "Rechercher les éléments de la base de donnée de moins de" , 402 , 30 35 150 10 , tab 8
  edit "" , 403 , 175 34 13 10 , tab 8
  text "jour(s)." , 404 , 195 35 20 10 , tab 8
  button "Lancer la recherche" , 405 , 15 50 220 10 , tab 8
  button "?" , 406 , 15 64 7 10 , tab 8
  text "Rechercher les éléments de la base de donnée de plus de" , 407 , 30 65 150 10 , tab 8
  edit "" , 408 , 175 64 13 10 , tab 8
  text "jour(s)." , 409 , 195 65 20 10 , tab 8
  button "Lancer la recherche" , 410 , 15 80 220 10 , tab 8
  button "?" , 411 , 15 94 7 10 , tab 8
  text "Rechercher l'adresse:" , 412 , 30 95 60 10 , tab 8
  edit "" , 413 , 90 94 145 10 , tab 8
  button "Lancer la recherche" , 414 , 15 110 220 10 , tab 8
  text "Résultats de la recherche..." , 415 , 15 125 220 10 , center , tab 8
  list 416 , 15 135 220 60 , multi , vsbar , hsbar, read , tab 8
}

dialog smemory-chargement {
  title ""
  size -1 -1 500 100
  button "Ok :) " , 1 , 50 70 400 20 , ok
  text "" , 2 , 10 5 480 20 , center
  text "" , 3 , 10 45 480 20 , center
  text "" , 4 , 10 25 480 20 , center
}

dialog mess-smemory {
  title "Celui qui rêve éternellement ne peut mourir..."
  size -1 -1 400 60
  button "J'ai bien tout compris :+p" , 1 , 100 30 200 20 , ok
  text "" , 2 , 5 10 390 15 , center
}

; ###### Evenements Dialog ######

on *:dialog:smemory:sclick:4:{ set %smemory.check 1 | did -v smemory 2 | smaide 7 | verif-smemory }
on *:dialog:smemory:sclick:5:{ set %smemory.check 0 | did -h smemory 2 | smaide 66 }
on *:dialog:smemory:sclick:6:{ set %smemory.check 0 | did -h smemory 2 | smaide 113 }
on *:dialog:smemory:sclick:7:{ set %smemory.check 0 | did -h smemory 2 | smaide 150 }
on *:dialog:smemory:sclick:8:{ set %smemory.check 0 | did -h smemory 2 | smaide 161 }
on *:dialog:smemory:sclick:46:{ smaide 26 }
on *:dialog:smemory:sclick:47:{ set %smemory-seen oui | if ( $window(@seen) == $null ) { sm-aff-seen } | sm-status-seen }
on *:dialog:smemory:sclick:48:{ set %smemory-seen non }
on *:dialog:smemory:sclick:51:{ smaide 33 }
on *:dialog:smemory:sclick:55:{ smaide 38 }
on *:dialog:smemory:sclick:59:{ if ( $did(smemory,57) == $null ) { set %smemory-max-seen 4000 | verif-smemory | halt }
  if ( $did(smemory,57) > 4000 ) { set %smemory-max-seen 4000 | verif-smemory | halt }
  if ( $did(smemory,57) < 100 ) { set %smemory-max-seen 100 | verif-smemory | halt }
set %smemory-max-seen $did(smemory,57) | verif-smemory }
on *:dialog:smemory:sclick:61:{ smaide 49 }
on *:dialog:smemory:edit:63:{ if ( $did(smemory,63) == $null ) { set %smemory-commande seen | verif-smemory | halt }
set %smemory-commande $did(smemory,63) }
on *:dialog:smemory:sclick:64:{ if ( %smemory-temps == oui ) { set %smemory-temps non | halt } | if ( %smemory-temps == non ) { set %smemory-temps oui } }
on *:dialog:smemory:sclick:65:{ smaide 60 }
on *:dialog:smemory:sclick:67:{ set %smemory-type-reponse channel }
on *:dialog:smemory:sclick:68:{ set %smemory-type-reponse message }
on *:dialog:smemory:sclick:69:{ set %smemory-type-reponse notice }

on *:dialog:smemory:sclick:101:{ smaide 76 }
on *:dialog:smemory:sclick:102:{ if ( %smemory-prive == oui ) { set %smemory-prive non | halt } | if ( %smemory-prive == non ) { set %smemory-prive oui } }
on *:dialog:smemory:sclick:103:{ smaide 81 }
on *:dialog:smemory:sclick:104:{ if ( %smemory-dcc == oui ) { set %smemory-dcc non | halt } | if ( %smemory-dcc == non ) { set %smemory-dcc oui } }
on *:dialog:smemory:sclick:105:{ smaide 92 }
on *:dialog:smemory:sclick:106:{ if ( %smemory-protection == oui ) { set %smemory-protection non | verif-smemory | halt } | if ( %smemory-protection == non ) { set %smemory-protection oui | verif-smemory } }
on *:dialog:smemory:edit:108:{ if ( $did(smemory,108) == $null ) { set %smemory-max 5 | verif-smemory | halt } | if ( $did(smemory,108) < 1 ) { set %smemory-max 5 | verif-smemory | halt }
set %smemory-max $did(smemory,108) }
on *:dialog:smemory:edit:110:{ if ( $did(smemory,110) == $null ) { set %smemory-protection-temps 10 | verif-smemory | halt } | if ( $did(smemory,110) < 11 ) { set %smemory-protection-temps 10 | verif-smemory | halt }
set %smemory-protection-temps $did(smemory,110) }
on *:dialog:smemory:sclick:112:{ smaide 86 }
on *:dialog:smemory:sclick:113:{ if ( %smemory-log == oui ) { set %smemory-log non | halt } | if ( %smemory-log == non ) { set %smemory-log oui } }
on *:dialog:smemory:sclick:114:{ smaide 98 }
on *:dialog:smemory:sclick:117:{ if ( $did(smemory,116) == $null ) { halt } | if ( $chr(35) !isin $did(smemory,116) ) { mess_sm Entrée invalide... | halt }
  if ( $istok(%smemory-channel-non-log,$did(smemory,116),32)  == $true ) { mess_sm Ce channel est déjà dans ma base de donnée :p | halt }
set %smemory-channel-non-log %smemory-channel-non-log $did(smemory,116) | verif-smemory }
on *:dialog:smemory:sclick:118:{ if ( $did(smemory,119).sel == $null ) { mess_sm Aucun channel sélectionné :) | halt }
set %smemory-channel-non-log $remtok(%smemory-channel-non-log,$did(smemory,119,$did(smemory,119).sel).text,32) | verif-smemory }
on *:dialog:smemory:sclick:120:{ smaide 106 }
on *:dialog:smemory:sclick:123:{ if ( $did(smemory,122) == $null ) { halt } | if ( $chr(35) !isin $did(smemory,122) ) { mess_sm Entrée invalide... | halt }
  if ( $istok(%smemory-channel-non-rep,$did(smemory,122),32)  == $true ) { mess_sm Ce channel est déjà dans ma base de donnée :p | halt }
set %smemory-channel-non-rep %smemory-channel-non-rep $did(smemory,122) | verif-smemory }
on *:dialog:smemory:sclick:124:{ if ( $did(smemory,125).sel == $null ) { mess_sm Aucun channel sélectionné :) | halt }
set %smemory-channel-non-rep $remtok(%smemory-channel-non-rep,$did(smemory,125,$did(smemory,125).sel).text,32) | verif-smemory }

on *:dialog:smemory:sclick:201:{ smaide 119 }
on *:dialog:smemory:sclick:202:{ set %smemory-sauvegarde deconnection | .timersmsauvegarde off }
on *:dialog:smemory:sclick:203:{ smaide 129 }
on *:dialog:smemory:sclick:204:{ set %smemory-sauvegarde horaire | if ( $server != $null ) { .timersmsauvegarde 0 3600 /sm-sauvegarde-donnée } }
on *:dialog:smemory:sclick:206:{ smaide 138 }
on *:dialog:smemory:edit:208:{ if ( $did(smemory,208) == $null ) { set %smemory-epuration-temps 60 | verif-smemory | halt } | if ( $did(smemory,208) < 1 ) { set %smemory-epuration-temps 15 | verif-smemory | halt }
set %smemory-epuration-temps $did(smemory,208) }
on *:dialog:smemory:sclick:210:{ if ( %smemory-epuration == oui ) { set %smemory-epuration non | halt } | if ( %smemory-epuration == non ) { set %smemory-epuration oui } }
on *:dialog:smemory:sclick:211:{ if ( $window(@seen) == $null ) { mess_sm Le serveur seen n'est pas activée. Veuillez l'activer d'abord :) | halt }
  verif_dialog smemory-chargement | dialog -m smemory-chargement smemory-chargement | dialog -t smemory-chargement Seen Memory v1.0 => Epuration des données... Veuillez patientez...
  var %filtre = 0 | var %seen = $line(@seen,0) | if ( %seen == 0 ) { goto fin }
  var %temps = $ticks |  var %i = 1 | var %lig = $line(@seen,%i) | var %i = 0
  while ( %lig != $null ) {
    did -ra smemory-chargement 3 Temps d'épuration: $calc( ( $ticks - %temps ) / 1024 ) seconde(s) )
    if ( %i < 0 ) { /break } | inc %i | var %lig = $line(@seen,%i) | if ( %lig == $null ) { /break }
  var %filtrage = $calc( $ctime - $gettok(%lig,5,32) ) | var %temps2 = $calc( 86400 * %smemory-epuration-temps ) | if ( %filtrage > %temps2 ) { dline @seen %i | inc %filtre | did -ra smemory-chargement 4 Elément(s) filtré(s): %filtre sur %seen élément(s). | dec %i | /continue } }
  var %fin = $ticks | :fin
  if ( %filtre != 0 ) { did -ra smemory-chargement 4 Au total: %filtre élément(s) épuré(s)... | did -ra smemory-chargement 3 Temps d'épuration: $calc( ( %fin - %temps ) / 1024 ) seconde(s) ) | sm-sauvegarde-seen 1 }
if ( %filtre == 0 ) { did -ra smemory-chargement 4 Au total: aucun élément épuré... } }
on *:dialog:smemory:sclick:212:{ window -c @seen | window -hl @seen 50 50 200 200 | sm-sauvegarde-seen | mess_sm La base de donnée a été totalement effacée :) }

on *:dialog:smemory:sclick:301:{ smaide 155 }
on *:dialog:smemory:sclick:304:{ if ( $window(@seen) == $null ) { mess_sm Le serveur seen n'est pas activée. Veuillez l'activer d'abord :) | halt }
  var %nick = $did(smemory,303) | if ( %nick == $null ) { mess_sm Pas de nick à rechercher :p | halt }
  did -ra smemory 307 Adresse: | did -ra smemory 308 Action: | did -ra smemory 309 Message:
  did -ra smemory 310 Date: | did -ra smemory 313 Channel:
  did -ra smemory 305 Résultats de la recherche... recherche en cours veuillez patienter ...
  var %temp = $ticks | var %i = 1 | var %lig = $line(@seen,%i)
  while ( %lig != $null ) {
    if ( %nick == $gettok(%lig,1,32) ) { var %recherche = %lig | /break }
  inc %i | var %lig = $line(@seen,%i) }
  var %temps-recherche = $calc( ( $ticks - %temp ) / 1024 ) seconde(s)
  if ( %recherche == $null ) { did -ra smemory 306 Nick: aucun nick de ma base de donnée ne correspond :p | goto fin }
  did -ra smemory 306 Nick: %nick
  did -ra smemory 307 Adresse: $replace($gettok(%recherche,4,32),inconnu,inconnue)
  if ( $gettok(%recherche,2,32) == Nick ) { did -ra smemory 308 Action: changement de nick pour $gettok(%recherche,6,32) }
  if ( $gettok(%recherche,2,32) != Nick ) { did -ra smemory 308 Action: $replace( $gettok(%recherche,2,32),join,entrée sur un channel,kick,kické(e) d'un channel,part,départ d'un channel,quit,départ de l'Irc) }
  did -ra smemory 313 Channel: $replace($gettok(%recherche,3,32),@,N/A)
  did -ra smemory 310 Date: il y a $replace($duration($calc( $ctime - $gettok(%recherche,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde)))
  if ( $gettok(%recherche,2,32) == Nick ) { did -ra smemory 309 Message: N/A | goto fin }
  if ( $gettok(%recherche,6,32) == $null ) { did -ra smemory 309 Message: N/A | goto fin }
  did -ra smemory 309 Message: " $strip($gettok(%recherche,6-,32)) "
  :fin
  if ( $server == $null ) { did -ra smemory 311 Status actuel: vous n'êtes pas connecté... | goto fini }
  if ( $comchan($did(smemory,303),1) != $null ) {
    var %i = 1 | var %liste_channel = sur | :debchan
    if ( $comchan($did(smemory,303),%i) == $null ) { goto finchan }
    var %liste_channel = %liste_channel $comchan($did(smemory,303),%i)
  inc %i | goto debchan | :finchan }
  if ( %liste_channel == $null ) { did -ra smemory 311 Status actuel: $did(smemory,303) n'est sur aucun channel où vous vous trouvez... | goto fini }
  did -ra smemory 311 Status actuel: %liste_channel
:fini | did -ra smemory 312 Temps de recherche: %temps-recherche | did -ra smemory 305 Résultats de la recherche... }

on *:dialog:smemory:sclick:401:{ smaide 167 }
on *:dialog:smemory:sclick:405:{ if ( $window(@seen) == $null ) { mess_sm Le serveur seen n'est pas activée. Veuillez l'activer d'abord :) | halt }
  var %temps = $did(smemory,403) | if ( %temps == $null ) { mess_sm Pas de temps défini :p | halt } | if ( %temps <= 0 ) { mess_sm Pas de temps nul ou négatif :p | halt }
  var %temps = $calc( %temps * 86400 ) | did -ra smemory 415 Recherche en cours veuillez patienter... | did -r smemory 416
  var %debut = $ticks | var %i = 1 | var %ligne = 1 | var %lig = $line(@seen,%i)
  while ( %lig != $null ) {
    if ( $calc( $ctime - $gettok(%lig,5,32) ) < %temps ) { did -i smemory 416 %ligne $strip( $sm-format-reponse( %lig ) ) | inc %ligne }
  inc %i | var %lig = $line(@seen,%i) }
  dec %ligne | var %fin = $ticks
  if ( %ligne == 0 ) { did -ra smemory 415 Aucun élément ne correspond aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
  if ( %ligne > 0 ) { did -ra smemory 415 %ligne élément(s) corresponde(nt) aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
did -z smemory 416 }
on *:dialog:smemory:sclick:406:{ smaide 173 }
on *:dialog:smemory:sclick:410:{ if ( $window(@seen) == $null ) { mess_sm Le serveur seen n'est pas activée. Veuillez l'activer d'abord :) | halt }
  var %temps = $did(smemory,408) | if ( %temps == $null ) { mess_sm Pas de temps défini :p | halt } | if ( %temps <= 0 ) { mess_sm Pas de temps nul ou négatif :p | halt }
  var %temps = $calc( %temps * 86400 ) | did -ra smemory 415 Recherche en cours veuillez patienter... | did -r smemory 416
  var %debut = $ticks | var %i = 1 | var %ligne = 1 | var %lig = $line(@seen,%i)
  while ( %lig != $null ) {
    if ( $calc( $ctime - $gettok(%lig,5,32) ) > %temps ) { did -i smemory 416 %ligne $strip( $sm-format-reponse( %lig ) ) | inc %ligne }
  inc %i | var %lig = $line(@seen,%i) }
  dec %ligne | var %fin = $ticks
  if ( %ligne == 0 ) { did -ra smemory 415 Aucun élément ne correspond aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
  if ( %ligne > 0 ) { did -ra smemory 415 %ligne élément(s) corresponde(nt) aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
did -z smemory 416 }
on *:dialog:smemory:sclick:411:{ smaide 179 }
on *:dialog:smemory:sclick:414:{ if ( $window(@seen) == $null ) { mess_sm Le serveur seen n'est pas activée. Veuillez l'activer d'abord :) | halt }
  var %temps = $did(smemory,413) | if ( %temps == $null ) { mess_sm Pas d'adresse définie :p | halt } | if ( @ !isin %temps ) { mess_sm Adresse incorrecte | halt }
  did -ra smemory 415 Recherche en cours veuillez patienter... | did -r smemory 416
  var %debut = $ticks | var %i = 1 | var %ligne = 1 | var %lig = $line(@seen,%i)
  while ( %lig != $null ) {
    if ( %temps iswm $gettok(%lig,4,32) ) { did -i smemory 416 %ligne $strip( $sm-format-reponse( %lig ) ) | inc %ligne }
  inc %i | var %lig = $line(@seen,%i) }
  dec %ligne | var %fin = $ticks
  if ( %ligne == 0 ) { did -ra smemory 415 Aucun élément ne correspond aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
  if ( %ligne > 0 ) { did -ra smemory 415 %ligne élément(s) corresponde(nt) aux critères de recherche... / $calc( ( %fin - %debut ) / 1024 ) seconde(s). }
did -z smemory 416 }

; ###### Alias ######

alias clean_smemory {
  if ( $dialog(smemory).title != $null ) { dialog -x smemory }
  unset %smemory*
  linesep | echo $colour(Info Text) -s $timestamp Désintallation de Seen Memory 1.0
  echo $colour(Info Text) -s  $timestamp Variables effacées...
  run -n deltree /y $shortfn($mircdirSeen-Memory)
  echo $colour(Info Text) -s  $timestamp Répertoire effacé...
  echo $colour(Info Text) -s  $timestamp Fichier Seen-Memory.mrc effacé de la mémoire...
  echo $colour(Info Text) -s  $timestamp Désinstallation terminée...
  .unload -rs $shortfn($mircdirSeen-Memory.mrc)
}

alias decrypt-sm {
  if ($2) {
    %crypt.i = 0 | %crypt.keynum = 0 | %crypt.keylen = $len($1) | %crypt.textlen = $len($2-) | unset %crypt.result
    :start
    inc %crypt.i
    if (%crypt.keynum >= %crypt.keylen) { %crypt.keynum = 1 } | else { inc %crypt.keynum }
    %crypt.decrypt = $calc($asc($mid($2-, %crypt.i, 1)) - $asc($mid($1, %crypt.keynum, 1)))
    if (%crypt.decrypt != 32) { %crypt.result = %crypt.result $+ $chr(%crypt.decrypt) }
    else { %crypt.result = %crypt.result $+ [ $chr(32) ] $+ $chr(%crypt.decrypt) }
    if (%crypt.i < %crypt.textlen) { goto start }
    unset %crypt.i | unset %crypt.keynum | unset %crypt.keylen | unset %key.textlen | unset %crypt.decrypt | unset %crypt.textlen | var %ligne = %crypt.result | unset %crypt.result
return %ligne } }

alias smaide {
  if ( $1 == $null ) { halt }
  did -r smemory 3
  var %i = $1 | var %x = 1
  :deb
  var %lig = $read -nl $+ %i $shortfn($mircdirSeen-Memory\Aide._A_)
  if ( %lig == $chr(160) ) { goto fin }
  if ( %lig == $null ) { goto fin }
  did -i smemory 3 %x $decrypt-sm(%auteur2,%lig)
  inc %i | inc %x
  goto deb
:fin }

alias sm-aff-seen {
  verif_dialog smemory-chargement | dialog -m smemory-chargement smemory-chargement | dialog -t smemory-chargement Seen Memory v1.0... Chargement de la base de donnée... Veuillez patienter...
  window -hl @seen 50 50 200 200
  var %fic = " $+ $mircdirSeen-Memory\Database.ash $+ "
  var %nomb = 0 | var %filtre = 0 | if ( $lines(%fic) == 0 ) { goto fin } | var %temps = $ticks |  var %i = 1 | var %lig = $read -nl $+ %i %fic | var %i = 0
  while ( %lig != $null ) {
    inc %i | var %lig = $read -nl $+ %i %fic | if ( %lig == $null ) { /break }
    if ( %smemory-epuration == oui ) { var %filtrage = $calc( $ctime - $gettok(%lig,5,32) ) | var %temps2 = $calc( 86400 * %smemory-epuration-temps ) | if ( %filtrage > %temps2 ) { inc %filtre | did -ra smemory-chargement 4 Elément(s) filtré(s): %filtre | /continue } }
    aline -l @seen %lig | inc %nomb
  did -ra smemory-chargement 2 Eléments chargés: %nomb | did -ra smemory-chargement 3 Temps écoulé: $calc( ( $ticks - %temps ) / 1024 ) seconde(s) }
  :fin
  if ( %nomb != 0 ) { did -ra smemory-chargement 2 %nomb élément(s) ont été chargé | did -ra smemory-chargement 3 Temps de chargement: $calc( ( $ticks - %temps ) / 1024 ) seconde(s) }
  if ( %nomb == 0 ) { did -ra smemory-chargement 2 Aucun élément chargé... Base de donnée vide | did -r smemory-chargement 3 }
if ( ( %smemory-epuration == oui ) && ( %filtre != 0 ) ) { sm-sauvegarde-seen 1 } }

alias sm-check {
  var %i = 1 | var %rep = $line(@seen,%i)
  while ( %rep != $null ) { if ( $gettok(%rep,1,32) == $1 ) { rline @seen %i $1- | halt } | inc %i | var %rep = $line(@seen,%i) }
if ( $line(@seen,0) < %smemory-max-seen ) { aline -l @seen $1- | sm-status-seen } }

alias sm-format-reponse {
  if ( $gettok($1-,2,32) == Join ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) joindre $gettok($1-,3,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) }
  if ( $gettok($1-,2,32) == Kick ) {
    if ( $gettok($1-,7,32) == $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) être kické de $gettok($1-,3,32) par $gettok($1-,6,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . }
  if ( $gettok($1-,7,32) != $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) être kické de $gettok($1-,3,32) par $gettok($1-,6,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . Raison: $gettok($1-,7-,32) } }
  if ( $gettok($1-,2,32) == Nick ) {
    if ( $comchan($gettok($1-,6,32),1) != $null ) {
      var %i = 1 | var %liste_channel = sur | :debchan
      if ( $comchan($gettok($1-,6,32),%i) == $null ) { goto finchan }
      var %liste_channel = %liste_channel $comchan($gettok($1-,6,32),%i) | inc %i | goto debchan | :finchan
    return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) changer de nick pour $gettok($1-,6,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . $gettok($1-,6,32), est actuellement %liste_channel  $+ . }
  return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) changer de nick pour $gettok($1-,6,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) }
  if ( $gettok($1-,2,32) == Part ) {
    if ( $gettok($1-,6,32) == $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) quitter $gettok($1-,3,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . }
  if ( $gettok($1-,6,32) != $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) quitter $gettok($1-,3,32) il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . Raison: $gettok($1-,6-,32) } }
  if ( $gettok($1-,2,32) == Quit ) {
    if ( $gettok($1-,6,32) == $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) quitter l'Irc il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . }
if ( $gettok($1-,6,32) != $null ) { return J'ai vu $gettok($1-,1,32) ( $gettok($1-,4,32) ) quitter l'Irc il y a $replace($duration($calc( $ctime - $gettok($1-,5,32))),wk,$tps(semaine),day,$tps(jour),hr,$tps(heure),min,$tps(minute),sec,$tps(seconde))) $+ . Raison: $gettok($1-,6-,32) } } }

alias smemory {                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                         if ( $crc($shortfn($mircdirSeen-Memory\Seen-Memory.bmp)) != C66A2E95 ) { halt }
  var %lig = $read -l2 $shortfn($mircdirSeen-Memory\Aide._A_)                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                     | if ( $crc($shortfn($mircdirSeen-Memory\Ash.bmp)) != 96AE9364 ) { halt }
  var %lig2 = $read -l346 $shortfn($mircdirSeen-Memory\Aide._A_)                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                               | if ( $crc($shortfn($mircdirSeen-Memory\Aide._A_)) != 7CF52D4F ) { halt }
  verif_dialog smemory
  dialog -m smemory smemory
  did -g smemory 2 $shortfn($mircdirSeen-Memory\Seen-Memory.bmp)
  dialog -t smemory $decrypt-sm(%auteur2,%lig)
  set %auteurrr $read -l3 $shortfn($mircdirSeen-Memory\Aide._A_) | set %auteurrr $decrypt-sm(%auteur2,%auteurrr)
  verif-smemory | smaide 7
  window -hodp +Lfd @smemory 140 185 150 80
  window -a @smemory
  drawfill -r @smemory $rgb(128,128,128) $rgb(128,128,128) 10 10
  .timersmemory -m 0 100 /smemory2
  unset %smemory.* | set %smemory.x 100 | set %smemory.y 100 | set %smemory.scroll 1 | set %smemory.temps $time | set %smemory.check 1
}

alias smemory2 {
  if ( $dialog(smemory).title == $null ) { /.timersmemory off | /window -c @smemory | unset %smemory.* %auteurrr | halt }
  if ( eViL_d !isin %auteurrr ) { /dialog -x smemory }
  if ( $appactive == $false ) { /window -c @smemory | inc %smemory.scroll 1 | halt }
  if ( $appstate == minimized || $appstate == hidden ) { /window -c @smemory | inc %smemory.scroll 1 | halt }
  if ( $appactive == $true ) {
    inc %smemory.scroll 1
    if ( %smemory.check == 0 ) { /window -c @smemory | halt }
    if ( %smemory.check == 1 ) { if ( $window(@smemory) == $null ) { unset %smemory.smemory |  /window -hodp +Lfd @smemory $calc( $dialog(smemory).x + 40 ) $calc( $dialog(smemory).y + 85 ) 150 80 | /window -a @smemory |   /drawfill -r @smemory $rgb(128,128,128) $rgb(128,128,128) 10 10 } }
    if ( ( $dialog(smemory).title != $null ) && ( $dialog(smemory).x != %smemory.x || $dialog(smemory).y != %smemory.y ) ) {
    set %smemory.x $dialog(smemory).x | set %smemory.y $dialog(smemory).y | /window -c @smemory | /window -hodp +Lfe @smemory $calc( $dialog(smemory).x + 40 ) $calc( $dialog(smemory).y + 85 ) 150 80 | /window -a @smemory |   /drawfill -r @smemory $rgb(128,128,128) $rgb(128,128,128) 10 10 }
    if ( $dialog(smemory).title != $null ) {
      if ( %smemory.scroll >= 248 ) { set %smemory.scroll 1 } | if ( eViL_d !isin %auteur2 ) { /dialog -x smemory }
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 90 - %smemory.scroll + 1 ) 500 200 $str($chr(160),3) < Seen-Memory v1.0 >
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 102 - %smemory.scroll + 1 ) 500 200 $str($chr(160),6) %auteurrr
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 114 - %smemory.scroll + 1 ) 500 200 $str($chr(160),9) pour mIRC 5.7
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 126 - %smemory.scroll + 1 ) 500 200 $str($chr(160),10) Il est %smemory.temps
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 138 - %smemory.scroll + 1 ) 500 200 $chr(160)
      drawtext -rc @smemory  $rgb(128,128,128) Tahoma 12 5 $calc( 235 - %smemory.scroll + 1 ) 500 200 $str($chr(160),3) (c)2000 :: [ Ash Project ] ::
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 90 - %smemory.scroll ) 500 200  $str($chr(160),3) < Seen-Memory v1.0 >
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 102 - %smemory.scroll ) 500 200 $str($chr(160),6) %auteurrr
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 114 - %smemory.scroll ) 500 200 $str($chr(160),9) pour mIRC 5.7
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 126 - %smemory.scroll ) 500 200 $str($chr(160),10) Il est $time
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 138 - %smemory.scroll ) 500 200 $chr(160)
      drawpic -c @smemory 2 $calc( 150 - %smemory.scroll ) $shortfn($mircdirSeen-Memory\Ash.bmp)
      drawline -r @smemory $rgb(128,128,128) 1 0 $calc( 222 - %smemory.scroll ) 150 $calc( 222 - %smemory.scroll )
      drawtext -c @smemory  1 Tahoma 12 5 $calc( 235 - %smemory.scroll ) 500 200 $str($chr(160),3) (c)2000 :: [ Ash Project ] ::
set %smemory.temps $time } } }

alias mess_sm {
  verif_dialog mess-smemory
  var %lig = $read -l4 $shortfn($mircdirSeen-Memory\Aide._A_)
  dialog -mo mess-smemory mess-smemory
  dialog -t mess-smemory $decrypt-sm(%auteur2,%lig)
  did -ra mess-smemory 2 $1-
}

alias sm-recherche {
  if ( $2 == @ ) { if ( $1 == channel ) { /msg $3 $5- } | if ( $1 == message ) { .msg $4 $5- } | if ( $1 == notice ) { .notice $4 $5- } | halt }
  var %temps = $ticks | var %i = 1 | :deb | var %rep = $line(@seen,%i) | if ( %rep == $null ) { goto fin }
  if ( $gettok(%rep,1,32) == $4 ) { var %temps2 = $ticks
    if ( %smemory-temps == non ) {
      if ( $1 == channel ) { /msg $2 $3 $+ , $sm-format-reponse( %rep ) }
      if ( $1 == dcc ) { msg = $+ $3 $sm-format-reponse( %rep ) }
      if ( $1 == message ) { .msg $3 $sm-format-reponse( %rep ) }
      if ( $1 == notice ) { .notice $3 $sm-format-reponse( %rep ) }
    halt }
    if ( $1 == channel ) { /msg $2 $3 $+ , $sm-format-reponse( %rep ) ( Recherche effectuée en $calc( ( %temps2 - %temps ) / 1024 ) seconde(s) ) }
    if ( $1 == dcc ) { msg = $+ $3 $3 $+ , $sm-format-reponse( %rep ) ( Recherche effectuée en $calc( ( %temps2 - %temps ) / 1024 ) seconde(s) ) }
    if ( $1 == message ) { .msg $3 $sm-format-reponse( %rep ) ( Recherche effectuée en $calc( ( %temps2 - %temps ) / 1024 ) seconde(s) ) }
    if ( $1 == notice ) { .notice $3 $sm-format-reponse( %rep ) ( Recherche effectuée en $calc( ( %temps2 - %temps ) / 1024 ) seconde(s) ) }
  halt }
  inc %i | goto deb | :fin
  if ( $1 == channel ) { /msg $2 Désolé $3 je n'ai pas de $4 dans ma base de donnée... }
  if ( $1 == dcc ) { msg = $+ $3 Désolé $3 je n'ai pas de $4 dans ma base de donnée... }
  if ( $1 == message ) { .msg $3 Désolé $3 je n'ai pas de $4 dans ma base de donnée... }
  if ( $1 == notice ) { .notice $3 Désolé $3 je n'ai pas de $4 dans ma base de donnée... }
}

alias sm-sauvegarde-seen {
  if ( $1 = 1 ) { linesep | echo $colour(Info Text) -s $timestap Seen Memory v1.0 => Sauvegarde des données... Veuillez patientez... }
  var %temps = $ticks
  var %fic = " $+ $mircdirSeen-Memory\Database.ash $+ "
  .remove %fic
  if ( $line(@seen,0) == 0 ) { write %fic ok | write -d1 %fic | goto fini }
  var %i = 1 | var %lig = $line(@seen,%i)
  while ( %lig != $null ) { write %fic %lig | inc %i | var %lig = $line(@seen,%i) }
  var %temps2 = $ticks
  if ( $1 = 1 ) {
    if ( $line(@seen,0) != 0 ) { echo $colour(Info Text) -s => $line(@seen,0) élément(s) sauvegardé(s)... | echo $colour(Info Text) -s => Temps de sauvegarde: $calc( ( %temps2 - %temps ) / 1024 ) seconde(s) ) }
if ( $line(@seen,0) == 0 ) { echo $colour(Info Text) -s => Pas d'élément a sauvegarder... } } | :fini }

alias sm-sauvegarde-donnée { if ( $server == $null ) { .timersmsauvegarde off | halt } | sm-sauvegarde-seen 1 }

alias sm-status-seen {
  if ( $dialog(smemory).title == $null ) { halt }
  var %rep = $line(@seen,0)
  if ( %rep == 0 ) { did -ra smemory 52 >0%< } | if ( %rep != 0 ) { did -ra smemory 52 0% }
  if ( %rep == %smemory-max-seen ) { did -ra smemory 54 >100%< } | if ( %rep != %smemory-max-seen ) { did -ra smemory 54 100% }
  did -ra smemory 50 Status de la base de donnée... ( %rep élément(s) / Encombement à $calc( %rep / %smemory-max-seen * 100 ) $+ % )
did -ra smemory 53 $str($chr(1),$int( $calc( %rep / %smemory-max-seen * 120 ) ) ) }

alias tps { return $chr(160) $+ $1- }

alias verif_dialog { if ( $dialog($1).title != $null ) { /dialog -v $1 | halt } }

alias verif-smemory {
  var %rep = $line(@seen,0)

  did -b smemory 108,110

  if ( %smemory-seen == oui ) { did -c smemory 47 | .enable #Seen-Memory | if ( %smemory-sauvegarde == horaire ) { .timersmsauvegarde 0 3600 /sm-sauvegarde-donnée } }
  if ( %smemory-seen == non ) { did -c smemory 48 | .disable #Seen-Memory | .timersmsauvegarde off }
  did -ra smemory 57 %smemory-max-seen
  if ( %rep > %smemory-max-seen ) { var %i = $calc( %rep - %smemory-max-seen ) | var %x = $calc( %smemory-max-seen + 1 ) $+ - $+ %rep | dline @seen [ %x ] | mess_sm %i personne(s) ont été éffacé de la base de donnée... |  var %rep = $line(@seen,0) }
  did -ra smemory 50 Status de la base de donnée... ( %rep élément(s) / Encombement à $calc( %rep / %smemory-max-seen * 100 ) $+ % )
  if ( %rep == 0 ) { did -ra smemory 52 [0%] } | if ( %rep != 0 ) { did -ra smemory 52 0% }
  if ( %rep == %smemory-max-seen ) { did -ra smemory 54 [100%] } | if ( %rep != %smemory-max-seen ) { did -ra smemory 54 100% }
  did -ra smemory 53 $str($chr(1),$int( $calc( %rep / %smemory-max-seen * 120 ) ) )
  did -ra smemory 63 %smemory-commande
  if ( %smemory-type-reponse == channel ) { did -c smemory 67 }
  if ( %smemory-type-reponse == message ) { did -c smemory 68 }
  if ( %smemory-type-reponse == notice ) { did -c smemory 68 }
  if ( %smemory-temps == oui ) { did -c smemory 64 }
  if ( %smemory-prive  == oui ) { did -c smemory 102 }
  if ( %smemory-dcc  == oui ) { did -c smemory 104 }
  if ( %smemory-protection  == oui ) { did -c smemory 106 | did -e smemory 108,110 }
  did -ra smemory 108 %smemory-max
  did -ra smemory 110 %smemory-protection-temps
  if ( %smemory-log == oui ) { did -c smemory 113 }
  did -r smemory 119,125
  var %i = 1 | var %lig = $gettok(%smemory-channel-non-log,%i,32)
  while ( %lig != $null ) { did -a smemory 119 %lig | inc %i | var %lig = $gettok(%smemory-channel-non-log,%i,32) }
  var %i = 1 | var %lig = $gettok(%smemory-channel-non-rep,%i,32)
  while ( %lig != $null ) { did -a smemory 125 %lig | inc %i | var %lig = $gettok(%smemory-channel-non-rep,%i,32) }
  did -z smemory 119,125
  if ( %smemory-sauvegarde == deconnection ) { did -c smemory 202 }
  if ( %smemory-sauvegarde == horaire ) { did -c smemory 204 }
  did -ra smemory 208 %smemory-epuration-temps
  if ( %smemory-epuration == oui ) { did -c smemory 210 }
}

; ###### Core ######

on 1:CHAT:*: {
  if ( %smemory-seen == non ) { goto fin }
  if ( %smemory-dcc == non ) { goto fin }

  if ( ( $1 == %smemory-commande ) && ( $2 != $null ) ) {
    if ( %smemory-protection == non ) { goto nonmais }
    if ([ %smemory-temp.dcc. [ $+ [ $chat($nick).ip ] ] ] != $null ) { goto fin }

    if ([ %smemory-temp. [ $+ [ $chat($nick).ip ] ] ] == $null) { set  %smemory-temp. [ $+ [ $chat($nick).ip ] ] 1 | .timer 1 %smemory-protection-temps /unset %smemory-temp. [ $+ [ $chat($nick).ip ] ] | goto nonmais }
    if ([ %smemory-temp. [ $+ [ $chat($nick).ip ] ] ] >= %smemory-max ) {
      linesep | echo $colour(Info Text) -s $timestamp Seen Flood de $nick ( $chat($nick).ip ) => plus de %smemory-max requête(s) seen en %smemory-protection-temps secondes : le flooder sera ignoré pendant 5 minutes...
      set %smemory-temp.dcc. [ $+ [ $chat($nick).ip ] ] 1 | .ignore -ncpku300 $nick | .unset %smemory-temp. [ $+ [ $chat($nick).ip ] ]
    .timer 1 300 /unset %smemory-temp.dcc [ $+ [ $chat($nick).ip ] ] | goto fin }
    inc %smemory-temp. [ $+ [ $chat($nick).ip ] ]
    :nonmais

    if ( %smemory-log == oui ) { linesep | echo $colour(Info Text) -s $timestamp $nick ( $chat($nick).ip ) a demandé le server seen sur un Dcc Chat ( recherche de $2 ) ... }
    if ($2 == $me) { sm-recherche dcc @ $nick $nick Je suis là $nick $+ !!! Arrêtes de me faire perdre mon temps... | goto fin }
    if ($2 == $nick) { sm-recherche dcc @ $nick $nick ?¿ Je me demande si tu n'as pas de multiples personnalités $nick ?¿ | goto fin }
    if ( $comchan($2,1) != $null ) {
      var %i = 1 | var %liste_channel = sur
      :debchan
      if ( $comchan($2,%i) == $null ) { goto finchan }
      var %liste_channel = %liste_channel $comchan($2,%i)
      inc %i
      goto debchan
      :finchan
    sm-recherche dcc @ $nick $nick $2 est %liste_channel :+) | goto fin }
  sm-recherche dcc $nick $nick $2 }
:fin  }

on 1:CONNECT: { .ial on | unset %smemory-temp.*
if ( %smemory-seen == oui ) { .enable #Seen-Memory | if ( %smemory-sauvegarde == horaire ) { .timersmsauvegarde 0 3600 /sm-sauvegarde-donnée } } | if ( %smemory-seen == non ) { .disable #Seen-Memory } }

on 1:DISCONNECT: { sm-sauvegarde-seen 1 | unset %smemory-temp.* | .timersmsauvegarde off
if ( %smemory-seen == oui ) { .enable #Seen-Memory } | if ( %smemory-seen == non ) { .disable #Seen-Memory } }

on 1:START: { if ( %smemory-seen == oui) { if ( %test == $null ) { sm-aff-seen } | if ( %test != $null ) { unset %test } } | unset %smemory-temp.*
if ( %smemory-seen == oui ) { .enable #Seen-Memory } | if ( %smemory-seen == non ) { .disable #Seen-Memory } }

on 1:TEXT:*:#:{

  if ( %smemory-seen == non ) { goto fin }
  if ( $istok(%smemory-channel-non-rep,$chan,32) == $true ) { goto fin }

  if ( ( $1 == %smemory-commande ) && ( $2 != $null ) ) {
    if ( %smemory-protection == non ) { goto nonmais }

    if ([ %smemory-temp. [ $+ [ $site ] ] ] == $null) { set  %smemory-temp. [ $+ [ $site ] ] 1 | .timer 1 %smemory-protection-temps /unset %smemory-temp. [ $+ [ $site ] ] | goto nonmais }
    if ([ %smemory-temp. [ $+ [ $site ] ] ] >= %smemory-max ) {
      linesep | echo $colour(Info Text) -s $timestamp Seen Flood de $nick ( *!*@ $+ $site ) => plus de %smemory-max requête(s) seen en %smemory-protection-temps secondes : le flooder sera ignoré pendant 5 minutes...
    .ignore -ncpku300 *!*@ $+ $site | .unset %smemory-temp. [ $+ [ $site ] ]  | goto fin }
    inc %smemory-temp. [ $+ [ $site ] ]
    :nonmais

    if ( %smemory-log == oui ) { linesep | echo $colour(Info Text) -s $timestamp $nick ( *!*@ $+ $site ) a demandé le server seen sur $chan ( recherche de $2 ) ... }
    if ($2 == $me) { sm-recherche %smemory-type-reponse @ $chan $nick Je suis là $nick $+ !!! Arrêtes de me faire perdre mon temps... | goto fin }
    if ($2 == $nick) { sm-recherche %smemory-type-reponse @ $chan $nick ?¿ Je me demande si tu n'as pas de multiples personnalités $nick ?¿ | goto fin }
    if ($2 ison $chan) { sm-recherche %smemory-type-reponse @ $chan $nick $2 est actuellement sur $chan !!! Arrêtes de me faire perdre mon temps... | goto fin }
    if ( $comchan($2,1) != $null ) {
      var %i = 1 | var %liste_channel = sur
      :debchan
      if ( $comchan($2,%i) == $null ) { goto finchan }
      var %liste_channel = %liste_channel $comchan($2,%i)
      inc %i
      goto debchan
      :finchan
    sm-recherche %smemory-type-reponse @ $chan $nick $2 est %liste_channel :+) | goto fin }
  sm-recherche %smemory-type-reponse $chan $nick $2 }
:fin }

on 1:TEXT:*:?:{
  if ( %smemory-seen == non ) { goto fin }
  if ( %smemory-prive == non ) { goto fin }

  if ( ( $1 == %smemory-commande ) && ( $2 != $null ) ) {
    if ( %smemory-protection == non ) { goto nonmais }

    if ([ %smemory-temp. [ $+ [ $site ] ] ] == $null) { set  %smemory-temp. [ $+ [ $site ] ] 1 | .timer 1 %smemory-protection-temps /unset %smemory-temp. [ $+ [ $site ] ] | goto nonmais }
    if ([ %smemory-temp. [ $+ [ $site ] ] ] >= %smemory-max ) {
      linesep | echo $colour(Info Text) -s $timestamp Seen Flood de $nick ( *!*@ $+ $site ) => plus de %smemory-max requête(s) seen en %smemory-protection-temps secondes : le flooder sera ignoré pendant 5 minutes...
    .ignore -ncpku300 *!*@ $+ $site | .unset %smemory-temp. [ $+ [ $site ] ]  | goto fin }
    inc %smemory-temp. [ $+ [ $site ] ]
    :nonmais

    if ( %smemory-log == oui ) { linesep | echo $colour(Info Text) -s $timestamp $nick ( *!*@ $+ $site ) a demandé le server seen en privé ( recherche de $2 ) ... }
    if ($2 == $me) { sm-recherche message @ $nick $nick Je suis là $nick $+ !!! Arrêtes de me faire perdre mon temps... | goto fin }
    if ($2 == $nick) { sm-recherche message @ $nick $nick ?¿ Je me demande si tu n'as pas de multiples personnalités $nick ?¿ | goto fin }
    if ( $comchan($2,1) != $null ) {
      var %i = 1 | var %liste_channel = sur
      :debchan
      if ( $comchan($2,%i) == $null ) { goto finchan }
      var %liste_channel = %liste_channel $comchan($2,%i)
      inc %i
      goto debchan
      :finchan
    sm-recherche message @ $nick $nick $2 est %liste_channel :+) | goto fin }
  sm-recherche message $nick $nick $2 }
:fin }

#Seen-Memory on

on 1:JOIN:#:{ if ( $nick == $me ) { goto fin }
  if ( $istok(%smemory-channel-non-log,$chan,32) == $true ) { goto fin }
  sm-check $nick Join $chan $address($nick,5) $ctime
:fin }

on 1:KICK:#:{ if ( ( $nick == $me ) || ( $knick == $me ) ) { goto fin }
  if ( $istok(%smemory-channel-non-log,$chan,32) == $true ) { goto fin }
  if ( $address($knick,5) == $null ) { sm-check $knick Kick $chan Inconnu $ctime $nick $1- | goto fin }
  if ( $address($knick,5) != $null ) { sm-check $knick Kick $chan $address($knick,5) $ctime $nick $1- }
:fin }

on 1:NICK:{ if ( $nick == $me ) { goto fin }
  if ( $address($nick,5) == $null ) { sm-check $nick Nick @ *!*@ $+ $site $ctime $newnick | goto fin }
  if ( $address($nick,5) != $null ) { sm-check $nick Nick @ $address($nick,5) $ctime $newnick }
:fin }

on 1:PART:#:{ if ( $nick == $me ) { goto fin }
  if ( $istok(%smemory-channel-non-log,$chan,32) == $true ) { goto fin }
  if ( $address($nick,5) == $null ) { sm-check $nick Part $chan *!*@ $+ $site $ctime $1- | goto fin }
  if ( $address($nick,5) != $null ) { sm-check $nick Part $chan $address($nick,5) $ctime $1- }
:fin }

on 1:QUIT: { if ( $nick == $me ) { goto fin }
  if ( $site == $null ) { sm-check $nick Quit @ Inconnu $ctime $1- | goto fin }
  if ( $site != $null ) { sm-check $nick Quit @ *!*@ $+ $site $ctime $1- }
:fin }

#Seen-Memory end

; ###### Menu ######

menu @eViL_dEaD {
  sclick { if ( %evil_dead == 1 ) { window -c @eViL_dEaD | unset %evil_dead %coul_smemory } }
}

menu menubar,status,channel {
  -
  Seen-Memory v1.0
  .Lancer:/smemory
  .Ecrivez moi:/run mailto:ash@enjoy-unix.org?Subject=Seen Memory 1.0
  .-
  .Désinstaller:/clean_smemory
}

; ###### Initialisation ######

on 1:LOAD: {
  if ( $version < 5.7 ) { linesep | echo $colour(Info Text) -s Chargement annulé... Veuillez installer une version de mIRC >= 5.7... | .unload -rs Seen-Memory.mrc | halt }
  if ( ( $window(-1).h < 768 ) && ( $window(-1).w < 1024 ) ) { linesep | echo $colour(Info Text) -s La résolution de votre écran n'est pas optimale ( < 1024*768 ), l'affichage sera peut être tronqué... }
  .ial on | set %test ok | window -hl @seen 50 50 200 200
  unset %evil_dead | set %auteur2 eViL_dEaD
  set %smemory-channel-non-log #montreal
  set %smemory-channel-non-rep ""
  set %smemory-commande !seen
  set %smemory-dcc oui
  set %smemory-epuration oui
  set %smemory-epuration-temps 60
  set %smemory-log oui
  set %smemory-max 4
  set %smemory-max-seen 1000
  set %smemory-prive oui
  set %smemory-protection oui
  set %smemory-protection-temps 30
  set %smemory-sauvegarde deconnection
  set %smemory-seen oui
  set %smemory-temps oui
  set %smemory-type-reponse channel
  unset %evil_dead
  window -aohdp +f  @eViL_dEaD $calc( ( $window(-1).w - 300 ) / 2 )  $calc( ( $window(-1).h - 200 ) / 2 ) 300 200 @eViL_dEaD
  /drawfill @eViL_dEaD 1 1 1 1
  set %coul_smemory 255
  /.timerdem -m 26 10 /aff_deb_smemory
}

alias aff_deb_smemory {
  /drawtext -rc @eViL_dEaD $rgb(%coul_smemory,%coul_smemory,%coul_smemory) Tahoma 50 50 65 500 500 eViL_dEaD
  dec %coul_smemory 10
  if ( %coul_smemory < 0 )  { /.timerdem off | set %coul_smemory 255 |  /.timerdem -m 26 10 /aff_deb_smemory2 }
}

alias aff_deb_smemory2 {
  /drawtext -rc @eViL_dEaD $rgb(%coul_smemory,%coul_smemory,%coul_smemory) Tahoma 60 50 65 500 500 présente
  dec %coul_smemory 10
  if ( %coul_smemory < 0 )  { /.timerdem off |  set %coul_smemory 255 |  /.timerdem -m 26 1 /aff_deb_smemory3 }
}

alias aff_deb_smemory3 {
  /drawtext -rc @eViL_dEaD $rgb(%coul_smemory,%coul_smemory,%coul_smemory) Tahoma 60 10 65 500 500 Seen-
  dec %coul_smemory 10
  if ( %coul_smemory < 0 )  { /.timerdem off |  set %coul_smemory 255 |  /.timerdem -m 26 1 /aff_deb_smemory4 }
}

alias aff_deb_smemory4 {
  /drawtext -rc @eViL_dEaD $rgb(%coul_smemory,%coul_smemory,%coul_smemory) Tahoma 60 100 65 500 500 Memory
  dec %coul_smemory 10
  if ( %coul_smemory < 0 )  { /.timerdem off |  set %coul_smemory 255 |  /.timerdem -m 26 1 /aff_deb_smemory5 }
}

alias aff_deb_smemory5 {
  /drawtext -rc @eViL_dEaD $rgb(%coul_smemory,%coul_smemory,%coul_smemory) Tahoma 60 30 65 500 500 version 1.0
  dec %coul_smemory 10
  if ( %coul_smemory < 0 )  { /.timerdem off |  unset %coul_smemory |  /aff_deb_smemoryfin }
}

alias aff_deb_smemoryfin {
  set %evil_dead 1
  /.timerdem -m 0 100  /aff_deb_smemorynj
  /drawtext -c @eViL_dEaD 0 Tahoma 14 80 5 500 500 Seen-Memory v1.1
  /drawtext -c @eViL_dEaD 0 Tahoma 12 5 45 500 500 Cet Add-on vous permet d'avoir un serveur seen :pppp
  /drawtext -c @eViL_dEaD 0 Tahoma 12 5 65 500 500 C' était pas trop dur à deviner ;)
  /drawtext -c @eViL_dEaD 0 Tahoma 11 45 180 500 500  (c)2000 :: [ eViL_dEaD ] Scripts :: Ash Project ::
  /drawtext -c @eViL_dEaD 0 Tahoma 11 60 155 500 500 ( Clickez dans la fenêtre pour la fermer )
}

alias aff_deb_smemorynj {  if ( $window(@eViL_dEaD) == $null ) { /.timerdem off | halt } | /drawtext -rc @eViL_dEaD $rgb($rand(0,255),$rand(0,255),$rand(0,255)) Tahoma 18 15 105 500 500 <<<<<< Klatu Verata Nectu >>>>>>  }