TESTie Flight Tool Build 0069

#IfWinActive Star Citizen
#NoTrayIcon
#SingleInstance force
#Warn All, Off

; Check for administrator rights and restart in admin mode if necessary.
if A_IsCompiled
{
   if not A_IsAdmin
   {
     Try
     {
       Run *RunAs "%A_ScriptFullPath%"
     }
     ExitApp
   }
}

myName = Testie Flight Tool
myAbout = Star Citizen VJOY app. created by MammonLord.`nBased on a controller balance suggestion by Pepperz.
myVersion = Build 0069

helpLink = https://forums.robertsspaceindustries.com/discussion/268979/testie-flight-mode-preview-extended-relative/p1#Item_0

; Create the tray icon.
Menu, Tray, NoStandard
Menu, Tray, Tip, %myName%`n%myVersion%
Menu, Tray, Add, E&xit, ExitClicked
Menu, Tray, Default, E&xit
Menu, Tray, Icon

; Create the sub-menus for the menu bar:
Menu, FileMenu, Add, E&xit, ExitClicked
Menu, HelpMenu, Add, Open the &Help Thread, HelpThread
Menu, HelpMenu, Add, &About, HelpAbout

; Create the menu bar by attaching the sub-menus to it:
Menu, MyMenuBar, Add, &File, :FileMenu
Menu, MyMenuBar, Add, &Help, :HelpMenu

; Attach the menu bar to the window:
Gui, Menu, MyMenuBar

; Create the form and display the window:
Gui, Margin, 0, 0, 0, 10
Gui, -Resize  ; Make the window non-resizable.
Gui, font, s14 q4, Tahoma ; Set 14-point Tahoma
Gui, Add, Text, x15 y10, How to:
Gui, Add, Text, x15 y+0, 1.
Gui, Add, Text, x+10, Launch this app (Good job)
Gui, Add, Text, x15 y+0, 2.
Gui, Add, Text, x+10, Launch Arena Commander
Gui, Add, Text, x15 y+0, 3.
Gui, Add, Text, x+10, Press Ctrl+C for Relative Mode
Gui, Add, Text, x15 y+0, 4.
Gui, Add, Text, x+10, Press Left Alt to lock gimbals
Gui, Add, Text, x15 y+0, 5.
Gui, Add, Text, x+10, Activate VJOY by holding the modifier key

Gui, Add, Text, x15 y+20, Select VJOY modifier key:
Gui, font, s12 q4, Tahoma ; Set 12-point Tahoma
Gui, Add, Radio, gModeLeftControl checked y+5, Left &Control key
Gui, Add, Radio, gModeMiddleMouseButton y+0, &Middle mouse button
Gui, Add, Radio, gModeXButton1 y+0, Mouse Thumb Button &1
Gui, Add, Radio, gModeXButton2 y+0, Mouse Thumb Button &2
Gui, font, s14 q4, Tahoma ; Set 14-point Tahoma

Gui, Add, Text, x15 y+17, Press F11 to perform steps 3 and 4 automatically
Gui, Font, underline
Gui, Add, Text, x15 cBlue gHelpThread y+5, Visit our forum thread to provide feedback.
Gui, Font, norm
Gui, font, s10 q4, Tahoma ; Set 10-point Tahoma
Gui, Add, Button, -default x15 y+25, Join &TEST Squadron!
Gui, Add, Text, x0 y+3, ; Bottom margin simulator

Gui, Add, Picture, Icon5 y0 x400 w200 h256, %A_ScriptFullPath%
Gui, Add, Picture, Icon4 y+0 x462 w128 h128 gButtonJoinTESTSquadron!, %A_ScriptFullPath%

Gui, Show, , %myName%

; Create hotkeys and set default mode:
Hotkey, ~$LControl, LeftControl
Hotkey, ~MButton, MiddleMouseButton
Hotkey, ~XButton1, XMouseButton1
Hotkey, ~XButton2, XMouseButton2
Hotkey, ~F11, Setup
Hotkey, MButton, Off
Hotkey, XButton1, Off
Hotkey, XButton2, Off
return

ButtonJoinTESTSquadron!:
Run "https://robertsspaceindustries.com/orgs/TEST"
return

HelpThread:
Run %helpLink%
return

HelpAbout:
Gui, About:+owner1  ; Make the main window (Gui #1) the owner of the "about box".
Gui, About:-Resize  ; No resizing the about box
Gui +Disabled  ; Disable main window.
Gui, About:Add, Text,, %myName%`n`n%myAbout%`n`n%myVersion%
Gui, About:Add, Button, Default -Wrap, OK
Gui, About:Show, , About %myName%
return

AboutButtonOK:  ; This section is used by the "about box" above.
AboutGuiClose:
AboutGuiEscape:
Gui, 1:-Disabled  ; Enable the main window.
Gui Destroy  ; Destroy the about box.
return

ModeLeftControl:
    Hotkey, LControl, On
    Hotkey, MButton, Off
    Hotkey, XButton1, Off
    Hotkey, XButton2, Off
return

ModeMiddleMouseButton:
    Hotkey, LControl, Off
    Hotkey, MButton, On
    Hotkey, XButton1, Off
    Hotkey, XButton2, Off
return

ModeXButton1:
    Hotkey, LControl, Off
    Hotkey, MButton, Off
    Hotkey, XButton1, On
    Hotkey, XButton2, Off
return

ModeXButton2:
    Hotkey, LControl, Off
    Hotkey, MButton, Off
    Hotkey, XButton1, Off
    Hotkey, XButton2, On
return

ExitClicked:     ; User chose "Exit" from the File menu or tray icon.
GuiClose:  ; User closed the window.
ExitApp

LeftControl:
    Send ^c
    While GetKeyState("Ctrl", "P")
    {
      Sleep 1
    }
    Send ^c
return

MiddleMouseButton:
    Send ^c
    While GetKeyState("MButton", "P")
    {
      Sleep 10
    }
    Send ^c
return

XMouseButton1:
    Send ^c
    While GetKeyState("XButton1", "P")
    {
      Sleep 1
    }
    Send ^c
return

XMouseButton2:
    Send ^c
    While GetKeyState("XButton2", "P")
    {
      Sleep 1
    }
    Send ^c
return

Setup:
    Send ^c
    Send {LAlt}
    SoundPlay *48
return