aur/solaar: PKGBUILD-0.9.2-2

# Maintainer: Arnaud Taffanel <dev@taffanel.org>

pkgname=solaar
pkgver=0.9.2
pkgrel=2
pkgdesc="Device manager for Logitech's Unifying receiver peripherals"
url="http://pwr.github.com/Solaar/"
license=('GPL2')
groups=()
arch=('any')
depends=('python' 'python-pyudev' 'python-gobject' 'pygtk')
optdepends=(
  'libappindicator3: better integration into Unity'
  )
makedepends=('python')
provides=('solaar')
conflicts=('solaar')
options=(!emptydirs)
install=solaar.install
source=("https://github.com/pwr/Solaar/archive/${pkgver}.tar.gz"
        'solaar.install'
        'workaround_Argument_0_does_not_allow_None.patch')
md5sums=('2a6ea17150cf030b09ff802cb454358b'
         '2416fcb58a4c24da5bbb94a9207799b4'
         '5e960c11699d75dc28e79ca4d70a07c1')

prepare() {
  cd "$srcdir/Solaar-${pkgver}/"
  patch -p1 -i "$srcdir/workaround_Argument_0_does_not_allow_None.patch"
}

package() {
  cd "$srcdir/Solaar-${pkgver}/"
  python3 setup.py install --root="$pkgdir/" --optimize=1
  install -D -m0644 rules.d/42-logitech-unify-permissions.rules \
                   "$pkgdir/etc/udev/rules.d/42-logitech-unify-permissions.rules"
}

post_install() {
  xdg-icon-resource forceupdate --theme hicolor
  update-desktop-database -q
}
# vim:set ts=2 sw=2 et: