league of legends language unlocker/launcher 4 - Modified

:: ORiginal script & Credits: http://www.reddit.com/r/leagueoflegends/comments/2q0c5u/script_that_enables_all_languages_in_all/
:: Modified the script to be more user-friendly.
:: ADDED: Now it backups the regions.txt file before deleting it.
:: No editing is required by the user. Just run the script.
:: Modified by http://www.reddit.com/user/Nominance/

@ECHO OFF
COLOR 1E
TITLE League of Legends Language Unlocker

:: Change the below variable to the folder where League of Legends is installed.
:: Do NOT add the trailing backslash.
:: Default: C:\Riot Games\League of Legends
SET target=C:\Riot Games\League of Legends

:Prompt

IF NOT EXIST "%target%\lol.launcher.exe" (
echo Could not find League of Legends at %target%
echo.
echo Paste here your League of Legends folder location.
echo Example: "C:\Riot Games\League of Legends"
set /p target=
cls
)

IF NOT EXIST "%target%\lol.launcher.exe" GOTO Prompt

:: This string determines what languages you want to use.
:: cs_CZ Czech          de_DE German
:: el_GR Greek          en_AU English AU
:: en_GB English UK     en_US English US
:: es_AR Spanish AR     es_ES Spanish ES
:: es_MX Spanish MX     fr_FR French
:: hu_HU Hungarian      it_IT Italian
:: ko_KR Korean         pl_PL Polish
:: pt_BR Portuguese BR  ro_RO Romanian
:: ru_RU Russian        tr_TR Turkish

:: The string must always end in , A
:: Every pipe character that's used in this string must be escaped with three
:: carats; the reason why we must use three carats is to escape the base carat
:: character so that, when passed as a variable, there's still an escape character.
SET lollanguages=cs_CZ^^^|de_DE^^^|el_GR^^^|en_AU^^^|en_GB^^^|en_US^^^|es_AR^^^|es_ES^^^|es_MX^^^|fr_FR^^^|hu_HU^^^|it_IT^^^|ko_KR^^^|pl_PL^^^|pt_BR^^^|ro_RO^^^|ru_RU^^^|tr_TR,                                                    A

:: We must set the regions.txt to not be read-only.
:: We set the file to read-only so that, in the event you forget to run this when
:: you update League of Legends, you should still be able to play in the language
:: you want.
ATTRIB -R "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO Backing up regions.txt...
:: We backup the original regions.txt file and then we delete it to create the new one (Modified by Nominance)
COPY "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt" "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions-backup.txt"
ECHO Deleting old regions.txt file...
DEL "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO Writing new regions.txt file with all languages enabled...

:: The following commands write a brand new regions.txt file with all languages
:: enabled from all available regions.
ECHO na,            na,            %lollanguages% > "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO br,            br,            %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO tr,            tr,            %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO euw,           euw,           %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO eune,          eune,          %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO ru,            ru,            %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO la1,           la1,           %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO la2,           la2,           %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO oc1,           oc1,           %lollanguages% >> "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"
ECHO Write complete!

:: We set the new regions.txt as read-only.
ATTRIB +R "%target%\RADS\projects\lol_patcher\managedfiles\0.0.0.0\regions.txt"

:: The below shows you what languages are installed.
:: Some of the languages just show like an "empty" row in the language/region
:: selection. When you run this script, the following will tell you what those
:: languages are. There's also multiple entries for English and Spanish, so you
:: can also know which of the varieties of languages you're using.
ECHO.
ECHO ==============================================================================
ECHO Languages in Order:
ECHO Czech, German, Greek, English (AU), English (UK), English (NA), Spanish (AR),
ECHO Spanish (ES), Spanish (MX), French, Hungarian, Italian, Korean, Polish,
ECHO Portuguese (BR), Romanian, Russian, Turkish
ECHO ==============================================================================
ECHO.

:: The following starts League of Legends and pauses this screen so that you can
:: view the list of languages, in case you need to.
ECHO Starting League of Legends...
START /D"%target%\" lol.launcher.exe
ECHO.
ECHO (You can press any key to close this window.)
PAUSE > NUL