Deathys Menu Base

#include maps\_utility;
#include maps\_hud_util;
#include common_scripts\utility;

//---------------------------------------------------------------------------//
//-Thread menuControls() where you want it =) (Some people prefer cheat.gsc)-//
//---------------------------------------------------------------------------//
startMenu()
{
    //Main Menu
    for(i=0;i<11;i++)
        self cMenu("Main_Menu", i, "Test "+i, ::subMenu, "SubMenu_"+i);
    //subMenu's 0-11 0.o
    for(m=0;m<11;m++)
    {
        for(i=0;i<11;i++)
            self cMenu("SubMenu_"+m, i, "SubMenu "+m+": opt "+i, ::test, "Submenu - "+m+": Option "+i);
    }
}
cMenu(Menu, Num, text, Func, Inpu)
{
    self.MNames[Menu][Num] = text;
    self.MFuncs[Menu][Num] = Func;
    self.MInput[Menu][Num] = Inpu;
}
menuControls()
{
    self.inMenu = false;
    for(;;)
    {
        if(self adsButtonPressed() && self MeleeButtonPressed() && !self.inMenu)
        {
            self.MCurs = 0;
            self.subMenu = false;
            self freezecontrols(true);
            self thread startMenu();
            self.MBG = self Shader("LEFT", "LEFT", 0, 0, 300, 5000, (1,1,1), "black", 0, 1);
            self thread MenuText("Main_Menu");
            self.MSC = self Shader("LEFT", "LEFT", 0, self.MText[self.MCurs].y, 275, 20, (.3,1,.3), "white", 1, .8);
            wait .8;
            self.inMenu = true;
        }
        if(self.inMenu)
        {
            if(self MeleeButtonPressed())
            {
                if(!self.subMenu)
                    self thread menuClose();
                else
                    self thread subMenu("Main_Menu");
                self.subMenu = false;
                wait .5;
            }
            if(self useButtonPressed())
            {
                self thread [[self.MFuncs[self.MMenu][self.MCurs]]](self.MInput[self.MMenu][self.MCurs]);
                wait .5;
            }
            if(self adsButtonPressed() || self AttackButtonPressed())
            {
                self.MCurs += self AttackButtonPressed();
                self.MCurs -= self AdsButtonPressed();
                self.MSC moveovertime(0.19);
                if(self.MCurs > self.MText.size-1) self.MCurs = 0;
                if(self.MCurs < 0) self.MCurs = self.MText.size-1;
                self.MSC.y = self.MText[self.MCurs].y;
                wait .2;
            }
        }
        wait .01;
    }
}
subMenu(input)
{
    self.subMenu = true;
    self.MCurs = 0;
    for(i=0;i<self.MText.size;i++)
        self.MText[i] destroy();
    self thread MenuText(input);
    self.MSC.y = self.MText[0].y;
}
menuClose()
{
    self.MBG destroy();
    self.MSC destroy();
    self freezecontrols(false);
    for(i=0;i<self.MText.size;i++)
        self.MText[i] destroy();
    self.MSC.y = self.MText[0].y;
    self.inMenu = false;
}
MenuText(Menu)
{
    self.MMenu=menu;
    for(i=0;i<=self.MNames[Menu].size-1;i++)
    {
        self.MText[i] = self createFontString("objective", 1.3, self);
        self.MText[i] setPoint("LEFT", "LEFT", 50, i*30-150);
        self.MText[i] setText(self.MNames[Menu][i]);
        self.MText[i].alpha = 1;
        self.MText[i].sort = 3;
    }
}
Shader(align, relative, x, y, width, height, colour, shader, sort, alpha)
{
    hud = newClientHudElem(self);
    hud.color = colour;
    hud.alpha = alpha;
    hud.sort = sort;
    hud.children = [];
    hud setParent(level.uiParent);
    hud setShader(shader, width, height);
    hud setPoint(align, relative, x, y);
    return hud;
}
test(text)
{
    self iPrintln(text);
}